Version bump for Gnome 3.8

(Portage version: 2.1.11.58/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

2 files changed, 58 insertions, 2 deletions

diff --git a/net-libs/gssdp/ChangeLog b/net-libs/gssdp/ChangeLog
index 4e469133e36f..2f34de63ae1c 100644
--- a/net-libs/gssdp/ChangeLog
+++ b/net-libs/gssdp/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for net-libs/gssdp
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/gssdp/ChangeLog,v 1.53 2012/10/28 16:23:09 armin76 Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gssdp/ChangeLog,v 1.54 2013/03/28 17:49:02 pacho Exp $
+
+*gssdp-0.14.2 (28 Mar 2013)
+
+  28 Mar 2013; Pacho Ramos <pacho@gentoo.org> +gssdp-0.14.2.ebuild:
+  Version bump for Gnome 3.8
 
   28 Oct 2012; Raúl Porcel <armin76@gentoo.org> gssdp-0.12.2.1.ebuild:
   ia64/sparc stable wrt #427544
diff --git a/net-libs/gssdp/gssdp-0.14.2.ebuild b/net-libs/gssdp/gssdp-0.14.2.ebuild
new file mode 100644
index 000000000000..761d88a48bb4
--- /dev/null
+++ b/net-libs/gssdp/gssdp-0.14.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/gssdp/gssdp-0.14.2.ebuild,v 1.1 2013/03/28 17:49:02 pacho Exp $
+
+EAPI=5
+VALA_MIN_API_VERSION="0.14"
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils gnome.org multilib vala
+
+DESCRIPTION="A GObject-based API for handling resource discovery and announcement over SSDP."
+HOMEPAGE="http://gupnp.org/"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="+introspection +gtk"
+
+RDEPEND=">=dev-libs/glib-2.32:2
+	>=net-libs/libsoup-2.26.1:2.4[introspection?]
+	gtk? ( >=x11-libs/gtk+-2.12:2 )
+	introspection? (
+		>=dev-libs/gobject-introspection-0.6.7
+		$(vala_depend)
+	)
+	!<net-libs/gupnp-vala-0.10.3
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+src_prepare() {
+	# Disable functional test as it requires port that might be used by rygel to
+	# be free of use
+	sed 's/\(check_PROGRAMS.*\)test-functional$(EXEEXT)/\1/' \
+		-i "${S}"/tests/gtest/Makefile.in || die
+	use introspection && vala_src_prepare
+}
+
+src_configure() {
+	econf \
+		$(use_enable introspection) \
+		$(use_with gtk) \
+		--disable-static \
+		--disable-gtk-doc
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}