add new revision with x11-libs/wxGTK:3.0 support for bug #506972, add python-3.4 support, sync live ebuild

(Portage version: 2.2.14_rc1/cvs/Linux x86_64, signed Manifest commit with key 072AD062)

4 files changed, 107 insertions, 12 deletions

diff --git a/media-gfx/hugin/ChangeLog b/media-gfx/hugin/ChangeLog
index d8fcf5204232..f8d73be6e02c 100644
--- a/media-gfx/hugin/ChangeLog
+++ b/media-gfx/hugin/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-gfx/hugin
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/ChangeLog,v 1.150 2014/10/10 20:12:04 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/ChangeLog,v 1.151 2014/10/12 17:57:08 maekke Exp $
+
+*hugin-2014.0.0-r1 (12 Oct 2014)
+
+  12 Oct 2014; Markus Meier <maekke@gentoo.org> hugin-2014.0.0.ebuild,
+  +hugin-2014.0.0-r1.ebuild, hugin-9999.ebuild:
+  add new revision with x11-libs/wxGTK:3.0 support for bug #506972, add
+  python-3.4 support, sync live ebuild
 
 *hugin-2014.0.0 (10 Oct 2014)
 
diff --git a/media-gfx/hugin/hugin-2014.0.0-r1.ebuild b/media-gfx/hugin/hugin-2014.0.0-r1.ebuild
new file mode 100644
index 000000000000..67607b5f3bb7
--- /dev/null
+++ b/media-gfx/hugin/hugin-2014.0.0-r1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-2014.0.0-r1.ebuild,v 1.1 2014/10/12 17:57:08 maekke Exp $
+
+EAPI=5
+
+WX_GTK_VER="3.0"
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
+
+inherit base python-single-r1 wxwidgets versionator cmake-utils
+
+DESCRIPTION="GUI for the creation & processing of panoramic images"
+HOMEPAGE="http://hugin.sf.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2 SIFT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+
+LANGS=" cs da de en_GB es eu fi fr hu it ja nl pl pt_BR ro ru sk sv zh_CN zh_TW"
+IUSE="debug lapack python sift $(echo ${LANGS//\ /\ linguas_})"
+
+CDEPEND="
+	!!dev-util/cocom
+	app-arch/zip
+	dev-cpp/tclap
+	>=dev-libs/boost-1.49.0-r1:=
+	dev-libs/zthread
+	>=media-gfx/enblend-4.0
+	media-gfx/exiv2
+	media-libs/freeglut
+	media-libs/glew:=
+	media-libs/lensfun
+	>=media-libs/libpano13-2.9.19_beta1:0=
+	media-libs/libpng:0=
+	media-libs/openexr:=
+	media-libs/tiff
+	sys-libs/zlib
+	virtual/jpeg
+	x11-libs/wxGTK:3.0=[X,opengl]
+	lapack? ( virtual/lapack )
+	sift? ( media-gfx/autopano-sift-C )"
+RDEPEND="${CDEPEND}
+	media-libs/exiftool"
+DEPEND="${CDEPEND}
+	sys-devel/gettext
+	virtual/pkgconfig
+	python? ( ${PYTHON_DEPS} >=dev-lang/swig-2.0.4 )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+S=${WORKDIR}/${PN}-$(get_version_component_range 1-3)
+
+PATCHES=( "${FILESDIR}"/${P}-lensfun-0.3.0.patch )
+
+pkg_setup() {
+	DOCS="authors.txt README TODO"
+	mycmakeargs=(
+		$(cmake-utils_use_enable lapack LAPACK)
+		$(cmake-utils_use_build python HSI)
+	)
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	sed \
+		-e 's:-O3::g' \
+		-i src/celeste/CMakeLists.txt || die
+	rm CMakeModules/{FindLAPACK,FindPkgConfig}.cmake || die
+
+	cmake-utils_src_prepare
+}
+
+src_install() {
+	cmake-utils_src_install
+	use python && python_optimize
+
+	for lang in ${LANGS} ; do
+		case ${lang} in
+			ca) dir=ca_ES;;
+			cs) dir=cs_CZ;;
+			*) dir=${lang};;
+		esac
+		use linguas_${lang} || rm -r "${D}"/usr/share/locale/${dir}
+	done
+}
diff --git a/media-gfx/hugin/hugin-2014.0.0.ebuild b/media-gfx/hugin/hugin-2014.0.0.ebuild
index 5d4e69616a6e..3416b02736c0 100644
--- a/media-gfx/hugin/hugin-2014.0.0.ebuild
+++ b/media-gfx/hugin/hugin-2014.0.0.ebuild
@@ -1,11 +1,11 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-2014.0.0.ebuild,v 1.1 2014/10/10 20:12:04 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-2014.0.0.ebuild,v 1.2 2014/10/12 17:57:08 maekke Exp $
 
 EAPI=5
 
 WX_GTK_VER="2.8"
