Use Ubuntu mirrors for sources and patch. Respect LDFLAGS (bug #337480), CC. Fix quoting issues. Use make to install.

(Portage version: 2.2_rc81/cvs/Linux i686)

1 files changed, 45 insertions, 0 deletions

diff --git a/net-analyzer/rain/rain-1.2.9_beta1.ebuild b/net-analyzer/rain/rain-1.2.9_beta1.ebuild
new file mode 100644
index 000000000000..89b7abd0eb08
--- /dev/null
+++ b/net-analyzer/rain/rain-1.2.9_beta1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/rain/rain-1.2.9_beta1.ebuild,v 1.1 2010/09/15 16:11:56 jer Exp $
+
+EAPI="2"
+
+inherit autotools eutils
+
+MY_P=${P/_/}
+MY_P=${MY_P/-/_}
+DESCRIPTION="powerful tool for testing stability of hardware and software utilizing IP protocols"
+HOMEPAGE="http://www.mirrors.wiretapped.net/security/packet-construction/rain/"
+SRC_URI="
+	mirror://ubuntu/pool/universe/r/${PN}/${MY_P}.orig.tar.gz
+	mirror://ubuntu/pool/universe/r/${PN}/${MY_P}-1.diff.gz
+"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE=""
+
+DEPEND=""
+
+S="${WORKDIR}/${MY_P/_/-}"
+
+src_prepare() {
+	# Debian patch
+	epatch "${WORKDIR}"/${MY_P}-1.diff
+
+	# respect CFLAGS, LDFLAGS, correct man path
+	sed -i Makefile.in \
+		-e 's|-g|@CFLAGS@|' \
+		-e 's|/usr/local/man|/usr/share/man|g' \
+		-e 's|$(CC) -o|$(CC) $(CFLAGS) $(LDFLAGS) -o|g' \
+		|| die "sed Makefile.in"
+
+	# generate a new configure that respects/exports CC
+	eautoreconf
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install"
+	dodoc BUGS CHANGES README TODO
+}