Add KDE SC 4.10.0

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key F82F92E6)

2 files changed, 96 insertions, 1 deletions

diff --git a/kde-base/systemsettings/ChangeLog b/kde-base/systemsettings/ChangeLog
index 4ab10925d102..8f5337524cf9 100644
--- a/kde-base/systemsettings/ChangeLog
+++ b/kde-base/systemsettings/ChangeLog
@@ -1,10 +1,16 @@
 # ChangeLog for kde-base/systemsettings
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.181 2013/02/07 01:32:00 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/ChangeLog,v 1.182 2013/02/07 04:57:09 alexxy Exp $
 
   07 Feb 2013; Naohiro Aota <naota@gentoo.org> systemsettings-4.9.5.ebuild:
   Add ~x86-fbsd wrt bug #430072
 
+*systemsettings-4.10.0 (06 Feb 2013)
+
+  06 Feb 2013; Alexey Shvetsov <alexxy@gentoo.org>
+  +systemsettings-4.10.0.ebuild:
+  Version bump KDE SC 4.10.0
+
   28 Jan 2013; Agostino Sarubbo <ago@gentoo.org> -systemsettings-4.9.3.ebuild,
   -systemsettings-4.9.4.ebuild:
   Remove old
diff --git a/kde-base/systemsettings/systemsettings-4.10.0.ebuild b/kde-base/systemsettings/systemsettings-4.10.0.ebuild
new file mode 100644
index 000000000000..42cb7da2923a
--- /dev/null
+++ b/kde-base/systemsettings/systemsettings-4.10.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/systemsettings/systemsettings-4.10.0.ebuild,v 1.1 2013/02/07 04:57:09 alexxy Exp $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kde-workspace"
+OPENGL_REQUIRED="optional"
+VIRTUALX_REQUIRED="test"
+VIRTUALDBUS_TEST="true"
+inherit kde4-meta
+
+DESCRIPTION="System settings utility"
+IUSE="debug gtk +usb"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+
+COMMONDEPEND="
+	dev-libs/glib:2
+	$(add_kdebase_dep libkworkspace)
+	media-libs/fontconfig
+	>=media-libs/freetype-2
+	>=x11-libs/libxklavier-3.2
+	x11-libs/libXcursor
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXrandr
+	x11-libs/libXtst
+	opengl? ( virtual/opengl )
+	usb? ( virtual/libusb:0 )
+"
+DEPEND="${COMMONDEPEND}
+	x11-proto/kbproto
+	x11-proto/xextproto
+"
+RDEPEND="${COMMONDEPEND}
+	sys-libs/timezone-data
+	x11-apps/setxkbmap
+	x11-misc/xkeyboard-config
+	gtk? ( kde-misc/kde-gtk-config )
+"
+
+KMEXTRA="
+	kcontrol/
+"
+KMEXTRACTONLY="
+	krunner/dbus/org.kde.krunner.App.xml
+	krunner/dbus/org.kde.screensaver.xml
+	ksmserver/screenlocker/dbus/org.kde.screensaver.xml
+	kwin/
+	libs/
+	plasma/
+"
+
+add_blocker kdeaccessibility-colorschemes '<4.6.50'
+
+src_unpack() {
+	if use handbook; then
+		KMEXTRA+="
+			doc/kcontrol
+			doc/kfontview
+		"
+	fi
+
+	kde4-meta_src_unpack
+}
+
+src_prepare() {
+	sed -i -e 's/systemsettingsrc DESTINATION ${SYSCONF_INSTALL_DIR}/systemsettingsrc DESTINATION ${CONFIG_INSTALL_DIR}/' \
+		systemsettings/CMakeLists.txt \
+		|| die "Failed to fix systemsettingsrc install location"
+
+	kde4-meta_src_prepare
+}
+
+# FIXME: is have_openglxvisual found without screensaver
+src_configure() {
+	# Old keyboard-detection code is unmaintained,
+	# so we force the new stuff, using libxklavier.
+	mycmakeargs=(
+		-DUSE_XKLAVIER=ON -DWITH_LibXKlavier=ON
+		-DWITH_GLIB2=ON -DWITH_GObject=ON
+		$(cmake-utils_use_with opengl OpenGL)
+		$(cmake-utils_use_with usb)
+	)
+
+	kde4-meta_src_configure
+}