Version bump.

(Portage version: 2.1.3.9)

3 files changed, 107 insertions, 1 deletions

diff --git a/media-sound/exaile/ChangeLog b/media-sound/exaile/ChangeLog
index a1f69ce57d14..79572d658d6d 100644
--- a/media-sound/exaile/ChangeLog
+++ b/media-sound/exaile/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/exaile
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/exaile/ChangeLog,v 1.26 2007/09/15 12:55:47 drac Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/exaile/ChangeLog,v 1.27 2007/09/23 09:51:12 drac Exp $
+
+*exaile-0.2.11_beta (23 Sep 2007)
+
+  23 Sep 2007; Samuli Suominen <drac@gentoo.org> +exaile-0.2.11_beta.ebuild:
+  Version bump.
 
   15 Sep 2007; Samuli Suominen <drac@gentoo.org> exaile-0.2.10-r1.ebuild:
   Add support for sqlite support in Python 2.5.
diff --git a/media-sound/exaile/exaile-0.2.11_beta.ebuild b/media-sound/exaile/exaile-0.2.11_beta.ebuild
new file mode 100644
index 000000000000..11baaee8bd21
--- /dev/null
+++ b/media-sound/exaile/exaile-0.2.11_beta.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/exaile/exaile-0.2.11_beta.ebuild,v 1.1 2007/09/23 09:51:12 drac Exp $
+
+inherit eutils fdo-mime multilib python
+
+GVER="0.10"
+
+MY_P=${PN}_${PV/_beta/b}
+
+DESCRIPTION="a media player aiming to be similar to AmaroK, but for GTK+"
+HOMEPAGE="http://www.exaile.org"
+SRC_URI="http://www.exaile.org/files/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="aac alsa cdparanoia flac gnome ipod libnotify libsexy mad musepack ogg
+	oss vorbis"
+
+RDEPEND=">=dev-python/pygtk-2.8.6
+	|| ( >=dev-lang/python-2.5 >=dev-python/pysqlite-2.3.4-r1 )
+	>=media-libs/mutagen-1.6
+	|| ( >=dev-lang/python-2.5 dev-python/elementtree )
+	dev-python/dbus-python
+	libnotify? ( dev-python/notify-python )
+	libsexy? ( dev-python/sexy-python )
+	gnome? ( >=dev-python/gnome-python-extras-2.14.2-r1
+		>=media-plugins/gst-plugins-gconf-${GVER}
+		>=media-plugins/gst-plugins-gnomevfs-${GVER} )
+	>=media-libs/gstreamer-${GVER}
+	>=media-libs/gst-plugins-good-${GVER}
+	>=dev-python/gst-python-${GVER}
+	musepack? ( >=media-plugins/gst-plugins-musepack-${GVER} )
+	vorbis? ( >=media-plugins/gst-plugins-vorbis-${GVER} )
+	flac? ( >=media-plugins/gst-plugins-flac-${GVER} )
+	aac? ( >=media-plugins/gst-plugins-faad-${GVER} )
+	alsa? ( >=media-plugins/gst-plugins-alsa-${GVER} )
+	oss? ( >=media-plugins/gst-plugins-oss-${GVER} )
+	mad? ( >=media-plugins/gst-plugins-mad-${GVER} )
+	ogg? ( >=media-plugins/gst-plugins-ogg-${GVER} )
+	cdparanoia? ( >=media-plugins/gst-plugins-cdparanoia-${GVER}
+		dev-python/cddb-py )
+	ipod? ( >=media-libs/libgpod-0.4
+		>=media-plugins/gst-plugins-faad-${GVER} )"
+DEPEND=""
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if use ipod && ! built_with_use media-libs/libgpod python ; then
+		eerror "libgpod has to be built with python support"
+		die "libgpod python use-flag not set"
+	fi
+
+	if ! has_version ">=dev-python/pysqlite-2.3.4-r1"; then
+		if ! built_with_use ">=dev-lang/python-2.5" sqlite; then
+			eerror "You need to compile dev-lang/python with USE sqlite, or"
+			eerror "install >=dev-python/pysqlite-2.3.4-r1."
+			die "python 2.5 or up with sqlite support or pysqlite 2.3.5 or up required."
+		fi
+	fi
+
+	if use gnome; then
+		if ! built_with_use dev-python/gnome-python-extras xulrunner; then
+			if ! built_with_use dev-python/gnome-python-extras firefox; then
+				if ! built_with_use dev-python/gnome-python-extras seamonkey; then
+					ewarn "In order to enable extra features provided by gtkmozembed,"
+					ewarn "you have to re-emerge gnome-python-extras with"
+					ewarn "xulrunner, firefox or seamonkey USE flag."
+					epause
+				fi
+			fi
+		fi
+	fi
+}
+
+src_compile() {
+	emake mmkeys.so || die "emake mmkeys.so failed."
+	emake translations || die "emake translations failed."
+}
+
+src_install() {
+	emake PREFIX="/usr" LIBDIR="/$(get_libdir)" DESTDIR="${D}" install || die "emake install failed."
+	dodoc changelog TODO
+}
+
+pkg_postinst() {
+	python_mod_optimize /usr/$(get_libdir)/${PN}
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	python_mod_cleanup /usr/$(get_libdir)/${PN}
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+}
diff --git a/media-sound/exaile/files/digest-exaile-0.2.11_beta b/media-sound/exaile/files/digest-exaile-0.2.11_beta
new file mode 100644
index 000000000000..20ef193a4dfc
--- /dev/null
+++ b/media-sound/exaile/files/digest-exaile-0.2.11_beta
@@ -0,0 +1,3 @@
+MD5 5baf65bf40df68218c9aa7887bc807ca exaile_0.2.11b.tar.gz 651764
+RMD160 edc4c609afa4ee1e86231590a63ab82326d8f424 exaile_0.2.11b.tar.gz 651764
+SHA256 7acd651002c49b6301ee83af479029aa1267f79705b9347c66e6eb043e861119 exaile_0.2.11b.tar.gz 651764