Remove USE="mkl" from -r0 for stabilization.

(Portage version: 2.2.0_alpha69/cvs/Linux x86_64)

3 files changed, 137 insertions, 5 deletions

diff --git a/media-gfx/povray/ChangeLog b/media-gfx/povray/ChangeLog
index e5b6624ae9b3..f0ca2eef32ea 100644
--- a/media-gfx/povray/ChangeLog
+++ b/media-gfx/povray/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/povray
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/povray/ChangeLog,v 1.117 2011/10/19 13:06:50 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/povray/ChangeLog,v 1.118 2011/10/21 16:40:19 ssuominen Exp $
+
+*povray-3.7.0_rc3-r1 (21 Oct 2011)
+
+  21 Oct 2011; Samuli Suominen <ssuominen@gentoo.org> povray-3.7.0_rc3.ebuild,
+  +povray-3.7.0_rc3-r1.ebuild:
+  Remove USE="mkl" from -r0 for stabilization.
 
   19 Oct 2011; Samuli Suominen <ssuominen@gentoo.org> povray-3.7.0_rc3.ebuild:
   amd64 stable wrt #384823
diff --git a/media-gfx/povray/povray-3.7.0_rc3-r1.ebuild b/media-gfx/povray/povray-3.7.0_rc3-r1.ebuild
new file mode 100644
index 000000000000..b1fe55087e17
--- /dev/null
+++ b/media-gfx/povray/povray-3.7.0_rc3-r1.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/povray/povray-3.7.0_rc3-r1.ebuild,v 1.1 2011/10/21 16:40:19 ssuominen Exp $
+
+EAPI="3"
+
+inherit autotools eutils flag-o-matic versionator
+
+POVRAY_MAJOR_VER=$(get_version_component_range 1-3)
+POVRAY_MINOR_VER=$(get_version_component_range 4)
+if [ -n "$POVRAY_MINOR_VER" ]; then
+	POVRAY_MINOR_VER=${POVRAY_MINOR_VER/rc/RC}
+	MY_PV="${POVRAY_MAJOR_VER}.${POVRAY_MINOR_VER}"
+else
+	MY_PV=${POVRAY_MAJOR_VER}
+fi
+
+DESCRIPTION="The Persistence of Vision Raytracer"
+HOMEPAGE="http://www.povray.org/"
+SRC_URI="http://www.povray.org/redirect/www.povray.org/beta/source/${PN}-${MY_PV}.tar.bz2"
+
+LICENSE="povlegal-3.6"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="debug mkl openexr tiff X"
+
+DEPEND="
+	>=dev-libs/boost-1.41
+	virtual/jpeg
+	media-libs/libpng:0
+	sys-libs/zlib
+	openexr? (
+		media-libs/ilmbase
+		media-libs/openexr )
+	mkl? ( sci-libs/mkl )
+	tiff? ( >=media-libs/tiff-3.6.1 )
+	X? ( media-libs/libsdl )"
+RDEPEND="${DEPEND}"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_prepare() {
+	# Change some destination directories that cannot be adjusted via configure
+	cp configure.ac configure.ac.orig
+	sed \
+		-e 's:${povsysconfdir}/$PACKAGE/$VERSION_BASE:${povsysconfdir}/'${PN}':g' \
+		-e 's:${povdatadir}/$PACKAGE-$VERSION_BASE:${povdatadir}/'${PN}':g' \
+		-e 's:${povdatadir}/doc/$PACKAGE-$VERSION_BASE:${povdatadir}/doc/'${PF}':g' \
+		-i configure.ac || die
+
+	cp Makefile.am Makefile.am.orig
+	sed \
+		-e "s:^povlibdir = .*:povlibdir = @datadir@/${PN}:" \
+		-e "s:^povdocdir = .*:povdocdir = @datadir@/doc/${PF}:" \
+		-e "s:^povconfdir = .*:povconfdir = @sysconfdir@/${PN}:" \
+		-i Makefile.am || die
+
+	# The "+p" option on the test command line causes a pause and
+	# prompts the user to interact, so remove it.
+	sed -i -e "s:biscuit.pov -f +d +p:biscuit.pov -f +d:" Makefile.am || die
+
+	epatch "${FILESDIR}"/${PV}-user-conf.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	local non_redist_conf
+
+	# Fixes bug 71255
+	if [[ $(get-flag march) == k6-2 ]]; then
+		filter-flags -fomit-frame-pointer
+	fi
+
+	# The config files are installed correctly (e.g. povray.conf),
+	# but the code compiles using incorrect [default] paths
+	# (based on /usr/local...), so povray will not find the system
+	# config files without the following fix:
+	append-flags -DPOVLIBDIR=\\\"${EROOT}usr/share/${PN}\\\"
+	append-flags -DPOVCONFDIR=\\\"${EROOT}etc/${PN}\\\"
+
+	if ! use tiff ; then
+		non_redist_conf="NON_REDISTRIBUTABLE_BUILD=yes"
+	else
+		non_redist_conf=""
+	fi
+
+	econf \
+		${non_redist_conf} \
+		COMPILED_BY="Portage (Gentoo `uname`) on `hostname -f`" \
+		$(use_enable debug) \
+		$(use_with openexr) \
+		$(use_with mkl libmkl) \
+		$(use_with tiff libtiff) \
+		$(use_with X libsdl) \
+		$(use_with X x) \
+		--disable-strip \
+		--disable-optimiz \
+		--disable-optimiz-arch \
+		--with-boost-libdir="${EPREFIX}/usr/$(get_libdir)"
+}
+
+src_test() {
+	# For the beta releases, we generate a license extension in case needed
+	POVRAY_BETA=`./unix/povray --betacode 2>&1` emake check || die "Test failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+}
+
+pkg_preinst() {
+	# Copy the old config files if they are in the old location
+	# but do not yet exist in the new location.
+	# This way, they can be treated by CONFIG_PROTECT as normal.
+	for conf_file in $(ls "${ED}/etc/${PN}"); do
+		if [ ! -e "${EROOT}etc/${PN}/${conf_file}" ]; then
+			for version_dir in $(ls "${EROOT}etc/${PN}" | grep "^[0-9]" | sort -rn); do
+				if [ -e "${EROOT}etc/${PN}/${version_dir}/${conf_file}" ]; then
+					mv "${EROOT}etc/${PN}/${version_dir}/${conf_file}" "${EROOT}etc/${PN}"
+					elog "Note: ${conf_file} moved from ${EROOT}etc/povray/${version_dir}/ to ${EROOT}etc/povray/"
+					break
+				fi
+			done
+		fi
+	done
+}
diff --git a/media-gfx/povray/povray-3.7.0_rc3.ebuild b/media-gfx/povray/povray-3.7.0_rc3.ebuild
index 56dbb77e76ed..5ab7ee32ba0d 100644
--- a/media-gfx/povray/povray-3.7.0_rc3.ebuild
+++ b/media-gfx/povray/povray-3.7.0_rc3.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/povray/povray-3.7.0_rc3.ebuild,v 1.5 2011/10/19 13:06:50 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/povray/povray-3.7.0_rc3.ebuild,v 1.6 2011/10/21 16:40:19 ssuominen Exp $
 
 EAPI="3"
 
@@ -22,7 +22,7 @@ SRC_URI="http://www.povray.org/redirect/www.povray.org/beta/source/${PN}-${MY_PV
 LICENSE="povlegal-3.6"
 SLOT="0"
 KEYWORDS="~alpha amd64 hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
-IUSE="debug mkl openexr tiff X"
+IUSE="debug openexr tiff X"
 
 DEPEND="
 	>=dev-libs/boost-1.41
@@ -32,7 +32,6 @@ DEPEND="
 	openexr? (
 		media-libs/ilmbase
 		media-libs/openexr )
-	mkl? ( sci-libs/mkl )
 	tiff? ( >=media-libs/tiff-3.6.1 )
 	X? ( media-libs/libsdl )"
 RDEPEND="${DEPEND}"
@@ -90,7 +89,7 @@ src_configure() {
 		COMPILED_BY="Portage (Gentoo `uname`) on `hostname -f`" \
 		$(use_enable debug) \
 		$(use_with openexr) \
-		$(use_with mkl libmkl) \
+		--without-libmkl \
 		$(use_with tiff libtiff) \
 		$(use_with X libsdl) \
 		$(use_with X x) \