Add ruby20. Drop alpha, ia64, sparc keywords due to yard dependency, bug 465948.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

2 files changed, 70 insertions, 1 deletions

diff --git a/dev-ruby/locale/ChangeLog b/dev-ruby/locale/ChangeLog
index 66d0826a2b06..75156242cc53 100644
--- a/dev-ruby/locale/ChangeLog
+++ b/dev-ruby/locale/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ruby/locale
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/locale/ChangeLog,v 1.55 2014/01/24 08:21:59 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/locale/ChangeLog,v 1.56 2014/01/24 08:38:57 graaff Exp $
+
+*locale-2.1.0-r1 (24 Jan 2014)
+
+  24 Jan 2014; Hans de Graaff <graaff@gentoo.org> +locale-2.1.0-r1.ebuild:
+  Add ruby20. Drop alpha, ia64, sparc keywords due to yard dependency, bug
+  465948.
 
   24 Jan 2014; Hans de Graaff <graaff@gentoo.org> -locale-2.0.8.ebuild,
   -locale-2.0.9.ebuild:
diff --git a/dev-ruby/locale/locale-2.1.0-r1.ebuild b/dev-ruby/locale/locale-2.1.0-r1.ebuild
new file mode 100644
index 000000000000..54c5b8ab0287
--- /dev/null
+++ b/dev-ruby/locale/locale-2.1.0-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/locale/locale-2.1.0-r1.ebuild,v 1.1 2014/01/24 08:38:57 graaff Exp $
+
+EAPI=5
+
+USE_RUBY="ruby18 ruby19 ruby20 jruby"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_DOCDIR="doc/reference"
+RUBY_FAKEGEM_EXTRADOC="ChangeLog README.rdoc doc/text/news.md"
+
+RUBY_FAKEGEM_TASK_TEST="test"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A pure ruby library which provides basic APIs for localization."
+HOMEPAGE="https://github.com/ruby-gettext/locale"
+LICENSE="|| ( Ruby GPL-2 )"
+SRC_URI="https://github.com/ruby-gettext/locale/archive/${PV}.tar.gz -> ${P}-git.tgz"
+
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-macos"
+SLOT="0"
+IUSE=""
+
+ruby_add_bdepend "doc? ( dev-ruby/yard )"
+
+ruby_add_bdepend "test? ( dev-ruby/test-unit:2 dev-ruby/test-unit-rr )"
+
+all_ruby_prepare() {
+	sed -i -e '/notify/ s:^:#:' test/run-test.rb || die
+}
+
+each_ruby_prepare() {
+	case ${RUBY} in
+		*jruby)
+			# Avoid failing tests in the partial jruby
+			# implementation. This may be dependeny on the specific
+			# locales available or it may be an issue with Gentoo still
+			# using jruby 1.6.
+			sed -i -e '/test_locales/,/end/ s:^:#:' test/test_driver_jruby.rb || die
+			;;
+	esac
+}
+
+all_ruby_compile() {
+	all_fakegem_compile
+
+	if use doc ; then
+		yard || die
+	fi
+}
+
+each_ruby_test() {
+	${RUBY} test/run-test.rb || die
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	insinto /usr/share/doc/${PF}
+	doins -r samples || die
+}