remove old revisions, fix QA warnings, add live ebuild.

(Portage version: 2.2_rc3/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

1 files changed, 57 insertions, 0 deletions

diff --git a/net-ftp/gftp/gftp-9999.ebuild b/net-ftp/gftp/gftp-9999.ebuild
new file mode 100644
index 000000000000..fe26325fc983
--- /dev/null
+++ b/net-ftp/gftp/gftp-9999.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-ftp/gftp/gftp-9999.ebuild,v 1.1 2008/07/27 21:02:52 eva Exp $
+
+inherit autotools eutils subversion
+
+DESCRIPTION="Gnome based FTP Client"
+ESVN_REPO_URI="http://svn.gnome.org/svn/${PN}/trunk"
+#SRC_URI="http://www.gftp.org/${P}.tar.bz2"
+HOMEPAGE="http://www.gftp.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS=""
+IUSE="gtk ssl"
+
+RDEPEND=">=dev-libs/glib-2
+		 sys-libs/ncurses
+		 sys-libs/readline
+		 gtk? ( >=x11-libs/gtk+-2 )
+		 ssl? ( dev-libs/openssl )"
+DEPEND="${RDEPEND}
+		  sys-devel/gettext
+		>=dev-util/intltool-0.35.5
+		>=dev-util/pkgconfig-0.9"
+
+src_unpack() {
+	subversion_src_unpack
+	cd "${S}"
+
+	# remove annoying/deprecated macros
+	sed -i -e "s/^\(AC_AIX\|AC_MINIX\)//g" configure.in
+	sed -i -e "s/AM_PATH_\(GLIB\|GTK\).*/AC_DEFINE(dummy, 1, [dummy])/g" configure.in
+
+	# Switching gettext to intltool
+	sed -i "s/AM_GNU_GETTEXT/IT_PROG_INTLTOOL(0.35.5)\nGETTEXT_PACKAGE=gftp\nAC_SUBST(GETTEXT_PACKAGE)\nAM_GLIB_GNU_GETTEXT/" configure.in
+	sed -i "s:intl/Makefile::" configure.in
+	sed -i "s:intl::g" Makefile.am
+	sed -i "s:LIBINTL:INTLLIBS:g" src/{gtk,text}/Makefile.am
+
+	intltoolize --force || die "intltoolize failed"
+	AT_M4DIR="." eautoreconf
+}
+
+src_compile() {
+	econf \
+		$(use_enable gtk gtkport) \
+		$(use_enable gtk gtk20) \
+		$(use_enable ssl) \
+		--enable-textport || die "configure failed"
+	emake || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "install failed"
+	dodoc ChangeLog* README* THANKS TODO docs/USERS-GUIDE
+}