go multilib, move ladspa-sdk as build dep only.

(Portage version: 2.2.0_alpha185/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

2 files changed, 78 insertions, 1 deletions

diff --git a/media-plugins/swh-plugins/ChangeLog b/media-plugins/swh-plugins/ChangeLog
index 4e7674cbc8bd..396acb4d4693 100644
--- a/media-plugins/swh-plugins/ChangeLog
+++ b/media-plugins/swh-plugins/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-plugins/swh-plugins
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-plugins/swh-plugins/ChangeLog,v 1.49 2013/06/27 13:53:56 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/swh-plugins/ChangeLog,v 1.50 2013/06/27 15:01:31 aballier Exp $
+
+*swh-plugins-0.4.15-r3 (27 Jun 2013)
+
+  27 Jun 2013; Alexis Ballier <aballier@gentoo.org>
+  +swh-plugins-0.4.15-r3.ebuild:
+  go multilib, move ladspa-sdk as build dep only.
 
   27 Jun 2013; Alexis Ballier <aballier@gentoo.org> -swh-plugins-0.4.15.ebuild,
   -swh-plugins-0.4.15-r1.ebuild:
diff --git a/media-plugins/swh-plugins/swh-plugins-0.4.15-r3.ebuild b/media-plugins/swh-plugins/swh-plugins-0.4.15-r3.ebuild
new file mode 100644
index 000000000000..7263097d2e08
--- /dev/null
+++ b/media-plugins/swh-plugins/swh-plugins-0.4.15-r3.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-plugins/swh-plugins/swh-plugins-0.4.15-r3.ebuild,v 1.1 2013/06/27 15:01:31 aballier Exp $
+
+EAPI=5
+
+inherit eutils autotools multilib-minimal
+
+DESCRIPTION="Large collection of LADSPA audio plugins/effects"
+HOMEPAGE="http://plugin.org.uk"
+SRC_URI="http://plugin.org.uk/releases/${PV}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="3dnow nls sse"
+
+RDEPEND="
+	media-sound/gsm[${MULTILIB_USEDEP}]
+	>=sci-libs/fftw-3[${MULTILIB_USEDEP}]
+	abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224-r2
+					!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
+DEPEND="${RDEPEND}
+	media-libs/ladspa-sdk
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( AUTHORS ChangeLog README TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-pic.patch"
+	epatch "${FILESDIR}/${P}-plugindir.patch"
+	epatch "${FILESDIR}/${P}-riceitdown.patch"
+	epatch "${FILESDIR}/${P}-gettext.patch"
+	epatch "${FILESDIR}/${P}-x86-asm-optional.patch"
+	epatch "${FILESDIR}/${P}-glibc-2.10.patch"
+
+	# Use system libgsm, bug #252890
+	rm -rf gsm
+	epatch "${FILESDIR}/${P}-system_gsm.patch"
+
+	# This is to update gettext macros, otherwise they are incompatible with
+	# recent libtools, bug #231767
+	autopoint -f || die
+
+	# it doesn't get updated otherwise
+	rm -f missing
+
+	# Fix build with automake 1.13
+	sed -i 's/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/g' configure.in || die
+
+	eautoreconf
+	elibtoolize
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable sse) \
+		$(use_enable 3dnow) \
+		$(use_enable nls) \
+		--enable-fast-install \
+		--disable-dependency-tracking
+}
+
+pkg_postinst() {
+	ewarn "WARNING: You have to be careful when using the"
+	ewarn "swh plugins. Be sure to lower your sound volume"
+	ewarn "and then play around a bit with the plugins so"
+	ewarn "you get a feeling for it. Otherwise your speakers"
+	ewarn "won't like that."
+}