Version bump, bug 253502

(Portage version: 2.2_rc20/cvs/Linux 2.6.28 x86_64)

1 files changed, 61 insertions, 0 deletions

diff --git a/media-sound/ario/ario-1.2.ebuild b/media-sound/ario/ario-1.2.ebuild
new file mode 100644
index 000000000000..8b402f4da948
--- /dev/null
+++ b/media-sound/ario/ario-1.2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/ario/ario-1.2.ebuild,v 1.1 2009/01/03 00:17:29 angelos Exp $
+
+EAPI=1
+inherit gnome2-utils
+
+DESCRIPTION="a GTK2 MPD (Music Player Daemon) client inspired by Rythmbox"
+HOMEPAGE="http://ario-player.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}-player/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="audioscrobbler dbus debug idle libnotify nls python zeroconf"
+
+RDEPEND=">=dev-libs/glib-2.14:2
+	gnome-base/libglade:2.0
+	net-misc/curl
+	net-libs/gnutls
+	>=x11-libs/gtk+-2.12:2
+	audioscrobbler? ( net-libs/libsoup:2.4 )
+	dbus? ( dev-libs/dbus-glib )
+	libnotify? ( x11-libs/libnotify )
+	python? ( dev-python/pygtk
+		dev-python/pygobject )
+	zeroconf? ( net-dns/avahi )"
+DEPEND="sys-devel/gettext
+	dev-util/intltool
+	dev-util/pkgconfig"
+
+src_compile() {
+	econf \
+		$(use_enable audioscrobbler) \
+		$(use_enable dbus) \
+		$(use_enable debug) \
+		$(use_enable idle mpdidle) \
+		$(use_enable libnotify notify) \
+		$(use_enable nls) \
+		$(use_enable python) \
+		$(use_enable zeroconf avahi)
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc AUTHORS ChangeLog NEWS README TODO
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}