Version bump.

(Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

2 files changed, 60 insertions, 1 deletions

diff --git a/net-analyzer/mtr/ChangeLog b/net-analyzer/mtr/ChangeLog
index 40d1c0edf100..fa587b38d6a5 100644
--- a/net-analyzer/mtr/ChangeLog
+++ b/net-analyzer/mtr/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/mtr
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/mtr/ChangeLog,v 1.108 2011/10/10 02:10:58 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/mtr/ChangeLog,v 1.109 2011/12/05 10:36:38 radhermit Exp $
+
+*mtr-0.82 (05 Dec 2011)
+
+  05 Dec 2011; Tim Harder <radhermit@gentoo.org> +mtr-0.82.ebuild:
+  Version bump.
 
 *mtr-0.81 (10 Oct 2011)
 
diff --git a/net-analyzer/mtr/mtr-0.82.ebuild b/net-analyzer/mtr/mtr-0.82.ebuild
new file mode 100644
index 000000000000..668c366f52da
--- /dev/null
+++ b/net-analyzer/mtr/mtr-0.82.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/mtr/mtr-0.82.ebuild,v 1.1 2011/12/05 10:36:38 radhermit Exp $
+
+EAPI="4"
+
+inherit eutils autotools flag-o-matic
+
+DESCRIPTION="My TraceRoute, an Excellent network diagnostic tool"
+HOMEPAGE="http://www.bitwizard.nl/mtr/"
+SRC_URI="ftp://ftp.bitwizard.nl/mtr/${P}.tar.gz
+	mirror://gentoo/gtk-2.0-for-mtr.m4.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="gtk ipv6 suid"
+
+RDEPEND="
+	sys-libs/ncurses
+	gtk? ( x11-libs/gtk+:2 )"
+DEPEND="${RDEPEND}
+	gtk? ( dev-util/pkgconfig )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/0.80-impl-dec.patch
+
+	# Keep this comment and following mv, even in case ebuild does not need
+	# it: kept gtk-2.0.m4 in SRC_URI but you'll have to mv it before autoreconf
+	mv "${WORKDIR}"/gtk-2.0-for-mtr.m4 gtk-2.0.m4 #222909
+	AT_M4DIR="." eautoreconf
+}
+src_configure() {
+	# In the source's configure script -lresolv is commented out. Apparently it
+	# is needed for 64bit macos still.
+	[[ ${CHOST} == *-darwin* ]] && append-libs -lresolv
+	econf \
+		$(use_with gtk) \
+		$(use_enable ipv6)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS FORMATS NEWS README SECURITY TODO
+
+	if use !prefix ; then
+		fowners root:0 /usr/sbin/mtr
+		if use suid; then
+			fperms 4711 /usr/sbin/mtr
+		else
+			fperms 0710 /usr/sbin/mtr
+		fi
+	fi
+}