Update the shipped version of ogg.m4 so that users of libflac don't get a ton of libtool warnings while linking.

(Portage version: 2.2.0_alpha29/cvs/Linux x86_64)

1 files changed, 70 insertions, 0 deletions

diff --git a/media-libs/flac/flac-1.2.1-r4.ebuild b/media-libs/flac/flac-1.2.1-r4.ebuild
new file mode 100644
index 000000000000..2e0ae976ca59
--- /dev/null
+++ b/media-libs/flac/flac-1.2.1-r4.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/flac/flac-1.2.1-r4.ebuild,v 1.1 2011/03/28 04:38:44 ford_prefect Exp $
+
+EAPI=2
+inherit autotools eutils
+
+DESCRIPTION="free lossless audio encoder and decoder"
+HOMEPAGE="http://flac.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	mirror://gentoo/${P}-embedded-m4.tar.bz2"
+
+LICENSE="BSD FDL-1.2 GPL-2 LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="3dnow altivec +cxx debug ogg sse static-libs"
+
+RDEPEND="ogg? ( >=media-libs/libogg-1.1.3 )"
+DEPEND="${RDEPEND}
+	x86? ( dev-lang/nasm )
+	!elibc_uclibc? ( sys-devel/gettext )
+	dev-util/pkgconfig"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-asneeded.patch \
+		"${FILESDIR}"/${P}-cflags.patch \
+		"${FILESDIR}"/${P}-asm.patch \
+		"${FILESDIR}"/${P}-dontbuild-tests.patch \
+		"${FILESDIR}"/${P}-dontbuild-examples.patch \
+		"${FILESDIR}"/${P}-gcc-4.3-includes.patch \
+		"${FILESDIR}"/${P}-ogg-m4.patch
+
+	cp "${WORKDIR}"/*.m4 m4 || die
+
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--disable-dependency-tracking \
+		$(use_enable debug) \
+		$(use_enable sse) \
+		$(use_enable 3dnow) \
+		$(use_enable altivec) \
+		--disable-doxygen-docs \
+		--disable-xmms-plugin \
+		$(use_enable cxx cpplibs) \
+		$(use_enable ogg) \
+		--disable-examples
+}
+
+src_test() {
+	if [ $UID != 0 ]; then
+		emake check || die
+	else
+		ewarn "Tests will fail if ran as root, skipping."
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	rm -rf "${D}"/usr/share/doc/${P}
+	dodoc AUTHORS README
+	dohtml -r doc/html/*
+
+	find "${D}" -name '*.la' -exec rm -f '{}' +
+}