version bump (bug #380657)

(Portage version: 2.1.10.11/cvs/Linux i686)

7 files changed, 233 insertions, 1 deletions

diff --git a/media-libs/allegro/ChangeLog b/media-libs/allegro/ChangeLog
index 8b405abed4e0..7c5d1e8167d7 100644
--- a/media-libs/allegro/ChangeLog
+++ b/media-libs/allegro/ChangeLog
@@ -1,6 +1,15 @@
 # ChangeLog for media-libs/allegro
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/ChangeLog,v 1.109 2011/08/09 12:29:55 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/ChangeLog,v 1.110 2011/09/03 08:57:09 mr_bones_ Exp $
+
+*allegro-5.0.4 (03 Sep 2011)
+*allegro-4.4.2 (03 Sep 2011)
+
+  03 Sep 2011; Michael Sterrett <mr_bones_@gentoo.org> +allegro-4.4.2.ebuild,
+  +files/allegro-4.4.2-rpath.patch, +files/allegro-4.4.2-shared.patch,
+  +files/allegro-4.4.2-underlink.patch, +allegro-5.0.4.ebuild,
+  +files/allegro-5.0.4-underlink.patch:
+  version bump (bug #380657)
 
   09 Aug 2011; Kacper Kowalik <xarthisius@gentoo.org> allegro-5.0.3.ebuild:
   ppc/ppc64 stable wrt #375491
diff --git a/media-libs/allegro/allegro-4.4.2.ebuild b/media-libs/allegro/allegro-4.4.2.ebuild
new file mode 100644
index 000000000000..d3f6a556c6c9
--- /dev/null
+++ b/media-libs/allegro/allegro-4.4.2.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/allegro-4.4.2.ebuild,v 1.1 2011/09/03 08:57:09 mr_bones_ Exp $
+
+EAPI=2
+CMAKE_IN_SOURCE_BUILD=1
+inherit cmake-utils eutils
+
+DESCRIPTION="cross-platform multimedia library"
+HOMEPAGE="http://alleg.sourceforge.net/"
+SRC_URI="mirror://sourceforge/alleg/${P}.tar.gz"
+
+LICENSE="Allegro as-is GPL-2 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="alsa fbcon jack jpeg opengl oss png svga test vga vorbis X"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg? ( virtual/jpeg )
+	png? ( >=media-libs/libpng-1.4 )
+	svga? ( media-libs/svgalib )
+	vorbis? ( media-libs/libvorbis )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+		x11-libs/libXext
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libXxf86dga
+		x11-libs/libXxf86vm
+		opengl? ( virtual/opengl
+			virtual/glu )
+	)
+	!media-libs/allegrogl
+	!media-libs/jpgalleg"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	X? (
+		x11-proto/xextproto
+		x11-proto/xf86dgaproto
+		x11-proto/xf86vidmodeproto
+		x11-proto/xproto
+	)"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-shared.patch \
+		"${FILESDIR}"/${P}-underlink.patch \
+		"${FILESDIR}"/${P}-rpath.patch
+
+	sed -i \
+		-e "s:allegro-\${ALLEGRO_VERSION}:${PF}:" \
+		docs/CMakeLists.txt || die
+}
+
+src_configure() {
+	# WANT_LINUX_CONSOLE is by default OFF
+	# WANT_EXAMPLES doesn't install anything
+
+	mycmakeargs=(
+		"-DDOCDIR=share/doc"
+		"-DINFODIR=share/info"
+		"-DMANDIR=share/man"
+		$(cmake-utils_use_want alsa)
+		"-DWANT_EXAMPLES=OFF"
+		$(cmake-utils_use_want jack)
+		$(cmake-utils_use_want jpeg JPGALLEG)
+		"-DWANT_LINUX_CONSOLE=OFF"
+		$(cmake-utils_use_want fbcon LINUX_FBCON)
+		$(cmake-utils_use_want svga LINUX_SVGALIB)
+		$(cmake-utils_use_want vga LINUX_VGA)
+		$(cmake-utils_use_want png LOADPNG)
+		$(cmake-utils_use_want vorbis LOGG)
+		$(cmake-utils_use_want oss)
+		$(cmake-utils_use_want test TESTS)
+		$(cmake-utils_use_want X TOOLS)
+		$(cmake-utils_use_want X X11)
+		)
+
+	if use X; then
+		mycmakeargs+=(
+			$(cmake-utils_use_want opengl ALLEGROGL)
+			)
+	else
+		mycmakeargs+=(
+			"-DWANT_ALLEGROGL=OFF"
+			)
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	dohtml docs/html/*.html || die
+	doman docs/man/*.3 || die
+
+	if use X; then
+		newbin setup/setup ${PN}-setup || die
+		insinto /usr/share/${PN}
+		doins {keyboard,language,setup/setup}.dat || die
+		newicon misc/icon.png ${PN}.png
+		make_desktop_entry ${PN}-setup "Allegro Setup" ${PN} "Settings"
+	fi
+
+	rm -f "${D}"/usr/share/man/man3/init_dialog.3* #176020
+	newman docs/man/init_dialog.3 allegro_init_dialog.3
+}
diff --git a/media-libs/allegro/allegro-5.0.4.ebuild b/media-libs/allegro/allegro-5.0.4.ebuild
new file mode 100644
index 000000000000..801175b488aa
--- /dev/null
+++ b/media-libs/allegro/allegro-5.0.4.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/allegro-5.0.4.ebuild,v 1.1 2011/09/03 08:57:09 mr_bones_ Exp $
+
+EAPI=2
+inherit cmake-utils
+
+DESCRIPTION="A game programming library"
+HOMEPAGE="http://alleg.sourceforge.net/"
+SRC_URI="mirror://sourceforge/alleg/${P}.tar.gz"
+
+LICENSE="BSD ZLIB"
+SLOT="5"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="alsa dumb flac gtk jpeg openal oss physfs png pulseaudio test truetype vorbis X xinerama"
+
+RDEPEND="alsa? ( media-libs/alsa-lib )
+	dumb? ( media-libs/dumb )
+	flac? ( media-libs/flac )
+	jpeg? ( virtual/jpeg )
+	openal? ( media-libs/openal )
+	physfs? ( dev-games/physfs )
+	png? ( >=media-libs/libpng-1.4 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.15 )
+	truetype? ( >=media-libs/freetype-2 )
+	vorbis? ( media-libs/libvorbis )
+	x11-libs/libXcursor
+	x11-libs/libXxf86vm
+	x11-libs/libXrandr
+	x11-libs/libX11
+	gtk? ( x11-libs/gtk+:2 )
+	virtual/opengl
+	xinerama? ( x11-libs/libXinerama )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	x11-proto/xextproto
+	x11-proto/xf86vidmodeproto
+	x11-proto/xproto"
+
+PATCHES=( "${FILESDIR}"/${P}-underlink.patch )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_want alsa)
+		-DWANT_DEMO=OFF
+		-DWANT_EXAMPLES=OFF
+		$(cmake-utils_use_want flac)
+		$(cmake-utils_use_want jpeg IMAGE_JPG)
+		$(cmake-utils_use_want png IMAGE_PNG)
+		$(cmake-utils_use_want dumb MODAUDIO)
+		$(cmake-utils_use_want openal)
+		$(cmake-utils_use_want oss)
+		$(cmake-utils_use_want physfs)
+		$(cmake-utils_use_want pulseaudio)
+		$(cmake-utils_use_want test TESTS)
+		$(cmake-utils_use_want truetype TTF)
+		$(cmake-utils_use_want vorbis)
+		$(cmake-utils_use_want gtk NATIVE_DIALOG)
+		$(cmake-utils_use_want X opengl)
+		$(cmake-utils_use_want xinerama X11_XINERAMA)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	dodoc CHANGES-5.0.txt || die
+	dohtml -r docs/html/refman/* || die
+	doman docs/man/*.3 || die
+}
diff --git a/media-libs/allegro/files/allegro-4.4.2-rpath.patch b/media-libs/allegro/files/allegro-4.4.2-rpath.patch
new file mode 100644
index 000000000000..57bdb6bf8d0e
--- /dev/null
+++ b/media-libs/allegro/files/allegro-4.4.2-rpath.patch
@@ -0,0 +1,8 @@
+--- setup/CMakeLists.txt
++++ setup/CMakeLists.txt
+@@ -1,3 +1,5 @@
++set(CMAKE_SKIP_BUILD_RPATH TRUE)
++
+ add_our_executable(setup setup.c)
+ copy_files(copy_setup_data setup.dat)
+ 
diff --git a/media-libs/allegro/files/allegro-4.4.2-shared.patch b/media-libs/allegro/files/allegro-4.4.2-shared.patch
new file mode 100644
index 000000000000..665c03e31204
--- /dev/null
+++ b/media-libs/allegro/files/allegro-4.4.2-shared.patch
@@ -0,0 +1,11 @@
+--- CMakeLists.txt
++++ CMakeLists.txt
+@@ -830,7 +830,7 @@
+ option(WANT_LOGG "Enable logg" on)
+ option(WANT_JPGALLEG "Enable JPGAlleg" on)
+ 
+-if(WANT_FRAMEWORKS)
++if(SHARED)
+     set(ADDON_LINKAGE SHARED)
+ else()
+     set(ADDON_LINKAGE STATIC)
diff --git a/media-libs/allegro/files/allegro-4.4.2-underlink.patch b/media-libs/allegro/files/allegro-4.4.2-underlink.patch
new file mode 100644
index 000000000000..33dc9d260b2d
--- /dev/null
+++ b/media-libs/allegro/files/allegro-4.4.2-underlink.patch
@@ -0,0 +1,11 @@
+--- CMakeLists.txt.old	2011-06-06 23:46:06.057320691 +0200
++++ CMakeLists.txt	2011-06-06 23:46:21.900313261 +0200
+@@ -392,7 +392,7 @@
+         message(FATAL_ERROR "Unix port requires pthreads support.")
+     endif()
+     set(ALLEGRO_HAVE_LIBPTHREAD 1)
+-    list(APPEND PLATFORM_LIBS m ${CMAKE_THREAD_LIBS_INIT})
++    list(APPEND PLATFORM_LIBS dl m ${CMAKE_THREAD_LIBS_INIT})
+     list(APPEND PLATFORM_SOURCES ${ALLEGRO_SRC_UNIX_FILES})
+ 
+     if(WANT_OSS)
diff --git a/media-libs/allegro/files/allegro-5.0.4-underlink.patch b/media-libs/allegro/files/allegro-5.0.4-underlink.patch
new file mode 100644
index 000000000000..7702c1d2c6db
--- /dev/null
+++ b/media-libs/allegro/files/allegro-5.0.4-underlink.patch
@@ -0,0 +1,11 @@
+--- CMakeLists.txt.old	2011-06-06 23:56:09.367125536 +0200
++++ CMakeLists.txt	2011-06-06 23:56:19.311748807 +0200
+@@ -703,7 +703,7 @@
+ 
+ if(ALLEGRO_UNIX) # not MACOSX
+     list(APPEND LIBRARY_SOURCES ${ALLEGRO_SRC_UNIX_FILES})
+-    list(APPEND PLATFORM_LIBS m ${CMAKE_THREAD_LIBS_INIT})
++    list(APPEND PLATFORM_LIBS dl m ${CMAKE_THREAD_LIBS_INIT})
+ endif(ALLEGRO_UNIX)
+ 
+ if(SUPPORT_X11)