Drop old extension uncompatible with nautilus-3, port to new python eclasses

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 73 insertions, 2 deletions

diff --git a/media-gfx/postr/ChangeLog b/media-gfx/postr/ChangeLog
index af0f66b29a8d..4b0490fc4b74 100644
--- a/media-gfx/postr/ChangeLog
+++ b/media-gfx/postr/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/postr
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/postr/ChangeLog,v 1.8 2013/12/08 19:08:18 pacho Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/postr/ChangeLog,v 1.9 2014/06/22 19:08:19 pacho Exp $
+
+*postr-0.13-r1 (22 Jun 2014)
+
+  22 Jun 2014; Pacho Ramos <pacho@gentoo.org> +postr-0.13-r1.ebuild:
+  Drop old extension uncompatible with nautilus-3, port to new python eclasses
 
   08 Dec 2013; Pacho Ramos <pacho@gentoo.org> postr-0.13.ebuild:
   x86 stable, bug #478252
diff --git a/media-gfx/postr/postr-0.13-r1.ebuild b/media-gfx/postr/postr-0.13-r1.ebuild
new file mode 100644
index 000000000000..9f0f0725100b
--- /dev/null
+++ b/media-gfx/postr/postr-0.13-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/postr/postr-0.13-r1.ebuild,v 1.1 2014/06/22 19:08:19 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="xml"
+
+inherit eutils gnome2 python-single-r1
+
+DESCRIPTION="Flickr uploader for GNOME"
+HOMEPAGE="https://wiki.gnome.org/Apps/Postr"
+
+LICENSE="GPL-2+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	dev-python/pygtk:2[${PYTHON_USEDEP}]
+"
+
+RDEPEND="${COMMON_DEPEND}
+	dev-python/bsddb3[${PYTHON_USEDEP}]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/gconf-python[${PYTHON_USEDEP}]
+	dev-python/gtkspell-python[${PYTHON_USEDEP}]
+	dev-python/libgnome-python[${PYTHON_USEDEP}]
+	dev-python/pygobject:2[${PYTHON_USEDEP}]
+	dev-python/twisted-core[${PYTHON_USEDEP}]
+	dev-python/twisted-web[${PYTHON_USEDEP}]
+"
+DEPEND="${COMMON_DEPEND}
+	app-text/gnome-doc-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_prepare() {
+	# In next release
+	epatch "${FILESDIR}/${P}-exception-after-quit.patch"
+
+	# Don't check for nautilus-python if we aren't installing the nautilus-2 extension
+	sed -e 's:nautilus-python >= 0.6.1::' -i configure || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--with-nautilus-extension-dir=${EPREFIX}/usr/share/nautilus-python/extensions
+}
+
+src_install() {
+	gnome2_src_install
+	python_fix_shebang "${ED}"
+
+	# In next release, https://bugzilla.gnome.org/show_bug.cgi?id=685454
+	mv "${ED}usr/share/postr/postr.glade" "${ED}$(python_get_sitedir)/postr/" || die
+
+	rm -r "${ED}usr/share/nautilus-python" || die
+}