-PYTHON_COMPAT=( python{2_7,3_2,3_3} )
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
 
 inherit base python-single-r1 wxwidgets versionator cmake-utils
 
@@ -18,7 +18,7 @@ SLOT="0"
 KEYWORDS="~amd64 ~ppc ~x86"
 
 LANGS=" cs da de en_GB es eu fi fr hu it ja nl pl pt_BR ro ru sk sv zh_CN zh_TW"
-IUSE="lapack python sift debug $(echo ${LANGS//\ /\ linguas_})"
+IUSE="debug lapack python sift $(echo ${LANGS//\ /\ linguas_})"
 
 CDEPEND="
 	!!dev-util/cocom
diff --git a/media-gfx/hugin/hugin-9999.ebuild b/media-gfx/hugin/hugin-9999.ebuild
index 2a354742f527..7e40a4d58ba7 100644
--- a/media-gfx/hugin/hugin-9999.ebuild
+++ b/media-gfx/hugin/hugin-9999.ebuild
@@ -1,10 +1,11 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-9999.ebuild,v 1.3 2014/01/12 19:45:37 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/hugin/hugin-9999.ebuild,v 1.4 2014/10/12 17:57:08 maekke Exp $
 
 EAPI=5
-WX_GTK_VER="2.8"
-PYTHON_COMPAT=( python{2_7,3_2,3_3} )
+
+WX_GTK_VER="3.0"
+PYTHON_COMPAT=( python{2_7,3_2,3_3,3_4} )
 
 inherit base mercurial python-single-r1 wxwidgets versionator cmake-utils
 
@@ -19,7 +20,7 @@ SLOT="0"
 KEYWORDS=""
 
 LANGS=" cs da de en_GB es eu fi fr hu it ja nl pl pt_BR ro ru sk sv zh_CN zh_TW"
-IUSE="lapack python sift $(echo ${LANGS//\ /\ linguas_})"
+IUSE="debug lapack python sift $(echo ${LANGS//\ /\ linguas_})"
 
 CDEPEND="
 	!!dev-util/cocom
@@ -36,15 +37,15 @@ CDEPEND="
 	media-libs/libpng:0=
 	media-libs/openexr:=
 	media-libs/tiff
-	sci-libs/flann
 	sys-libs/zlib
 	virtual/jpeg
-	x11-libs/wxGTK:2.8=[X,opengl,-odbc]
+	x11-libs/wxGTK:3.0=[X,opengl]
 	lapack? ( virtual/lapack )
 	sift? ( media-gfx/autopano-sift-C )"
 RDEPEND="${CDEPEND}
 	media-libs/exiftool"
 DEPEND="${CDEPEND}
+	sys-devel/gettext
 	virtual/pkgconfig
 	python? ( ${PYTHON_DEPS} >=dev-lang/swig-2.0.4 )"
 
@@ -58,7 +59,7 @@ pkg_setup() {
 		$(cmake-utils_use_enable lapack LAPACK)
 		$(cmake-utils_use_build python HSI)
 	)
-	python-single-r1_pkg_setup
+	use python && python-single-r1_pkg_setup
 }
 
 src_prepare() {
@@ -66,12 +67,13 @@ src_prepare() {
 		-e 's:-O3::g' \
 		-i src/celeste/CMakeLists.txt || die
 	rm CMakeModules/{FindLAPACK,FindPkgConfig}.cmake || die
+
 	cmake-utils_src_prepare
 }
 
 src_install() {
 	cmake-utils_src_install
-	python_optimize
+	use python && python_optimize
 
 	for lang in ${LANGS} ; do
 		case ${lang} in