Version bump

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

2 files changed, 75 insertions, 1 deletions

diff --git a/media-sound/wildmidi/ChangeLog b/media-sound/wildmidi/ChangeLog
index ad9f0c5c7530..a4de262d8bc3 100644
--- a/media-sound/wildmidi/ChangeLog
+++ b/media-sound/wildmidi/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/wildmidi
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/wildmidi/ChangeLog,v 1.27 2014/05/21 20:33:36 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/wildmidi/ChangeLog,v 1.28 2014/05/30 22:11:29 hwoarang Exp $
+
+*wildmidi-0.3.7 (30 May 2014)
+
+  30 May 2014; Markos Chandras <hwoarang@gentoo.org> +wildmidi-0.3.7.ebuild:
+  Version bump
 
 *wildmidi-0.3.6 (21 May 2014)
 
diff --git a/media-sound/wildmidi/wildmidi-0.3.7.ebuild b/media-sound/wildmidi/wildmidi-0.3.7.ebuild
new file mode 100644
index 000000000000..a993d2d66828
--- /dev/null
+++ b/media-sound/wildmidi/wildmidi-0.3.7.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/wildmidi/wildmidi-0.3.7.ebuild,v 1.1 2014/05/30 22:11:29 hwoarang Exp $
+
+EAPI=5
+inherit cmake-utils readme.gentoo
+
+DESCRIPTION="Midi processing library and a midi player using the gus patch set"
+HOMEPAGE="http://www.mindwerks.net/projects/wildmidi/"
+SRC_URI="http://github.com/Mindwerks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86"
+IUSE="+alsa openal oss +player"
+
+DEPEND="player? (
+	alsa? ( media-libs/alsa-lib )
+	openal? ( media-libs/openal )
+	)"
+RDEPEND="${DEPEND}
+	media-sound/timidity-freepats"
+
+REQUIRED_USE="player? ( ^^ ( alsa oss openal ) )"
+
+DOC_CONTENTS="${PN} is using timidity-freepats for midi playback.
+	A default configuration file was placed on /etc/${PN}/${PN}.cfg.
+	For more information please read the ${PN}.cfg manpage."
+
+src_prepare() {
+	# alsa openal oss only make sense if player is enabled. See CMakeLists.txt
+	if ! use player && (use alsa || use openal || use oss); then
+		ewarn
+		ewarn "The 'alsa', 'openal' and 'oss' use flags only make sense if"
+		ewarn "the 'player' use flags is selected and as a result they will be"
+		ewarn "ignored in this build"
+		ewarn
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_want alsa)
+		$(cmake-utils_use_want openal)
+		$(cmake-utils_use_want oss)
+		$(cmake-utils_use_want player)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	find "${D}" -name '*.la' -exec rm -f {} +
+	insinto /etc/${PN}/
+	doins cfg/${PN}.cfg
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	if [[ -e "${ROOT}"/etc/${PN}.cfg ]]; then
+		elog
+		elog "Old /etc/${PN}.cfg detected!"
+		elog "Please migrate your configuration file to"
+		elog "/etc/${PN}/ directory which is now the default"
+		elog "location for the ${PN} configuration file."
+		elog
+	fi
+}