Add 3.0.11 ebuild since it has features which have been removed in later versions. Do not remove it before you talk to me please

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 09BF4F54C2BA7F3C!)

2 files changed, 65 insertions, 1 deletions

diff --git a/net-p2p/qbittorrent/ChangeLog b/net-p2p/qbittorrent/ChangeLog
index bcf293acf66e..05234148eb7e 100644
--- a/net-p2p/qbittorrent/ChangeLog
+++ b/net-p2p/qbittorrent/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for net-p2p/qbittorrent
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.236 2014/11/06 21:37:52 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/ChangeLog,v 1.237 2014/12/05 17:16:42 hwoarang Exp $
+
+*qbittorrent-3.0.11-r2 (05 Dec 2014)
+
+  05 Dec 2014; Markos Chandras <hwoarang@gentoo.org>
+  +qbittorrent-3.0.11-r2.ebuild:
+  Add 3.0.11 ebuild since it has features which have been removed in later
+  versions. Do not remove it before you talk to me please
 
 *qbittorrent-3.1.11 (06 Nov 2014)
 
diff --git a/net-p2p/qbittorrent/qbittorrent-3.0.11-r2.ebuild b/net-p2p/qbittorrent/qbittorrent-3.0.11-r2.ebuild
new file mode 100644
index 000000000000..86bdbeedbc9a
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-3.0.11-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/qbittorrent/qbittorrent-3.0.11-r2.ebuild,v 1.1 2014/12/05 17:16:42 hwoarang Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit python-r1 qt4-r2
+
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="http://www.qbittorrent.org/"
+MY_P=${P/_}
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+
+IUSE="dbus debug geoip +X"
+
+# geoip and python are runtime deps only (see INSTALL file)
+CDEPEND="
+	dev-libs/boost:=
+	dev-qt/qtcore:4
+	>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[X?]
+	>=net-libs/rb_libtorrent-0.16.17
+	dbus? ( dev-qt/qtdbus:4 )
+	X? ( dev-qt/qtgui:4 )
+"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+"
+RDEPEND="${CDEPEND}
+	${PYTHON_DEPS}
+	geoip? ( dev-libs/geoip )
+"
+
+S=${WORKDIR}/${MY_P}
+DOCS=(AUTHORS Changelog README TODO)
+
+src_configure() {
+	# Custom configure script, econf fails
+	local myconf=(
+		./configure
+		--prefix="${EPREFIX}/usr"
+		--with-libboost-inc="${EPREFIX}/usr/include/boost"
+		--with-qtsingleapplication=system
+		$(use dbus  || echo --disable-qt-dbus)
+		$(use debug && echo --enable-debug)
+		$(use geoip || echo --disable-geoip-database)
+		$(use X     || echo --disable-gui)
+	)
+
+	echo "${myconf[@]}"
+	"${myconf[@]}" || die "configure failed"
+	eqmake4
+}