Version bump KDE SC 4.11.0

(Portage version: 2.2.0_alpha196/cvs/Linux x86_64, signed Manifest commit with key EBE6A336BE19039C!)

2 files changed, 80 insertions, 1 deletions

diff --git a/kde-base/korundum/ChangeLog b/kde-base/korundum/ChangeLog
index 2182fb4cc8fa..716feda37ae8 100644
--- a/kde-base/korundum/ChangeLog
+++ b/kde-base/korundum/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for kde-base/korundum
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.175 2013/08/02 17:20:01 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/ChangeLog,v 1.176 2013/08/14 20:23:25 dilfridge Exp $
+
+*korundum-4.11.0 (14 Aug 2013)
+
+  14 Aug 2013; Andreas K. Huettel <dilfridge@gentoo.org>
+  +korundum-4.11.0.ebuild:
+  Version bump KDE SC 4.11.0
 
   02 Aug 2013; Johannes Huber <johu@gentoo.org> -korundum-4.10.4.ebuild:
   Remove KDE SC 4.10.4
diff --git a/kde-base/korundum/korundum-4.11.0.ebuild b/kde-base/korundum/korundum-4.11.0.ebuild
new file mode 100644
index 000000000000..14d15e180c87
--- /dev/null
+++ b/kde-base/korundum/korundum-4.11.0.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/korundum/korundum-4.11.0.ebuild,v 1.1 2013/08/14 20:23:25 dilfridge Exp $
+
+EAPI=5
+
+OPENGL_REQUIRED="always"
+
+USE_RUBY="ruby19"
+# Only one ruby version is supported:
+# 1) cmake bails when configuring twice or more - solved with CMAKE_IN_SOURCE_BUILD=1
+# 2) the ebuild can only be installed for one ruby variant, otherwise the compiled
+#    files with identical path+name will overwrite each other - difficult :(
+
+inherit kde4-base ruby-ng
+
+DESCRIPTION="KDE Ruby bindings"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="akonadi debug kate okular"
+HOMEPAGE="http://techbase.kde.org/Development/Languages/Ruby"
+
+# unfortunately single modules cannot be disabled with cmake defines
+# possible more useflags have no effect... does anyone actually build this stuff?
+
+DEPEND="
+	$(add_kdebase_dep qtruby)
+	$(add_kdebase_dep smokekde 'kate?,okular?')
+	$(add_kdebase_dep smokeqt)
+"
+RDEPEND="${DEPEND}
+"
+
+pkg_setup() {
+	ruby-ng_pkg_setup
+	kde4-base_pkg_setup
+}
+
+src_unpack() {
+	local S="${WORKDIR}/${P}"
+	kde4-base_src_unpack
+
+	cd "${WORKDIR}"
+	mkdir all
+	mv ${P} all/ || die "Could not move sources"
+}
+
+all_ruby_prepare() {
+	kde4-base_src_prepare
+}
+
+each_ruby_configure() {
+	CMAKE_USE_DIR=${S}
+	mycmakeargs=(
+		-DRUBY_LIBRARY=$(ruby_get_libruby)
+		-DRUBY_INCLUDE_PATH=$(ruby_get_hdrdir)
+		-DRUBY_EXECUTABLE=${RUBY}
+		$(cmake-utils_use_with akonadi)
+		$(cmake-utils_use_with akonadi KdepimLibs)
+		$(cmake-utils_use_disable kate)
+		$(cmake-utils_use_with okular)
+	)
+	kde4-base_src_configure
+}
+
+each_ruby_compile() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_compile
+}
+
+each_ruby_install() {
+	CMAKE_USE_DIR=${S}
+	kde4-base_src_install
+}