Version bump, thanks to Triffid Hunter <triffid_hunter@funkmunch.net> for the notice, bug #239989.

(Portage version: 2.2_rc12/cvs/Linux 2.6.27.3 x86_64)

2 files changed, 75 insertions, 1 deletions

diff --git a/media-video/dvdrip/ChangeLog b/media-video/dvdrip/ChangeLog
index 90714745a3ab..63f249359ba3 100644
--- a/media-video/dvdrip/ChangeLog
+++ b/media-video/dvdrip/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/dvdrip
 # Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/dvdrip/ChangeLog,v 1.112 2008/10/15 12:04:36 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/dvdrip/ChangeLog,v 1.113 2008/10/30 08:34:10 aballier Exp $
+
+*dvdrip-0.98.9 (30 Oct 2008)
+
+  30 Oct 2008; Alexis Ballier <aballier@gentoo.org> +dvdrip-0.98.9.ebuild:
+  Version bump, thanks to Triffid Hunter <triffid_hunter@funkmunch.net> for
+  the notice, bug #239989.
 
 *dvdrip-0.98.8-r3 (15 Oct 2008)
 
diff --git a/media-video/dvdrip/dvdrip-0.98.9.ebuild b/media-video/dvdrip/dvdrip-0.98.9.ebuild
new file mode 100644
index 000000000000..80b10bfbd378
--- /dev/null
+++ b/media-video/dvdrip/dvdrip-0.98.9.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/dvdrip/dvdrip-0.98.9.ebuild,v 1.1 2008/10/30 08:34:10 aballier Exp $
+
+EAPI=2
+
+inherit eutils flag-o-matic perl-module
+
+DESCRIPTION="Dvd::rip is a graphical frontend for transcode"
+HOMEPAGE="http://www.exit1.org/dvdrip/"
+SRC_URI="http://www.exit1.org/dvdrip/dist/${P}.tar.gz"
+
+LICENSE="Artistic GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="ffmpeg fping hal mplayer ogg subtitles vcd vorbis xine xvid"
+
+DEPEND=">=dev-perl/Event-ExecFlow-0.63
+	>=dev-perl/Event-RPC-0.89
+	dev-perl/gtk2-perl
+	>=dev-perl/gtk2-ex-formfactory-0.65
+	>=dev-perl/libintl-perl-1.16
+	media-gfx/imagemagick
+	<media-video/transcode-1.1.0_pre0[dvdread]"
+RDEPEND="${DEPEND}
+	x11-libs/gtk+:2[jpeg]
+	ffmpeg? ( media-video/ffmpeg )
+	fping? ( >=net-analyzer/fping-2.2 )
+	hal? ( >=sys-apps/hal-0.5 )
+	mplayer? ( media-video/mplayer )
+	ogg? ( media-sound/ogmtools )
+	subtitles? ( media-video/subtitleripper )
+	vcd? (
+		<media-video/transcode-1.1.0_pre0[mjpeg]
+		>=media-video/mjpegtools-1.6.0
+	)
+	vorbis? ( media-sound/vorbis-tools )
+	xine? ( media-video/xine-ui )
+	xvid? ( media-video/xvid4conf )
+	>=media-video/lsdvd-0.15"
+
+src_prepare() {
+	filter-flags "-ftracer"
+	sed -i -e 's:cc :$(CC) :' src/Makefile || die "sed failed"
+}
+
+src_install() {
+	newicon lib/Video/DVDRip/icon.xpm dvdrip.xpm
+	make_desktop_entry dvdrip dvd::rip dvdrip AudioVideo
+	DOCS="Changes Changes.0.46 Credits README TODO"
+
+	perl-module_src_install
+}
+
+pkg_postinst() {
+
+	# bug 173924
+	if use fping; then
+		ewarn "For dvdrip-master to work correctly with cluster mode,"
+		ewarn "the fping binary must be setuid."
+		ewarn ""
+		ewarn "Run this command to fix it:"
+		ewarn "chmod u=rwsx,g=rx,o=rx /usr/sbin/fping"
+		ewarn ""
+		ewarn "Note that this is a security risk when enabled."
+	fi
+
+}