Re-try committing this.

(Portage version: 2.1.2)

3 files changed, 98 insertions, 1 deletions

diff --git a/kde-base/arts/ChangeLog b/kde-base/arts/ChangeLog
index b72e351bd989..7db1fa8d2e38 100644
--- a/kde-base/arts/ChangeLog
+++ b/kde-base/arts/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/arts
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/ChangeLog,v 1.246 2007/01/05 16:54:15 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/ChangeLog,v 1.247 2007/01/18 15:29:40 flameeyes Exp $
+
+*arts-3.5.6 (18 Jan 2007)
+
+  18 Jan 2007; Diego Pettenò <flameeyes@gentoo.org> +arts-3.5.6.ebuild:
+  Re-try committing this.
 
   05 Jan 2007; Diego Pettenò <flameeyes@gentoo.org> arts-3.5.2-r1.ebuild,
   arts-3.5.5.ebuild:
diff --git a/kde-base/arts/arts-3.5.6.ebuild b/kde-base/arts/arts-3.5.6.ebuild
new file mode 100644
index 000000000000..cd2b19e902bf
--- /dev/null
+++ b/kde-base/arts/arts-3.5.6.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/arts/arts-3.5.6.ebuild,v 1.1 2007/01/18 15:29:40 flameeyes Exp $
+
+inherit kde flag-o-matic eutils versionator
+set-kdedir 3.5
+
+MY_PV="1.$(get_version_component_range 2-3)"
+S=${WORKDIR}/${PN}-${MY_PV}
+
+RESTRICT="test"
+
+DESCRIPTION="aRts, the KDE sound (and all-around multimedia) server/output manager"
+HOMEPAGE="http://multimedia.kde.org/"
+SRC_URI="mirror://kde/stable/${PV}/src/${PN}-${MY_PV}.tar.bz2"
+#SRC_URI="mirror://kde/stable/3.5/src/${PN}-${MY_PV}.tar.bz2"
+LICENSE="GPL-2 LGPL-2"
+
+SLOT="3.5"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="alsa esd artswrappersuid jack mp3 nas vorbis"
+
+RDEPEND="$(qt_min_version 3.3)
+	>=dev-libs/glib-2
+	alsa? ( media-libs/alsa-lib )
+	vorbis? ( media-libs/libogg
+			  media-libs/libvorbis )
+	esd? ( media-sound/esound )
+	jack? ( >=media-sound/jack-audio-connection-kit-0.90 )
+	mp3? ( media-libs/libmad )
+	nas? ( media-libs/nas )
+	media-libs/audiofile"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+PATCHES="${FILESDIR}/arts-1.5.0-bindnow.patch
+	${FILESDIR}/arts-1.5.4-multilib.patch"
+
+src_unpack() {
+	kde_src_unpack
+
+	# Alternative to arts-1.4-mcopidl.patch, make sure that flags are supported
+	# before trying to use them, for non-GCC, vanilla GCC or GCC 4.1 compilers
+	local nosspflags
+
+	nosspflags="$(test-flags -fno-stack-protector -fno-stack-protector-all)"
+	sed -i -e "s:KDE_CXXFLAGS =\(.*\):KDE_CXXFLAGS = \1 ${nosspflags}:" \
+		"${S}/mcopidl/Makefile.am"
+
+	# Fix libao/gaim problems with aRTs. See bug #116290.
+	epatch "${FILESDIR}/arts-1.5.0-check_tmp_dir.patch"
+
+	rm -f "${S}/configure"
+}
+
+src_compile() {
+	myconf="$(use_enable alsa) $(use_enable vorbis)
+			$(use_enable mp3 libmad) $(use_with jack)
+			$(use_with esd) $(use_with nas)
+		--with-audiofile --without-mas"
+
+	#fix bug 13453
+	filter-flags -foptimize-sibling-calls
+
+	# breaks otherwise <gustavoz>
+	use sparc && export CFLAGS="-O1" && export CXXFLAGS="-O1"
+
+	export BINDNOW_FLAGS="$(bindnow-flags)"
+
+	kde_src_compile
+}
+
+src_install() {
+	kde_src_install
+
+	# used for realtime priority, but off by default as it is a security hazard
+	use artswrappersuid && chmod u+s "${D}/${PREFIX}/bin/artswrapper"
+}
+
+pkg_postinst() {
+	if ! use artswrappersuid ; then
+		elog "Run chmod u+s ${PREFIX}/bin/artswrapper to let artsd use realtime priority"
+		elog "and so avoid possible skips in sound. However, on untrusted systems this"
+		elog "creates the possibility of a DoS attack that'll use 100% cpu at realtime"
+		elog "priority, and so is off by default. See bug #7883."
+		elog "Or, you can set the local artswrappersuid USE flag to make the ebuild do this."
+	fi
+}
diff --git a/kde-base/arts/files/digest-arts-3.5.6 b/kde-base/arts/files/digest-arts-3.5.6
new file mode 100644
index 000000000000..526530f288fb
--- /dev/null
+++ b/kde-base/arts/files/digest-arts-3.5.6
@@ -0,0 +1,3 @@
+MD5 e986393a5827499bbad04a00b797add0 arts-1.5.6.tar.bz2 966746
+RMD160 42074889e415dca534b1cf2700dd6e983319a28d arts-1.5.6.tar.bz2 966746
+SHA256 66f03a329e45c8a4a96c14c42cf28b9e6803d70740950e238c5ea494b2ab93df arts-1.5.6.tar.bz2 966746