Add unit file (#513296 by Michael Cook)

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

1 files changed, 58 insertions, 0 deletions

diff --git a/net-p2p/rtorrent/rtorrent-0.9.4-r1.ebuild b/net-p2p/rtorrent/rtorrent-0.9.4-r1.ebuild
new file mode 100644
index 000000000000..77504a23eae6
--- /dev/null
+++ b/net-p2p/rtorrent/rtorrent-0.9.4-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/rtorrent/rtorrent-0.9.4-r1.ebuild,v 1.1 2014/07/01 19:31:42 pacho Exp $
+
+EAPI=5
+
+inherit eutils systemd
+
+DESCRIPTION="BitTorrent Client using libtorrent"
+HOMEPAGE="http://libtorrent.rakshasa.no/"
+SRC_URI="http://libtorrent.rakshasa.no/downloads/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris"
+IUSE="daemon debug ipv6 selinux test xmlrpc"
+
+COMMON_DEPEND="~net-libs/libtorrent-0.13.${PV##*.}
+	>=dev-libs/libsigc++-2.2.2:2
+	>=net-misc/curl-7.19.1
+	sys-libs/ncurses
+	selinux? ( sec-policy/selinux-rtorrent )
+	xmlrpc? ( dev-libs/xmlrpc-c )"
+RDEPEND="${COMMON_DEPEND}
+	daemon? ( app-misc/screen )"
+DEPEND="${COMMON_DEPEND}
+	test? ( dev-util/cppunit )
+	virtual/pkgconfig"
+
+DOCS=( doc/rtorrent.rc )
+
+src_prepare() {
+	# bug #358271
+	epatch "${FILESDIR}"/${PN}-0.9.1-ncurses.patch
+
+	# upstream forgot to include
+	cp "${FILESDIR}"/rtorrent.1 "${S}"/doc/ || die
+}
+
+src_configure() {
+	# configure needs bash or script bombs out on some null shift, bug #291229
+	CONFIG_SHELL=${BASH} econf \
+		--disable-dependency-tracking \
+		$(use_enable debug) \
+		$(use_enable ipv6) \
+		$(use_with xmlrpc xmlrpc-c)
+}
+
+src_install() {
+	default
+	doman doc/rtorrent.1
+
+	if use daemon; then
+		newinitd "${FILESDIR}/rtorrentd.init" rtorrentd
+		newconfd "${FILESDIR}/rtorrentd.conf" rtorrentd
+		systemd_newunit "${FILESDIR}/rtorrentd_at.service" "rtorrentd@.service"
+	fi
+}