dev-vcs/git-cola: Version BUmp

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key B9D4F231BD1558AB!)

2 files changed, 109 insertions, 1 deletions

diff --git a/dev-vcs/git-cola/ChangeLog b/dev-vcs/git-cola/ChangeLog
index a7138630bbdb..43d33fd22e69 100644
--- a/dev-vcs/git-cola/ChangeLog
+++ b/dev-vcs/git-cola/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-vcs/git-cola
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v 1.29 2014/06/25 13:54:25 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/ChangeLog,v 1.30 2014/07/27 08:26:35 jlec Exp $
+
+*git-cola-2.0.5 (27 Jul 2014)
+
+  27 Jul 2014; Justin Lecher <jlec@gentoo.org> +git-cola-2.0.5.ebuild:
+  Version BUmp
 
 *git-cola-2.0.4 (25 Jun 2014)
 
diff --git a/dev-vcs/git-cola/git-cola-2.0.5.ebuild b/dev-vcs/git-cola/git-cola-2.0.5.ebuild
new file mode 100644
index 000000000000..512aed1eeb63
--- /dev/null
+++ b/dev-vcs/git-cola/git-cola-2.0.5.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git-cola/git-cola-2.0.5.ebuild,v 1.1 2014/07/27 08:26:35 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3} )
+DISTUTILS_SINGLE_IMPL=true
+
+inherit distutils-r1 readme.gentoo virtualx
+
+DESCRIPTION="The highly caffeinated git GUI"
+HOMEPAGE="http://git-cola.github.com/"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/jsonpickle[${PYTHON_USEDEP}]
+	dev-python/pyinotify[${PYTHON_USEDEP}]
+	dev-python/PyQt4[${PYTHON_USEDEP}]
+	dev-vcs/git"
+DEPEND="${RDEPEND}
+	app-text/asciidoc
+	app-text/xmlto
+	sys-devel/gettext
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		sys-apps/net-tools
+		)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.9.3-disable-tests.patch
+	"${FILESDIR}"/${PN}-1.9.1-system-ssh-askpass.patch
+	)
+
+pkg_pretend() {
+	if use test && [[ -z "$(hostname -d)" ]] ; then
+		die "Test will fail if no domain is set"
+	fi
+}
+
+python_prepare_all() {
+	rm share/git-cola/bin/*askpass* || die
+
+	# unfinished translate framework
+	rm test/i18n_test.py || die
+
+	# don't install docs into wrong location
+	sed -i \
+		-e '/doc/d' \
+		setup.py || die "sed failed"
+
+	sed -i \
+		-e  "s|'doc', 'git-cola'|'doc', '${PF}'|" \
+		cola/resources.py || die "sed failed"
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	cd share/doc/${PN}/
+	if use doc ; then
+		emake all
+	else
+		sed \
+			-e '/^install:/s:install-html::g' \
+			-e '/^install:/s:install-man::g' \
+			-i Makefile || die
+	fi
+}
+
+src_install() {
+	distutils-r1_src_install
+}
+
+python_install_all() {
+	cd share/doc/${PN}/ || die
+	emake \
+		DESTDIR="${D}" \
+		docdir="${EPREFIX}/usr/share/doc/${PF}" \
+		prefix="${EPREFIX}/usr" \
+		install
+
+	if ! use doc ; then
+		HTML_DOCS=( "${FILESDIR}"/index.html )
+	fi
+
+	distutils-r1_python_install_all
+	readme.gentoo_create_doc
+	docompress /usr/share/doc/${PF}/git-cola.txt
+}
+
+python_test() {
+	PYTHONPATH="${S}:${S}/build/lib:${PYTHONPATH}" LC_ALL="C" \
+		VIRTUALX_COMMAND="nosetests --verbose --with-doctest \
+		--with-id --exclude=jsonpickle --exclude=json" \
+		virtualmake
+}