Introduce USE=libav to control the preferred implementation. Fixes subslot & implementation switch rebuilds as well.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

4 files changed, 532 insertions, 8 deletions

diff --git a/media-video/mpv/ChangeLog b/media-video/mpv/ChangeLog
index 17805bfc852f..40da01808f93 100644
--- a/media-video/mpv/ChangeLog
+++ b/media-video/mpv/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for media-video/mpv
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/ChangeLog,v 1.112 2015/01/05 02:11:15 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/ChangeLog,v 1.113 2015/02/01 22:34:52 mgorny Exp $
+
+*mpv-0.3.11-r1 (01 Feb 2015)
+*mpv-0.7.2-r1 (01 Feb 2015)
+
+  01 Feb 2015; Michał Górny <mgorny@gentoo.org> +mpv-0.3.11-r1.ebuild,
+  +mpv-0.7.2-r1.ebuild, mpv-9999.ebuild:
+  Introduce USE=libav to control the preferred implementation. Fixes subslot &
+  implementation switch rebuilds as well.
 
   05 Jan 2015; Yixun Lan <dlan@gentoo.org> mpv-9999.ebuild:
   remove USE=portaudio from live ebuild, bug 534018, thanks Perfect Gentleman,
diff --git a/media-video/mpv/mpv-0.3.11-r1.ebuild b/media-video/mpv/mpv-0.3.11-r1.ebuild
new file mode 100644
index 000000000000..c9ec3172ceed
--- /dev/null
+++ b/media-video/mpv/mpv-0.3.11-r1.ebuild
@@ -0,0 +1,252 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/mpv-0.3.11-r1.ebuild,v 1.1 2015/02/01 22:34:52 mgorny Exp $
+
+EAPI=5
+
+EGIT_REPO_URI="https://github.com/mpv-player/mpv.git"
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit eutils python-any-r1 waf-utils pax-utils fdo-mime gnome2-utils
+[[ ${PV} == *9999* ]] && inherit git-r3
+
+WAF_V="1.7.15"
+
+DESCRIPTION="Video player based on MPlayer/mplayer2"
+HOMEPAGE="http://mpv.io/"
+SRC_URI="https://waf.googlecode.com/files/waf-${WAF_V}"
+[[ ${PV} == *9999* ]] || \
+SRC_URI+=" https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+[[ ${PV} == *9999* ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
+IUSE="+alsa bluray bs2b +cdio -doc-pdf dvb +dvd dvdnav +enca encode +iconv jack -joystick
+jpeg ladspa lcms +libass libav libcaca libguess lirc lua luajit +mpg123 -openal +opengl
+oss portaudio +postproc pulseaudio pvr +quvi -radio samba sdl selinux +shm v4l vaapi vcd vdpau
+vf-dlopen wayland +X xinerama +xscreensaver +xv"
+
+REQUIRED_USE="
+	dvdnav? ( dvd )
+	enca? ( iconv )
+	lcms? ( opengl )
+	libguess? ( iconv )
+	luajit? ( lua )
+	opengl? ( || ( wayland X ) )
+	pvr? ( v4l )
+	radio? ( v4l || ( alsa oss ) )
+	vaapi? ( X )
+	vdpau? ( X )
+	wayland? ( opengl )
+	xinerama? ( X )
+	xscreensaver? ( X )
+	xv? ( X )
+"
+
+RDEPEND+="
+	libav? ( >=media-video/libav-9.10:0=[encode?,threads,vaapi?,vdpau?] )
+	!libav? ( >=media-video/ffmpeg-1.2.4:0=[encode?,threads,vaapi?,vdpau?] )
+	sys-libs/ncurses
+	sys-libs/zlib
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		x11-libs/libXxf86vm
+		opengl? ( virtual/opengl )
+		lcms? ( media-libs/lcms:2 )
+		vaapi? ( >=x11-libs/libva-0.34.0[X(+)] )
+		vdpau? ( >=x11-libs/libvdpau-0.2 )
+		xinerama? ( x11-libs/libXinerama )
+		xscreensaver? ( x11-libs/libXScrnSaver )
+		xv? ( x11-libs/libXv )
+	)
+	alsa? ( media-libs/alsa-lib )
+	bluray? ( >=media-libs/libbluray-0.2.1 )
+	bs2b? ( media-libs/libbs2b )
+	cdio? (
+		dev-libs/libcdio
+		dev-libs/libcdio-paranoia
+	)
+	dvb? ( virtual/linuxtv-dvb-headers )
+	dvd? (
+		>=media-libs/libdvdread-4.1.3
+		dvdnav? ( >=media-libs/libdvdnav-4.2.0 )
+	)
+	enca? ( app-i18n/enca )
+	iconv? ( virtual/libiconv )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg? ( virtual/jpeg:0 )
+	ladspa? ( media-libs/ladspa-sdk )
+	libass? (
+		>=media-libs/libass-0.9.10:=[enca?,fontconfig]
+		virtual/ttf-fonts
+	)
+	libcaca? ( >=media-libs/libcaca-0.99_beta18 )
+	libguess? ( >=app-i18n/libguess-1.0 )
+	lirc? ( app-misc/lirc )
+	lua? (
+		!luajit? ( >=dev-lang/lua-5.1 )
+		luajit? ( dev-lang/luajit:2 )
+	)
+	mpg123? ( >=media-sound/mpg123-1.14.0 )
+	openal? ( >=media-libs/openal-1.13 )
+	portaudio? ( >=media-libs/portaudio-19_pre20111121 )
+	postproc? (
+		libav? ( media-libs/libpostproc:0= )
+		!libav? ( >=media-video/ffmpeg-1.2:0=[encode?,threads,vaapi?,vdpau?] )
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	quvi? (
+		>=media-libs/libquvi-0.4.1:=
+		libav? ( >=media-video/libav-9.10:0=[network] )
+		!libav? ( >=media-video/ffmpeg-1.2.4:0=[network] )
+	)
+	samba? ( net-fs/samba )
+	sdl? ( media-libs/libsdl2[threads] )
+	v4l? ( media-libs/libv4l )
+	wayland? (
+		>=dev-libs/wayland-1.3.0
+		media-libs/mesa[egl,wayland]
+		>=x11-libs/libxkbcommon-0.3.0
+	)
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	>=dev-lang/perl-5.8
+	dev-python/docutils
+	doc-pdf? (
+		dev-texlive/texlive-latex
+		dev-texlive/texlive-latexrecommended
+		dev-texlive/texlive-latexextra
+		dev-tex/xcolor
+	)
+	X? (
+		x11-proto/videoproto
+		x11-proto/xf86vidmodeproto
+		xinerama? ( x11-proto/xineramaproto )
+		xscreensaver? ( x11-proto/scrnsaverproto )
+	)
+"
+RDEPEND+="
+	selinux? ( sec-policy/selinux-mplayer )
+"
+DOCS=( Copyright README.md etc/example.conf etc/input.conf )
+
+pkg_setup() {
+	if use !libass; then
+		ewarn
+		ewarn "You've disabled the libass flag. No OSD or subtitles will be displayed."
+	fi
+
+	einfo "For additional format support you need to enable the support on your"
+	einfo "libavcodec/libavformat provider:"
+	einfo "    media-video/libav or media-video/ffmpeg"
+
+	python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]]; then
+		git-r3_src_unpack
+	else
+		default_src_unpack
+	fi
+
+	cp "${DISTDIR}"/waf-${WAF_V} "${S}"/waf || die
+	chmod 0755 "${S}"/waf || die
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-libav-9.patch"
+	epatch_user
+}
+
+src_configure() {
+	# keep build reproducible
+	# do not add -g to CFLAGS
+	# SDL output is fallback for platforms where nothing better is available
+	# media-sound/rsound is in pro-audio overlay only
+	waf-utils_src_configure \
+		--disable-build-date \
+		--disable-debug-build \
+		--disable-sdl \
+		$(use_enable sdl sdl2) \
+		--disable-rsound \
+		$(use_enable encode encoding) \
+		$(use_enable joystick) \
+		$(use_enable bluray libbluray) \
+		$(use_enable vcd) \
+		$(use_enable quvi libquvi) \
+		$(use_enable samba libsmbclient) \
+		$(use_enable lirc) \
+		$(use_enable lua) \
+		$(usex luajit '--lua=luajit' '') \
+		$(use_enable doc-pdf pdf-build) \
+		$(use_enable vf-dlopen vf-dlopen-filters) \
+		$(use_enable cdio cdda) \
+		$(use_enable dvd dvdread) \
+		$(use_enable dvdnav) \
+		$(use_enable enca) \
+		$(use_enable iconv) \
+		$(use_enable libass) \
+		$(use_enable libguess) \
+		$(use_enable dvb) \
+		$(use_enable pvr) \
+		$(use_enable v4l libv4l2) \
+		$(use_enable v4l tv) \
+		$(use_enable v4l tv-v4l2) \
+		$(use_enable radio) \
+		$(use_enable radio radio-capture) \
+		$(use_enable radio radio-v4l2) \
+		$(use_enable mpg123) \
+		$(use_enable jpeg) \
+		$(use_enable libcaca caca) \
+		$(use_enable postproc libpostproc) \
+		$(use_enable alsa) \
+		$(use_enable jack) \
+		$(use_enable ladspa) \
+		$(use_enable portaudio) \
+		$(use_enable bs2b libbs2b) \
+		$(use_enable openal) \
+		$(use_enable oss oss-audio) \
+		$(use_enable pulseaudio pulse) \
+		$(use_enable shm) \
+		$(use_enable X x11) \
+		$(use_enable vaapi) \
+		$(use_enable vdpau) \
+		$(use_enable wayland) \
+		$(use_enable xinerama) \
+		$(use_enable xv) \
+		$(use_enable opengl gl) \
+		$(use_enable lcms lcms2) \
+		$(use_enable xscreensaver xss) \
+		--confdir="${EPREFIX}"/etc/${PN} \
+		--mandir="${EPREFIX}"/usr/share/man \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+}
+
+src_install() {
+	waf-utils_src_install
+
+	if use luajit; then
+		pax-mark -m "${ED}"usr/bin/mpv
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-video/mpv/mpv-0.7.2-r1.ebuild b/media-video/mpv/mpv-0.7.2-r1.ebuild
new file mode 100644
index 000000000000..407f7c7aa936
--- /dev/null
+++ b/media-video/mpv/mpv-0.7.2-r1.ebuild
@@ -0,0 +1,266 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/mpv-0.7.2-r1.ebuild,v 1.1 2015/02/01 22:34:52 mgorny Exp $
+
+EAPI=5
+
+EGIT_REPO_URI="https://github.com/mpv-player/mpv.git"
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+PYTHON_REQ_USE='threads(+)'
+
+inherit eutils python-any-r1 waf-utils pax-utils fdo-mime gnome2-utils
+[[ ${PV} == *9999* ]] && inherit git-r3
+
+WAF_V="1.8.1"
+
+DESCRIPTION="Video player based on MPlayer/mplayer2"
+HOMEPAGE="http://mpv.io/"
+SRC_URI="http://ftp.waf.io/pub/release/waf-${WAF_V}"
+[[ ${PV} == *9999* ]] || \
+SRC_URI+=" https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+[[ ${PV} == *9999* ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
+IUSE="+alsa bluray bs2b cdio +cli -doc-pdf dvb +dvd dvdnav egl +enca encode
++iconv jack -joystick jpeg ladspa lcms +libass libav libcaca libguess libmpv
+lirc lua luajit +mpg123 -openal +opengl oss -portaudio postproc pulseaudio pvr
+samba -sdl selinux v4l vaapi vdpau vf-dlopen wayland +X xinerama +xscreensaver
++xv"
+
+REQUIRED_USE="
+	|| ( cli libmpv )
+	dvdnav? ( dvd )
+	egl? ( opengl X )
+	enca? ( iconv )
+	lcms? ( opengl )
+	libguess? ( iconv )
+	luajit? ( lua )
+	opengl? ( || ( wayland X ) )
+	pvr? ( v4l )
+	vaapi? ( X )
+	vdpau? ( X )
+	wayland? ( opengl )
+	xinerama? ( X )
+	xscreensaver? ( X )
+	xv? ( X )
+"
+
+RDEPEND="
+	libav? ( >=media-video/libav-10:0=[encode?,threads,vaapi?,vdpau?] )
+	!libav? ( >=media-video/ffmpeg-2.1.4:0=[encode?,threads,vaapi?,vdpau?] )
+	sys-libs/zlib
+	X? (
+		x11-libs/libX11
+		x11-libs/libXext
+		>=x11-libs/libXrandr-1.2.0
+		opengl? (
+			virtual/opengl
+			egl? ( media-libs/mesa[egl] )
+		)
+		lcms? ( >=media-libs/lcms-2.6:2 )
+		vaapi? ( >=x11-libs/libva-0.34.0[X(+),opengl?] )
+		vdpau? ( >=x11-libs/libvdpau-0.2 )
+		xinerama? ( x11-libs/libXinerama )
+		xscreensaver? ( x11-libs/libXScrnSaver )
+		xv? ( x11-libs/libXv )
+	)
+	alsa? ( >=media-libs/alsa-lib-1.0.18 )
+	bluray? ( >=media-libs/libbluray-0.3.0 )
+	bs2b? ( media-libs/libbs2b )
+	cdio? (
+		dev-libs/libcdio
+		dev-libs/libcdio-paranoia
+	)
+	dvb? ( virtual/linuxtv-dvb-headers )
+	dvd? (
+		>=media-libs/libdvdread-4.1.3
+		dvdnav? ( >=media-libs/libdvdnav-4.2.0 )
+	)
+	enca? ( app-i18n/enca )
+	iconv? ( virtual/libiconv )
+	jack? ( media-sound/jack-audio-connection-kit )
+	jpeg? ( virtual/jpeg:0 )
+	ladspa? ( media-libs/ladspa-sdk )
+	libass? (
+		>=media-libs/libass-0.9.10:=[enca?,fontconfig]
+		virtual/ttf-fonts
+	)
+	libcaca? ( >=media-libs/libcaca-0.99_beta18 )
+	libguess? ( >=app-i18n/libguess-1.0 )
+	lirc? ( app-misc/lirc )
+	lua? (
+		!luajit? ( >=dev-lang/lua-5.1 )
+		luajit? ( dev-lang/luajit:2 )
+	)
+	mpg123? ( >=media-sound/mpg123-1.14.0 )
+	openal? ( >=media-libs/openal-1.13 )
+	portaudio? ( >=media-libs/portaudio-19_pre20111121 )
+	postproc? (
+		libav? ( >=media-libs/libpostproc-10.20140517:0= )
+		!libav? ( >=media-video/ffmpeg-2.1.4:0= )
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( net-fs/samba )
+	sdl? ( media-libs/libsdl2[threads] )
+	v4l? ( media-libs/libv4l )
+	wayland? (
+		>=dev-libs/wayland-1.6.0
+		media-libs/mesa[egl,wayland]
+		>=x11-libs/libxkbcommon-0.3.0
+	)
+"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	>=dev-lang/perl-5.8
+	dev-python/docutils
+	doc-pdf? ( dev-python/rst2pdf )
+	X? (
+		x11-proto/videoproto
+		xinerama? ( x11-proto/xineramaproto )
+		xscreensaver? ( x11-proto/scrnsaverproto )
+	)
+"
+RDEPEND+="
+	selinux? ( sec-policy/selinux-mplayer )
+"
+DOCS=( Copyright README.md etc/example.conf etc/input.conf )
+
+pkg_setup() {
+	if use !libass; then
+		ewarn
+		ewarn "You've disabled the libass flag. No OSD or subtitles will be displayed."
+	fi
+
+	einfo "For additional format support you need to enable the support on your"
+	einfo "libavcodec/libavformat provider:"
+	einfo "    media-video/libav or media-video/ffmpeg"
+
+	python-any-r1_pkg_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == *9999* ]]; then
+		git-r3_src_unpack
+	else
+		default_src_unpack
+	fi
+
+	cp "${DISTDIR}"/waf-${WAF_V} "${S}"/waf || die
+	chmod 0755 "${S}"/waf || die
+}
+
+src_prepare() {
+	epatch_user
+}
+
+src_configure() {
+	local mywafargs=(
+		--confdir="${EPREFIX}"/etc/${PN}
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+		$(usex cli '' '--disable-cplayer')
+		$(use_enable libmpv libmpv-shared)
+		--disable-libmpv-static
+		--disable-build-date	# keep build reproducible
+		--disable-optimize	# do not add '-O2' to CFLAGS
+		--disable-debug-build	# do not add '-g' to CFLAGS
+		$(use_enable doc-pdf pdf-build)
+		$(use_enable vf-dlopen vf-dlopen-filters)
+		$(use_enable cli zsh-comp)
+
+		# optional features
+		$(use_enable iconv)
+		$(use_enable libguess)
+		$(use_enable samba libsmbclient)
+		$(use_enable lua)
+		$(use_enable libass)
+		$(use_enable libass libass-osd)
+		$(use_enable encode encoding)
+		$(use_enable joystick)
+		$(use_enable lirc)
+		$(use_enable bluray libbluray)
+		$(use_enable dvd dvdread)
+		$(use_enable dvdnav)
+		$(use_enable cdio cdda)
+		$(use_enable enca)
+		$(use_enable mpg123)
+		$(use_enable ladspa)
+		$(use_enable bs2b libbs2b)
+		$(use_enable lcms lcms2)
+		--disable-vapoursynth	# vapoursynth is not packaged
+		--disable-vapoursynth-lazy
+		--enable-libavfilter
+		--enable-libavdevice
+		$(use_enable postproc libpostproc)
+		$(usex luajit '--lua=luajit' '')
+
+		# audio outputs
+		$(use_enable sdl sdl2)	# SDL output is fallback for platforms where nothing better is available
+		--disable-sdl1
+		$(use_enable oss oss-audio)
+		--disable-rsound	# media-sound/rsound is in pro-audio overlay only
+		$(use_enable pulseaudio pulse)
+		$(use_enable portaudio)
+		$(use_enable jack)
+		$(use_enable openal)
+		$(use_enable alsa)
+
+		# video outputs
+		$(use_enable wayland)
+		$(use_enable X x11)
+		$(use_enable xscreensaver xss)
+		$(use_enable X xext)
+		$(use_enable xv)
+		$(use_enable xinerama)
+		$(use_enable X xrandr)
+		$(usex X "$(use_enable opengl gl-x11)" '--disable-gl-x11')
+		$(use_enable egl egl-x11)
+		$(usex wayland "$(use_enable opengl gl-wayland)" '--disable-gl-wayland')
+		$(use_enable opengl gl)
+		$(use_enable vdpau)
+		$(usex vdpau "$(use_enable opengl vdpau-gl-x11)" '--disable-vdpau-gl-x11')
+		$(use_enable vaapi)
+		$(use_enable vaapi vaapi-vpp)
+		$(usex vaapi "$(use_enable opengl vaapi-glx)" '--disable-vaapi-glx')
+		$(use_enable libcaca caca)
+		$(use_enable jpeg)
+
+		# hwaccels
+		$(use_enable vaapi vaapi-hwaccel)
+		$(use_enable vdpau vdpau-hwaccel)
+
+		# tv features
+		$(use_enable v4l tv)
+		$(use_enable v4l tv-v4l2)
+		$(use_enable v4l libv4l2)
+		$(use_enable pvr)
+		$(use_enable dvb)
+		$(use_enable dvb dvbin)
+	)
+	waf-utils_src_configure "${mywafargs[@]}"
+}
+
+src_install() {
+	waf-utils_src_install
+
+	if use cli && use luajit; then
+		pax-mark -m "${ED}"usr/bin/mpv
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-video/mpv/mpv-9999.ebuild b/media-video/mpv/mpv-9999.ebuild
index 6dd816ec96eb..e5bb2e5d33df 100644
--- a/media-video/mpv/mpv-9999.ebuild
+++ b/media-video/mpv/mpv-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/mpv-9999.ebuild,v 1.64 2015/01/05 02:11:15 dlan Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/mpv-9999.ebuild,v 1.65 2015/02/01 22:34:52 mgorny Exp $
 
 EAPI=5
 
@@ -25,8 +25,8 @@ SLOT="0"
 [[ ${PV} == *9999* ]] || \
 KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
 IUSE="+alsa bluray bs2b cdio +cli -doc-pdf dvb +dvd dvdnav egl +enca encode
-+iconv jack -joystick jpeg ladspa lcms +libass libcaca libguess libmpv lirc lua
-luajit +mpg123 -openal +opengl oss pulseaudio pvr samba -sdl selinux
++iconv jack -joystick jpeg ladspa lcms +libass libav libcaca libguess libmpv
+lirc lua luajit +mpg123 -openal +opengl oss pulseaudio pvr samba -sdl selinux
 v4l vaapi vdpau vf-dlopen wayland +X xinerama +xscreensaver +xv"
 
 REQUIRED_USE="
@@ -48,10 +48,8 @@ REQUIRED_USE="
 "
 
 RDEPEND="
-	|| (
-		>=media-video/libav-10:=[encode?,threads,vaapi?,vdpau?]
-		>=media-video/ffmpeg-2.1.4:0=[encode?,threads,vaapi?,vdpau?]
-	)
+	libav? ( >=media-video/libav-10:0=[encode?,threads,vaapi?,vdpau?] )
+	!libav? ( >=media-video/ffmpeg-2.1.4:0=[encode?,threads,vaapi?,vdpau?] )
 	sys-libs/zlib
 	X? (
 		x11-libs/libX11