Version bump. Features subsong support for console music (NSF/NSFE/GBS) and improved stability.

(Portage version: 2.1)

3 files changed, 118 insertions, 1 deletions

diff --git a/media-sound/audacious/ChangeLog b/media-sound/audacious/ChangeLog
index dffcd5859848..ed6a541c40a5 100644
--- a/media-sound/audacious/ChangeLog
+++ b/media-sound/audacious/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/audacious
 # Copyright 1999-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.44 2006/06/06 15:13:37 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/ChangeLog,v 1.45 2006/06/12 20:40:48 chainsaw Exp $
+
+*audacious-1.1.0_beta2 (12 Jun 2006)
+
+  12 Jun 2006; Tony Vroon <chainsaw@gentoo.org>
+  +audacious-1.1.0_beta2.ebuild:
+  Version bump. Features subsong support for console music (NSF/NSFE/GBS) and
+  improved stability.
 
   06 Jun 2006; Tony Vroon <chainsaw@gentoo.org> audacious-1.0.0-r1.ebuild:
   Mark stable on ppc. Approved: hansmi.
diff --git a/media-sound/audacious/audacious-1.1.0_beta2.ebuild b/media-sound/audacious/audacious-1.1.0_beta2.ebuild
new file mode 100644
index 000000000000..ba481c8c45fd
--- /dev/null
+++ b/media-sound/audacious/audacious-1.1.0_beta2.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/audacious/audacious-1.1.0_beta2.ebuild,v 1.1 2006/06/12 20:40:48 chainsaw Exp $
+
+inherit flag-o-matic
+
+MY_P="${P/_beta/-dr}"
+S="${WORKDIR}/${MY_P}"
+DESCRIPTION="Audacious Player - Your music, your way, no exceptions"
+HOMEPAGE="http://audacious-media-player.org/"
+SRC_URI="http://audacious-media-player.org/beta/${MY_P}.tgz
+	mirror://gentoo/gentoo_ice-xmms-0.2.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="aac alsa arts esd flac gnome jack lirc mmx modplug mp3 musepack nls oss sid sndfile timidity vorbis wma"
+
+RDEPEND="app-arch/unzip
+	net-misc/curl
+	media-libs/musicbrainz
+	>=x11-libs/gtk+-2.6
+	>=gnome-base/libglade-2.3.1
+	>=dev-cpp/libbinio-1.4
+	alsa? ( >=media-libs/alsa-lib-1.0.9_rc2 )
+	arts? ( kde-base/arts )
+	esd? ( >=media-sound/esound-0.2.30 )
+	flac? ( >=media-libs/libvorbis-1.0
+		>=media-libs/flac-1.1.2 )
+	gnome? ( >=gnome-base/gconf-2.6.0 )
+	jack? ( >=media-libs/bio2jack-0.4
+		media-libs/libsamplerate
+		media-sound/jack-audio-connection-kit )
+	lirc? ( app-misc/lirc )
+	modplug? ( media-libs/libmodplug )
+	musepack? ( media-libs/libmpcdec
+		    media-libs/taglib )
+	mp3? ( media-libs/taglib )
+	sid? ( media-libs/libsidplay )
+	sndfile? ( media-libs/libsndfile )
+	timidity? ( media-sound/timidity++ )
+	vorbis? ( >=media-libs/libvorbis-1.0
+		  >=media-libs/libogg-1.0 )"
+DEPEND="${RDEPEND}
+	nls? ( dev-util/intltool )
+	>=dev-util/pkgconfig-0.9.0"
+
+mp3_warning() {
+	if ! useq mp3 ; then
+		echo
+		ewarn "MP3 support is now optional, you may want to enable the mp3 USE-flag"
+		echo
+	fi
+}
+
+src_compile() {
+	mp3_warning
+
+	# Bug #42893
+	replace-flags "-Os" "-O2"
+	# Bug #86689
+	is-flag "-O*" || append-flags -O
+
+	econf \
+		--with-dev-dsp=/dev/sound/dsp \
+		--with-dev-mixer=/dev/sound/mixer \
+		$(use_enable mmx simd) \
+		$(use_enable gnome gconf) \
+		$(use_enable vorbis) \
+		$(use_enable esd) \
+		$(use_enable mp3) \
+		$(use_enable nls) \
+		$(use_enable oss) \
+		$(use_enable alsa) \
+		$(use_enable arts) \
+		$(use_enable flac) \
+		$(use_enable aac) \
+		$(use_enable modplug) \
+		$(use_enable lirc) \
+		$(use_enable sndfile) \
+		$(use_enable wma) \
+		$(use_enable sid) \
+		$(use_enable musepack) \
+		$(use_enable jack) \
+		$(use_enable timidity) \
+		|| die
+
+	emake || die "make failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die
+	dodoc AUTHORS NEWS README
+
+	# Gentoo_ice skin installation; bug #109772
+	insinto /usr/share/audacious/Skins/gentoo_ice
+	doins "${WORKDIR}"/gentoo_ice/*
+	docinto gentoo_ice
+	dodoc "${WORKDIR}"/README
+}
+
+pkg_postinst() {
+	mp3_warning
+}
diff --git a/media-sound/audacious/files/digest-audacious-1.1.0_beta2 b/media-sound/audacious/files/digest-audacious-1.1.0_beta2
new file mode 100644
index 000000000000..d62a777c8729
--- /dev/null
+++ b/media-sound/audacious/files/digest-audacious-1.1.0_beta2
@@ -0,0 +1,6 @@
+MD5 98ecf3d0980341ce6645f5663550d21b audacious-1.1.0-dr2.tgz 3270998
+RMD160 1e91c41a3fd519674303b8b1207eab9a55768a51 audacious-1.1.0-dr2.tgz 3270998
+SHA256 620c31ac372a2f91c4afd419387244f324d6396a5e54ccd39e64ac954526a7fc audacious-1.1.0-dr2.tgz 3270998
+MD5 41eababfa8bad11e9e34e467cdfb86be gentoo_ice-xmms-0.2.tar.bz2 51839
+RMD160 11439cbebf8c6dc5745c8593a79e88303d094544 gentoo_ice-xmms-0.2.tar.bz2 51839
+SHA256 d1be63368b76f4a8b1d5b0e955cd7a77177f56a7f0b828c6603d8fd2836422b1 gentoo_ice-xmms-0.2.tar.bz2 51839