media-sound/mp3splt-gtk: 0.7.1

(Portage version: 2.1.10.44/cvs/Linux x86_64)

2 files changed, 65 insertions, 2 deletions

diff --git a/media-sound/mp3splt-gtk/ChangeLog b/media-sound/mp3splt-gtk/ChangeLog
index 85639f974b86..cef1d2a3fc2d 100644
--- a/media-sound/mp3splt-gtk/ChangeLog
+++ b/media-sound/mp3splt-gtk/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/mp3splt-gtk
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/mp3splt-gtk/ChangeLog,v 1.22 2011/09/23 21:26:49 sping Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mp3splt-gtk/ChangeLog,v 1.23 2012/01/04 10:45:44 sping Exp $
+
+*mp3splt-gtk-0.7.1 (04 Jan 2012)
+
+  04 Jan 2012; Sebastian Pipping <sping@gentoo.org> +mp3splt-gtk-0.7.1.ebuild:
+  Bump to 0.7.1, looks trivial
 
 *mp3splt-gtk-0.7.0.930 (23 Sep 2011)
 
diff --git a/media-sound/mp3splt-gtk/mp3splt-gtk-0.7.1.ebuild b/media-sound/mp3splt-gtk/mp3splt-gtk-0.7.1.ebuild
new file mode 100644
index 000000000000..a0f0986f2b27
--- /dev/null
+++ b/media-sound/mp3splt-gtk/mp3splt-gtk-0.7.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mp3splt-gtk/mp3splt-gtk-0.7.1.ebuild,v 1.1 2012/01/04 10:45:44 sping Exp $
+
+EAPI=2
+inherit versionator autotools multilib
+
+DESCRIPTION="a GTK+ based utility to split mp3 and ogg files without decoding."
+HOMEPAGE="http://mp3splt.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN::-4}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="audacious doc gtk3 gnome gstreamer nls"
+
+RDEPEND=">=media-libs/libmp3splt-0.7.0.920
+	gtk3? ( x11-libs/gtk+:3
+		audacious? ( >=media-sound/audacious-3.0 ) )
+	!gtk3? ( >=x11-libs/gtk+-2.6:2
+		audacious? ( <media-sound/audacious-3.0 ) )
+	gstreamer? ( media-libs/gst-plugins-base:0.10 )
+	gnome? ( gnome-base/libgnomeui )"
+DEPEND="${RDEPEND}
+	gnome? ( app-text/gnome-doc-utils app-text/rarian )
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	if use audacious; then
+		sed -i \
+			-e 's:@AUDACIOUS_LIBS@:-laudclient &:' \
+			src/Makefile.am || die
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	use nls || myconf+=" --disable-nls"
+	use audacious || myconf+=" --disable-audacious"
+	use gstreamer || myconf+=" --disable-gstreamer"
+
+	econf \
+		--disable-dependency-tracking \
+		--with-mp3splt-libraries=/usr/$(get_libdir) \
+		--with-mp3splt-includes=/usr/include/libmp3splt \
+		$(use_enable gnome) \
+		$(use_enable doc doxygen_doc) \
+		$(use_enable gtk3) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS README
+}