version bump

(Portage version: 2.2.8/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 72 insertions, 2 deletions

diff --git a/media-libs/libmikmod/ChangeLog b/media-libs/libmikmod/ChangeLog
index 9ba27ac9bba1..aaa1abc5de22 100644
--- a/media-libs/libmikmod/ChangeLog
+++ b/media-libs/libmikmod/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/libmikmod
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libmikmod/ChangeLog,v 1.114 2013/12/17 17:10:07 ssuominen Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmikmod/ChangeLog,v 1.115 2014/01/11 14:24:44 aballier Exp $
+
+*libmikmod-3.3.5 (11 Jan 2014)
+
+  11 Jan 2014; Alexis Ballier <aballier@gentoo.org> +libmikmod-3.3.5.ebuild:
+  version bump
 
   17 Dec 2013; Samuli Suominen <ssuominen@gentoo.org> libmikmod-3.3.4.ebuild:
   Introduce USE="nas" for media-libs/nas support thanks to upstream fixing the
diff --git a/media-libs/libmikmod/libmikmod-3.3.5.ebuild b/media-libs/libmikmod/libmikmod-3.3.5.ebuild
new file mode 100644
index 000000000000..9344610e3e40
--- /dev/null
+++ b/media-libs/libmikmod/libmikmod-3.3.5.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libmikmod/libmikmod-3.3.5.ebuild,v 1.1 2014/01/11 14:24:44 aballier Exp $
+
+EAPI=5
+inherit eutils multilib-minimal
+
+DESCRIPTION="A library to play a wide range of module formats"
+HOMEPAGE="http://mikmod.sourceforge.net/"
+SRC_URI="mirror://sourceforge/mikmod/${P}.tar.gz"
+
+LICENSE="LGPL-2+ LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="+alsa altivec coreaudio debug nas openal oss pulseaudio sse2 static-libs +threads"
+
+REQUIRED_USE="|| ( alsa oss coreaudio )"
+
+RDEPEND="alsa? ( media-libs/alsa-lib:=[${MULTILIB_USEDEP}] )
+	nas? ( media-libs/nas:=[${MULTILIB_USEDEP}] )
+	openal? ( >=media-libs/openal-1.15.1-r1[${MULTILIB_USEDEP}] )
+	pulseaudio? ( >=media-sound/pulseaudio-4.0-r1[${MULTILIB_USEDEP}] )
+	!${CATEGORY}/${PN}:2
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224-r3
+					!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	oss? ( virtual/os-headers )"
+
+multilib_src_configure() {
+	local mysimd="--disable-simd"
+	if use ppc || use ppc64 || use ppc-macos; then
+		mysimd="$(use_enable altivec simd)"
+	fi
+	if use amd64 || use x86 || use x86-fbsd || use x86-freebsd || use amd64-linux || use x86-linux || use x86-macos; then
+		mysimd="$(use_enable sse2 simd)"
+	fi
+
+	# sdl, sdl2: missing multilib supported ebuilds, temporarily disabled
+	ECONF_SOURCE=${S} \
+	econf \
+		$(use_enable alsa) \
+		$(use_enable nas) \
+		$(use_enable pulseaudio) \
+		--disable-sdl \
+		--disable-sdl2 \
+		$(use_enable openal) \
+		$(use_enable oss) \
+		$(use_enable coreaudio osx) \
+		$(use_enable debug) \
+		$(use_enable threads) \
+		$(use_enable static-libs static) \
+		--disable-dl \
+		${mysimd}
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	dosym ${PN}$(get_libname 3) /usr/$(get_libdir)/${PN}$(get_libname 2)
+}
+
+multilib_src_install_all() {
+	dodoc AUTHORS NEWS README TODO
+	dohtml docs/*.html
+	prune_libtool_files
+}