Version bump KDE SC 4.13.0

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

2 files changed, 93 insertions, 1 deletions

diff --git a/kde-base/marble/ChangeLog b/kde-base/marble/ChangeLog
index 384f9076cd72..7aed387fc3a2 100644
--- a/kde-base/marble/ChangeLog
+++ b/kde-base/marble/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for kde-base/marble
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/ChangeLog,v 1.242 2014/04/01 18:10:04 johu Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/ChangeLog,v 1.243 2014/04/16 18:26:41 johu Exp $
+
+*marble-4.13.0 (16 Apr 2014)
+
+  16 Apr 2014; Johannes Huber <johu@gentoo.org> +marble-4.13.0.ebuild:
+  Version bump KDE SC 4.13.0
 
 *marble-4.12.4 (01 Apr 2014)
 
diff --git a/kde-base/marble/marble-4.13.0.ebuild b/kde-base/marble/marble-4.13.0.ebuild
new file mode 100644
index 000000000000..19382096abaa
--- /dev/null
+++ b/kde-base/marble/marble-4.13.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/marble/marble-4.13.0.ebuild,v 1.1 2014/04/16 18:26:41 johu Exp $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KDE_REQUIRED="optional"
+CPPUNIT_REQUIRED="optional"
+PYTHON_COMPAT=( python{2_6,2_7} )
+inherit kde4-base python-single-r1
+
+DESCRIPTION="Generic geographical map widget"
+HOMEPAGE="http://marble.kde.org/"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug designer-plugin gps +kde plasma python shapefile test zip"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# tests fail / segfault. Last checked for 4.9.0
+RESTRICT="test"
+
+RDEPEND="
+	dev-qt/qtcore:4
+	dev-qt/qtdbus:4
+	dev-qt/qtdeclarative:4
+	dev-qt/qtgui:4
+	dev-qt/qtscript:4
+	dev-qt/qtsql:4
+	dev-qt/qtsvg:4
+	dev-qt/qtwebkit:4
+	gps? ( >=sci-geosciences/gpsd-2.95[qt4] )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/PyQt4-4.4.4-r1[${PYTHON_USEDEP}]
+		kde? ( $(add_kdebase_dep pykde4 "${PYTHON_USEDEP}" ) )
+	)
+	shapefile? ( sci-libs/shapelib )
+	zip? ( dev-libs/quazip )
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-qt/qttest:4 )
+"
+# the qt dependencies are needed because with USE=-kde nothing is pulled in
+# by default... bugs 414165 & 429346
+
+REQUIRED_USE="
+	plasma? ( kde )
+	python? ( kde )
+"
+
+pkg_setup() {
+	kde4-base_pkg_setup
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_with designer-plugin DESIGNER_PLUGIN)
+		$(cmake-utils_use python EXPERIMENTAL_PYTHON_BINDINGS)
+		$(cmake-utils_use_with python PythonLibrary)
+		$(cmake-utils_use_with python PyQt4)
+		$(cmake-utils_use_with python SIP)
+		$(cmake-utils_use_with gps libgps)
+		$(cmake-utils_use !kde QTONLY)
+		$(cmake-utils_use_with plasma)
+		$(cmake-utils_use_with shapefile libshp)
+		$(cmake-utils_use_with zip quazip)
+		-DBUILD_MARBLE_TESTS=OFF
+		-DWITH_liblocation=0
+		-DWITH_QextSerialPort=OFF
+	)
+
+	kde4-base_src_configure
+}
+
+src_test() {
+	if use kde; then
+		elog "Marble tests can only be run in the qt-only version"
+	else
+		local mycmakeargs=(
+			-DBUILD_MARBLE_TESTS=ON
+		)
+		kde4-base_src_test
+	fi
+}