Fixed dependencies (added xmlrpc USE flag for that), added scripts USE flag to install optional scripts.

(Portage version: 2.2_rc46/cvs/Linux x86_64)

3 files changed, 99 insertions, 1 deletions

diff --git a/net-misc/aria2/ChangeLog b/net-misc/aria2/ChangeLog
index f43212ff98de..59614ff33e7e 100644
--- a/net-misc/aria2/ChangeLog
+++ b/net-misc/aria2/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/aria2
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v 1.51 2009/11/14 19:12:21 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/ChangeLog,v 1.52 2009/12/04 21:25:02 dev-zero Exp $
+
+*aria2-1.6.3-r1 (04 Dec 2009)
+
+  04 Dec 2009; Tiziano Müller <dev-zero@gentoo.org> +aria2-1.6.3-r1.ebuild,
+  metadata.xml:
+  Fixed dependencies (added xmlrpc USE flag for that), added scripts USE
+  flag to install optional scripts.
 
   14 Nov 2009; Tiziano Müller <dev-zero@gentoo.org>
   +files/1.6.3-unaligned_pointers.patch, aria2-1.6.3.ebuild:
diff --git a/net-misc/aria2/aria2-1.6.3-r1.ebuild b/net-misc/aria2/aria2-1.6.3-r1.ebuild
new file mode 100644
index 000000000000..942d2d3e0f3d
--- /dev/null
+++ b/net-misc/aria2/aria2-1.6.3-r1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/aria2/aria2-1.6.3-r1.ebuild,v 1.1 2009/12/04 21:25:02 dev-zero Exp $
+
+EAPI="2"
+
+inherit eutils
+
+DESCRIPTION="A download utility with resuming and segmented downloading with HTTP/HTTPS/FTP/BitTorrent support."
+HOMEPAGE="http://aria2.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+SLOT="0"
+IUSE="ares bittorrent expat gnutls metalink nls scripts sqlite ssl test xmlrpc"
+
+CDEPEND="sys-libs/zlib
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-1.2.9 )
+		!gnutls? ( dev-libs/openssl ) )
+	ares? ( >=net-dns/c-ares-1.5.0 )
+	bittorrent? (
+		gnutls? ( >=net-libs/gnutls-1.2.9 >=dev-libs/libgcrypt-1.2.2 )
+		!gnutls? ( dev-libs/openssl ) )
+	metalink? (
+		!expat? ( >=dev-libs/libxml2-2.6.26 )
+		expat? ( dev-libs/expat )
+	)
+	sqlite? ( dev-db/sqlite:3 )
+	xmlrpc? (
+		!expat? ( >=dev-libs/libxml2-2.6.26 )
+		expat? ( dev-libs/expat )
+	)"
+DEPEND="${CDEPEND}
+	nls? ( sys-devel/gettext )
+	test? ( >=dev-util/cppunit-1.12.0 )"
+RDEPEND="${CDEPEND}
+	scripts? ( dev-lang/ruby )
+	nls? ( virtual/libiconv virtual/libintl )"
+
+pkg_setup() {
+	if use scripts && use !xmlrpc && use !metalink; then
+		ewarn "Please also enable the 'xmlrpc' USE flag to actually use the additional scripts"
+	fi
+}
+
+src_prepare() {
+	sed -i -e "s|/tmp|${T}|" test/*.cc test/*.txt || die "sed failed"
+
+	epatch "${FILESDIR}/${PV}-unaligned_pointers.patch"
+}
+
+src_configure() {
+	local myconf="--without-gnutls --without-openssl"
+	use ssl && \
+		myconf="$(use_with gnutls) $(use_with !gnutls openssl)"
+
+	local xmllib="--without-libexpat --without-libxml2"
+	if use metalink || use xmlrpc ; then
+		xmllib="$(use_with expat libexpat) $(use_with !expat libxml2)"
+	fi
+
+	# Note:
+	# - depends on libgcrypt only when using gnutls
+	# - links only against libxml2 and libexpat when metalink is enabled
+	# - always enable gzip/http compression since zlib should always be available anyway
+	# - always enable epoll since we can assume kernel 2.6.x
+	# - other options for threads: solaris, pth, win32
+	econf \
+		--enable-epoll \
+		--enable-threads=posix \
+		--with-libz \
+		$(use_enable nls) \
+		$(use_enable metalink) \
+		$(use_with sqlite sqlite3) \
+		$(use_enable bittorrent) \
+		$(use_with ares libcares) \
+		${xmllib} \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+
+	rm -rf "${D}/usr/share/doc/aria2"
+	dodoc ChangeLog README AUTHORS NEWS
+	dohtml README.html doc/aria2c.1.html
+
+	use scripts && dobin doc/xmlrpc/*
+}
diff --git a/net-misc/aria2/metadata.xml b/net-misc/aria2/metadata.xml
index f5d69c017be8..2e3c25bbc362 100644
--- a/net-misc/aria2/metadata.xml
+++ b/net-misc/aria2/metadata.xml
@@ -10,5 +10,6 @@
     <flag name="ares">Enables support for asynchronous DNS using the c-ares library</flag>
     <flag name="bittorrent">Enables support for the bittorrent protocol</flag>
     <flag name="metalink">Enables support for metalink</flag>
+    <flag name="scripts">Install additional scripts which use aria2's xmlrpc functionality</flag>
   </use>
 </pkgmetadata>