media-libs/gegl: 0.2.0

(Portage version: 2.1.10.56/cvs/Linux x86_64)

3 files changed, 118 insertions, 3 deletions

diff --git a/media-libs/gegl/ChangeLog b/media-libs/gegl/ChangeLog
index 02c0a4773e42..fb7b27912ccb 100644
--- a/media-libs/gegl/ChangeLog
+++ b/media-libs/gegl/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/gegl
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/ChangeLog,v 1.66 2012/02/13 20:21:43 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/ChangeLog,v 1.67 2012/04/11 23:34:40 sping Exp $
+
+*gegl-0.2.0 (11 Apr 2012)
+
+  11 Apr 2012; Sebastian Pipping <sping@gentoo.org> gegl-0.1.8.ebuild,
+  +gegl-0.2.0.ebuild:
+  Bump to 0.2.0
 
   13 Feb 2012; Fabian Groffen <grobian@gentoo.org> gegl-0.1.8.ebuild:
   Marked ~x64-macos
diff --git a/media-libs/gegl/gegl-0.1.8.ebuild b/media-libs/gegl/gegl-0.1.8.ebuild
index c0e24a5b0540..69f5f681470f 100644
--- a/media-libs/gegl/gegl-0.1.8.ebuild
+++ b/media-libs/gegl/gegl-0.1.8.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/gegl-0.1.8.ebuild,v 1.8 2012/02/13 20:21:43 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/gegl-0.1.8.ebuild,v 1.9 2012/04/11 23:34:40 sping Exp $
 
 EAPI=4
 
@@ -18,7 +18,7 @@ IUSE="cairo debug exif ffmpeg graphviz introspection jpeg jpeg2k lensfun lua mmx
 
 VALASLOT="0.14"
 
-RDEPEND=">=media-libs/babl-0.1.6
+RDEPEND=">=media-libs/babl-0.1.6[introspection?]
 	>=dev-libs/glib-2.28:2
 	>=x11-libs/gdk-pixbuf-2.18:2
 	x11-libs/pango
diff --git a/media-libs/gegl/gegl-0.2.0.ebuild b/media-libs/gegl/gegl-0.2.0.ebuild
new file mode 100644
index 000000000000..524e5d25541e
--- /dev/null
+++ b/media-libs/gegl/gegl-0.2.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/gegl/gegl-0.2.0.ebuild,v 1.1 2012/04/11 23:34:40 sping Exp $
+
+EAPI=4
+
+inherit gnome2-utils eutils autotools
+
+DESCRIPTION="A graph based image processing framework"
+HOMEPAGE="http://www.gegl.org/"
+SRC_URI="ftp://ftp.gimp.org/pub/${PN}/${PV:0:3}/${P}.tar.bz2"
+
+LICENSE="|| ( GPL-3 LGPL-3 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
+
+IUSE="cairo debug exif ffmpeg graphviz introspection jpeg jpeg2k lensfun lua mmx openexr png raw sdl sse svg umfpack v4l vala"
+
+VALASLOT="0.14"
+
+RDEPEND=">=media-libs/babl-0.1.10[introspection?]
+	>=dev-libs/glib-2.28:2
+	>=x11-libs/gdk-pixbuf-2.18:2
+	x11-libs/pango
+	sys-libs/zlib
+	cairo? ( x11-libs/cairo )
+	exif? ( media-gfx/exiv2 )
+	ffmpeg? ( virtual/ffmpeg )
+	graphviz? ( media-gfx/graphviz )
+	jpeg? ( virtual/jpeg )
+	jpeg2k? ( >=media-libs/jasper-1.900.1 )
+	lua? ( >=dev-lang/lua-5.1 )
+	openexr? ( media-libs/openexr )
+	png? ( media-libs/libpng )
+	raw? ( >=media-libs/libopenraw-0.0.5 )
+	sdl? ( media-libs/libsdl )
+	svg? ( >=gnome-base/librsvg-2.14:2 )
+	umfpack? ( sci-libs/umfpack )
+	v4l? ( media-libs/libv4l )
+	dev-lang/perl
+	introspection? ( >=dev-libs/gobject-introspection-0.10
+			>=dev-python/pygobject-2.26:2 )
+	lensfun? ( >=media-libs/lensfun-0.2.5 )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.40.1
+	dev-util/pkgconfig
+	>=sys-devel/libtool-2.2
+	vala? ( dev-lang/vala:${VALASLOT}[vapigen] )"
+
+# tests fail in various ways:
+#   see bug #362215
+RESTRICT="test"
+
+DOCS=( ChangeLog INSTALL README NEWS )
+
+src_prepare() {
+	# fix OSX loadable module filename extension
+	sed -i -e 's/\.dylib/.bundle/' configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	# never enable altering of CFLAGS via profile option
+	# libspiro: not in portage main tree
+	# disable documentation as the generating is bit automagic
+	#    if anyone wants to work on it just create bug with patch
+	VAPIGEN="$(type -p vapigen-${VALASLOT})" \
+	econf \
+		--disable-profile \
+		--without-libspiro \
+		--disable-docs --disable-workshop \
+		--with-pango --with-gdk-pixbuf \
+		$(use_enable mmx) \
+		$(use_enable sse) \
+		$(use_enable debug) \
+		$(use_with cairo) \
+		$(use_with cairo pangocairo) \
+		$(use_with exif exiv2) \
+		$(use_with ffmpeg libavformat) \
+		$(use_with graphviz) \
+		$(use_with jpeg libjpeg) \
+		$(use_with jpeg2k jasper) \
+		$(use_with lua) \
+		$(use_with openexr) \
+		$(use_with png libpng) \
+		$(use_with raw libopenraw) \
+		$(use_with sdl) \
+		$(use_with svg librsvg) \
+		$(use_with umfpack) \
+		$(use_with v4l libv4l) \
+		$(use_enable introspection) \
+		$(use_with lensfun) \
+		$(use_with vala)
+}
+
+src_test() {
+	gnome2_environment_reset  # sandbox issues
+	default
+}
+
+src_compile() {
+	gnome2_environment_reset  # sandbox issues (bug #396687)
+	default
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -delete
+}