Version bump.

(Portage version: 2.2_rc62/cvs/Linux x86_64)

3 files changed, 122 insertions, 1 deletions

diff --git a/net-p2p/transmission/ChangeLog b/net-p2p/transmission/ChangeLog
index 17f19c1d06d9..5e14c65430bb 100644
--- a/net-p2p/transmission/ChangeLog
+++ b/net-p2p/transmission/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-p2p/transmission
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.103 2010/02/04 08:03:12 remi Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.104 2010/02/11 08:52:48 ssuominen Exp $
+
+*transmission-1.83 (11 Feb 2010)
+
+  11 Feb 2010; Samuli Suominen <ssuominen@gentoo.org>
+  +transmission-1.83.ebuild:
+  Version bump.
 
 *transmission-1.77 (04 Feb 2010)
 
diff --git a/net-p2p/transmission/metadata.xml b/net-p2p/transmission/metadata.xml
index 82abc271ca26..06e0396fb65e 100644
--- a/net-p2p/transmission/metadata.xml
+++ b/net-p2p/transmission/metadata.xml
@@ -4,5 +4,6 @@
   <herd>net-p2p</herd>
   <use>
     <flag name="dht">Enable Distributed Hash Tables support</flag>
+	<flag name="sound">Enable sound event support with <pkg>media-libs/libcanberra</pkg></flag>
   </use>
 </pkgmetadata>
diff --git a/net-p2p/transmission/transmission-1.83.ebuild b/net-p2p/transmission/transmission-1.83.ebuild
new file mode 100644
index 000000000000..b18b97adb905
--- /dev/null
+++ b/net-p2p/transmission/transmission-1.83.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-1.83.ebuild,v 1.1 2010/02/11 08:52:48 ssuominen Exp $
+
+EAPI=3
+inherit autotools eutils fdo-mime gnome2-utils qt4-r2
+
+DESCRIPTION="A Fast, Easy and Free BitTorrent client"
+HOMEPAGE="http://www.transmissionbt.com/"
+SRC_URI="http://download.transmissionbt.com/${PN}/files/${P}.tar.xz"
+
+LICENSE="MIT GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+IUSE="gnome gtk libnotify sound qt4"
+
+RDEPEND=">=dev-libs/libevent-1.4.11
+	<dev-libs/libevent-2
+	>=dev-libs/openssl-0.9.4
+	|| ( >=net-misc/curl-7.16.3[openssl]
+		>=net-misc/curl-7.16.3[ssl]
+		>=net-misc/curl-7.16.3[gnutls] )
+	gtk? ( >=dev-libs/glib-2.15.5:2
+		>=x11-libs/gtk+-2.12:2
+		>=dev-libs/dbus-glib-0.70
+		gnome? ( gnome-base/gconf )
+		libnotify? ( >=x11-libs/libnotify-0.4.3 )
+		sound? ( >=media-libs/libcanberra-0.10 ) )
+	qt4? ( x11-libs/qt-gui:4 )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	>=sys-devel/libtool-2.2.6b
+	sys-devel/gettext
+	>=dev-util/intltool-0.40
+	dev-util/pkgconfig
+	sys-apps/sed"
+
+src_prepare() {
+	sed -i \
+		-e 's:-g -O0::g' \
+		-e 's:-g -O3::g' \
+		-e 's:-ggdb3::g' \
+		configure.ac || die
+
+	sed -i \
+		-e 's:$${TRANSMISSION_TOP}/third-party/libevent/.libs/libevent.a:-levent:' \
+		qt/qtr.pro || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf="--disable-libnotify --disable-libcanberra --disable-libgconf"
+
+	if use gtk; then
+		myconf="$(use_enable libnotify) $(use_enable sound libcanberra)
+			$(use_enable gnome libgconf)"
+	fi
+
+	# cli and daemon doesn't have external deps
+	econf \
+		--disable-dependency-tracking \
+		$(use_enable gtk) \
+		--enable-cli \
+		--enable-daemon \
+		${myconf}
+
+	if use qt4; then
+		cd qt
+		eqmake4 qtr.pro
+	fi
+}
+
+src_compile() {
+	emake || die
+
+	if use qt4; then
+		cd qt
+		emake || die
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS NEWS qt/README.txt
+	rm -f "${D}"/usr/share/${PN}/web/LICENSE
+
+	# these are likely outdated for 1.83
+	newinitd "${FILESDIR}"/${PN}-daemon.initd.2 ${PN}-daemon
+	newconfd "${FILESDIR}"/${PN}-daemon.confd.1 ${PN}-daemon
+
+	if use qt4; then
+		cd qt
+		emake INSTALL_ROOT="${D}/usr" install || die
+		make_desktop_entry qtr "Transmission Qt BitTorrent Client" ${PN} \
+			"Network;FileTransfer;P2P;Qt"
+		use gtk || doicon qt/icons/transmission.png
+	fi
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}