snapshot. still does not fix some self test fails will look later. TESTFAIL: These test cases failed: 300 301 304 305 306 400 401 403 404 405

(Portage version: 2.1.2.2)

1 files changed, 100 insertions, 0 deletions

diff --git a/net-misc/curl/curl-7.16.3_pre20070418.ebuild b/net-misc/curl/curl-7.16.3_pre20070418.ebuild
new file mode 100644
index 000000000000..b45e6266c4ae
--- /dev/null
+++ b/net-misc/curl/curl-7.16.3_pre20070418.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/curl/curl-7.16.3_pre20070418.ebuild,v 1.1 2007/04/18 11:04:51 dragonheart Exp $
+
+# NOTE: If you bump this ebuild, make sure you bump dev-python/pycurl!
+
+inherit libtool eutils
+
+MY_P=${P/_pre/-}
+DESCRIPTION="A Client that groks URLs"
+HOMEPAGE="http://curl.haxx.se/ http://curl.planetmirror.com"
+SRC_URI="http://cool.haxx.se/curl-daily/${MY_P}.tar.bz2"
+#SRC_URI="http://curl.planetmirror.com/download/${P}.tar.bz2"
+
+LICENSE="MIT X11"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="ssl ipv6 ldap ares gnutls idn kerberos test"
+
+RDEPEND="gnutls? ( net-libs/gnutls )
+	ssl? ( !gnutls? ( dev-libs/openssl ) )
+	ldap? ( net-nds/openldap )
+	idn? ( net-dns/libidn )
+	ares? ( net-dns/c-ares )
+	kerberos? ( virtual/krb5 )"
+
+DEPEND="${RDEPEND}
+	test? (
+		sys-apps/diffutils
+		dev-lang/perl
+	)"
+# used - but can do without in self test: net-misc/stunnel
+S="${WORKDIR}"/${MY_P}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+#	epatch "${FILESDIR}"/${P}-strip-ldflags.patch
+	epatch "${FILESDIR}"/curl-7.16.2-strip-ldflags.patch
+	elibtoolize
+}
+
+src_compile() {
+
+	myconf="$(use_enable ldap)
+		$(use_with idn libidn)
+		$(use_enable kerberos gssapi)
+		$(use_enable ipv6)
+		--enable-http
+		--enable-ftp
+		--enable-gopher
+		--enable-file
+		--enable-dict
+		--enable-manual
+		--enable-telnet
+		--enable-nonblocking
+		--enable-largefile
+		--enable-maintainer-mode"
+
+	if use ipv6 && use ares; then
+		ewarn "c-ares support disabled because it is incompatible with ipv6."
+		myconf="${myconf} --disable-ares"
+	else
+		myconf="${myconf} $(use_enable ares)"
+	fi
+
+	if use gnutls; then
+		myconf="${myconf} --without-ssl --with-gnutls=/usr"
+	elif use ssl; then
+		myconf="${myconf} --without-gnutls --with-ssl=/usr"
+	else
+		myconf="${myconf} --without-gnutls --without-ssl"
+	fi
+
+	if use kerberos; then
+	   myconf="${myconf} --with-gssapi=/usr"
+	fi
+
+	econf ${myconf} || die 'configure failed'
+	emake || die "install failed for current version"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "installed failed for current version"
+
+	insinto /usr/share/aclocal
+	doins docs/libcurl/libcurl.m4
+
+	dodoc CHANGES README
+	dodoc docs/FEATURES docs/INTERNALS
+	dodoc docs/MANUAL docs/FAQ docs/BUGS docs/CONTRIBUTE
+}
+
+pkg_postinst() {
+	if [[ -e "${ROOT}"/usr/$(get_libdir)/libcurl.so.3 ]] ; then
+		ewarn "You must re-compile all packages that are linked against"
+		ewarn "curl-7.15.* by using revdep-rebuild from gentoolkit:"
+		ewarn "# revdep-rebuild --library libcurl.so.3"
+	fi
+}