Import live ebuild from the multimedia overlay (requested by Nikoli).

(Portage version: 2.2.0_alpha37/cvs/Linux x86_64)

3 files changed, 84 insertions, 1 deletions

diff --git a/media-video/x264-encoder/ChangeLog b/media-video/x264-encoder/ChangeLog
index 4ba6efc65682..3c758af06ce7 100644
--- a/media-video/x264-encoder/ChangeLog
+++ b/media-video/x264-encoder/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/x264-encoder
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v 1.49 2011/04/27 17:20:43 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/ChangeLog,v 1.50 2011/05/28 12:04:21 radhermit Exp $
+
+*x264-encoder-9999 (28 May 2011)
+
+  28 May 2011; Tim Harder <radhermit@gentoo.org> +x264-encoder-9999.ebuild,
+  metadata.xml:
+  Import live ebuild from the multimedia overlay (requested by Nikoli).
 
 *x264-encoder-0.0.20110426 (27 Apr 2011)
 
diff --git a/media-video/x264-encoder/metadata.xml b/media-video/x264-encoder/metadata.xml
index c572c7d9b478..baa755b35bb5 100644
--- a/media-video/x264-encoder/metadata.xml
+++ b/media-video/x264-encoder/metadata.xml
@@ -5,4 +5,7 @@
   <maintainer>
     <email>media-video@gentoo.org</email>
   </maintainer>
+  <use>
+    <flag name="system-libx264">Use the system x264 library</flag>
+  </use>
 </pkgmetadata>
diff --git a/media-video/x264-encoder/x264-encoder-9999.ebuild b/media-video/x264-encoder/x264-encoder-9999.ebuild
new file mode 100644
index 000000000000..51167bf57478
--- /dev/null
+++ b/media-video/x264-encoder/x264-encoder-9999.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/x264-encoder/x264-encoder-9999.ebuild,v 1.1 2011/05/28 12:04:21 radhermit Exp $
+
+EAPI=4
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	V_ECLASS="git-2"
+else
+	V_ECLASS="versionator"
+fi
+
+inherit multilib toolchain-funcs ${V_ECLASS}
+
+if [ "${PV#9999}" = "${PV}" ] ; then
+	MY_P="x264-snapshot-$(get_version_component_range 3)-2245"
+fi
+DESCRIPTION="A free commandline encoder for X264/AVC streams"
+HOMEPAGE="http://www.videolan.org/developers/x264.html"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	EGIT_REPO_URI="git://git.videolan.org/x264.git"
+	SRC_URI=""
+else
+	SRC_URI="http://ftp.videolan.org/pub/videolan/x264/snapshots/${MY_P}.tar.bz2"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+if [ "${PV#9999}" != "${PV}" ] ; then
+	KEYWORDS=""
+else
+	KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+fi
+IUSE="debug ffmpeg mp4 +system-libx264 +threads"
+
+RDEPEND="
+	ffmpeg? ( media-video/ffmpeg )
+	mp4? ( >=media-video/gpac-0.4.1_pre20060122 )
+	system-libx264? ( ~media-libs/x264-${PV} )
+"
+ASM_DEP=">=dev-lang/yasm-0.6.2"
+DEPEND="${RDEPEND}
+	amd64? ( ${ASM_DEP} )
+	x86? ( || ( ${ASM_DEP} dev-lang/nasm )
+		!<dev-lang/yasm-0.6.2 )
+	x86-fbsd? ( ${ASM_DEP} )
+	dev-util/pkgconfig
+"
+if [ "${PV#9999}" = "${PV}" ] ; then
+	S=${WORKDIR}/${MY_P}
+fi
+
+src_configure() {
+	tc-export CC
+
+	local myconf=""
+	use debug && myconf+=" --enable-debug"
+	use ffmpeg || myconf+=" --disable-lavf --disable-swscale"
+	use mp4 || myconf+=" --disable-gpac"
+	use system-libx264 && myconf+=" --system-libx264"
+	use threads || myconf+=" --disable-thread"
+
+	./configure \
+		--prefix="${EPREFIX}"/usr \
+		--libdir="${EPREFIX}"/usr/$(get_libdir) \
+		--disable-avs \
+		--disable-ffms \
+		--extra-asflags="${ASFLAGS}" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-ldflags="${LDFLAGS}" \
+		--host="${CHOST}" \
+		${myconf} \
+		|| die
+}