version bump

(Portage version: 2.1.6.7/cvs/Linux i686)

2 files changed, 87 insertions, 1 deletions

diff --git a/games-engines/scummvm/ChangeLog b/games-engines/scummvm/ChangeLog
index c22d28f1a51e..25227ca9bba7 100644
--- a/games-engines/scummvm/ChangeLog
+++ b/games-engines/scummvm/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for games-engines/scummvm
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v 1.67 2009/03/13 22:10:49 josejx Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/ChangeLog,v 1.68 2009/04/28 18:20:21 mr_bones_ Exp $
+
+*scummvm-0.13.1 (28 Apr 2009)
+
+  28 Apr 2009; Michael Sterrett <mr_bones_@gentoo.org>
+  +scummvm-0.13.1.ebuild:
+  version bump
 
   13 Mar 2009; Joseph Jezak <josejx@gentoo.org> scummvm-0.12.0.ebuild:
   Marked ppc stable for bug #255573.
diff --git a/games-engines/scummvm/scummvm-0.13.1.ebuild b/games-engines/scummvm/scummvm-0.13.1.ebuild
new file mode 100644
index 000000000000..912da16a7a88
--- /dev/null
+++ b/games-engines/scummvm/scummvm-0.13.1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/games-engines/scummvm/scummvm-0.13.1.ebuild,v 1.1 2009/04/28 18:20:21 mr_bones_ Exp $
+
+EAPI=2
+inherit eutils games
+
+DESCRIPTION="Reimplementation of the SCUMM game engine used in Lucasarts adventures"
+HOMEPAGE="http://scummvm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/scummvm/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="alsa debug flac fluidsynth mp3 ogg vorbis zlib"
+RESTRICT="test"  # it only looks like there's a test there #77507
+
+RDEPEND=">=media-libs/libsdl-1.2.2
+	>media-libs/libmpeg2-0.3.1
+	ogg? ( media-libs/libogg media-libs/libvorbis )
+	vorbis? ( media-libs/libogg media-libs/libvorbis )
+	alsa? ( >=media-libs/alsa-lib-0.9[midi] )
+	mp3? ( media-libs/libmad )
+	flac? ( media-libs/flac )
+	fluidsynth? ( media-sound/fluidsynth )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}
+	x86? ( dev-lang/nasm )"
+
+src_prepare() {
+	# -g isn't needed for nasm here
+	sed -i \
+		-e '/NASMFLAGS/ s/-g//' \
+		Makefile.common \
+		|| die "sed failed"
+	sed -i \
+		-e '/INSTALL.*doc\//d' \
+		-e '/INSTALL.*\/pixmaps/d' \
+		-e 's/-s //' \
+		ports.mk \
+		|| die "sed failed"
+}
+
+src_configure() {
+	local myconf="--backend=sdl" # x11 backend no worky (bug #83502)
+
+	# let the engine find its data files in the right place (bug #178116)
+	myconf="${myconf} --datadir=${GAMES_DATADIR}"
+
+	( use vorbis || use ogg ) \
+		&& myconf="${myconf} --enable-vorbis" \
+		|| myconf="${myconf} --disable-vorbis --disable-mpeg2"
+
+	# bug #137547
+	use fluidsynth || myconf="${myconf} --disable-fluidsynth"
+
+	# NOT AN AUTOCONF SCRIPT SO DONT CALL ECONF
+	# mpeg2 support needs vorbis (bug #79149) so turn it off if -oggvorbis
+	./configure \
+		--prefix=/usr \
+		--bindir="${GAMES_BINDIR}" \
+		--datadir="${GAMES_DATADIR}" \
+		--libdir="${GAMES_LIBDIR}" \
+		$(use_enable debug) \
+		$(use_enable alsa) \
+		$(use_enable mp3 mad) \
+		$(use_enable flac) \
+		$(use_enable zlib) \
+		$(use_enable x86 nasm) \
+		${myconf} \
+		|| die "configure failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS NEWS README TODO
+	doicon icons/scummvm.svg
+	make_desktop_entry scummvm ScummVM scummvm "Game;AdventureGame"
+	prepgamesdirs
+}