Revision bump to remove broken static USE flag.

(Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

2 files changed, 77 insertions, 1 deletions

diff --git a/media-video/mediainfo/ChangeLog b/media-video/mediainfo/ChangeLog
index d2de3139587b..20623d88169c 100644
--- a/media-video/mediainfo/ChangeLog
+++ b/media-video/mediainfo/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-video/mediainfo
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.10 2011/01/30 22:56:14 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/ChangeLog,v 1.11 2011/01/30 23:08:41 radhermit Exp $
+
+*mediainfo-0.7.36-r1 (30 Jan 2011)
+
+  30 Jan 2011; Tim Harder <radhermit@gentoo.org> +mediainfo-0.7.36-r1.ebuild:
+  Revision bump to remove broken static USE flag.
 
 *mediainfo-0.7.41 (30 Jan 2011)
 
diff --git a/media-video/mediainfo/mediainfo-0.7.36-r1.ebuild b/media-video/mediainfo/mediainfo-0.7.36-r1.ebuild
new file mode 100644
index 000000000000..4fa7af840cd5
--- /dev/null
+++ b/media-video/mediainfo/mediainfo-0.7.36-r1.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mediainfo/mediainfo-0.7.36-r1.ebuild,v 1.1 2011/01/30 23:08:41 radhermit Exp $
+
+EAPI="2"
+
+WX_GTK_VER="2.8"
+inherit autotools wxwidgets multilib
+
+DESCRIPTION="MediaInfo supplies technical and tag information about media files"
+HOMEPAGE="http://mediainfo.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/source/${PN}/${PV}/${PN}_${PV}.tar.bz2"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl debug libmms wxwidgets"
+
+RDEPEND="sys-libs/zlib
+	media-libs/libzen
+	~media-libs/lib${P}[curl=,libmms=]
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S="${WORKDIR}/MediaInfo"
+
+pkg_setup() {
+	TARGETS="CLI"
+	use wxwidgets && TARGETS+=" GUI"
+}
+
+src_prepare() {
+	for x in ${TARGETS}; do
+		cd "${S}/Project/GNU/${x}"
+		eautoreconf
+	done
+}
+
+src_configure() {
+	for target in ${TARGETS}; do
+		cd "${S}/Project/GNU/${target}"
+		local myconf=""
+		[[ ${target} == "GUI" ]] && myconf="${myconf} --with-wxwidgets --with-wx-gui"
+		econf \
+			${myconf} \
+			--disable-dependency-tracking \
+			--enable-shared \
+			$(use_enable debug)
+	done
+}
+
+src_compile() {
+	for x in ${TARGETS}; do
+		cd "${S}/Project/GNU/${x}"
+		emake || die "emake failed for ${x}"
+	done
+}
+src_install() {
+	for x in ${TARGETS}; do
+		cd "${S}/Project/GNU/${x}"
+		emake DESTDIR="${D}" install || die "emake install failed"
+		dodoc "${S}/History_${x}.txt" || die
+		if [[ "${x}" = "GUI" ]]; then
+			newicon "${S}/Source/Ressource/Image/MediaInfo.png" "${PN}.png"
+			make_desktop_entry "${PN}-gui" "MediaInfo" "${PN}" "AudioVideo;GTK;"
+		fi
+	done
+
+	dodoc "${S}/"*.html || die
+}