kismet: Revbump, change the fperms line to pkg_preinst() because we have to change permissions after we change ownership otherwise we lose the setuid bit. Add ~arm keyword, tested on my cortex-a8.

(Portage version: 2.1.8.3/cvs/Linux x86_64)

2 files changed, 103 insertions, 1 deletions

diff --git a/net-wireless/kismet/ChangeLog b/net-wireless/kismet/ChangeLog
index be38a25a3632..eff5a845c3e3 100644
--- a/net-wireless/kismet/ChangeLog
+++ b/net-wireless/kismet/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for net-wireless/kismet
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/kismet/ChangeLog,v 1.107 2010/03/14 13:19:08 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/kismet/ChangeLog,v 1.108 2010/04/15 01:32:42 steev Exp $
+
+*kismet-2010.01.1-r1 (15 Apr 2010)
+
+  15 Apr 2010; Steev Klimaszewski <steev@gentoo.org>
+  +kismet-2010.01.1-r1.ebuild:
+  kismet: Revbump, change the fperms line to pkg_preinst() because we have 
+  to change permissions after we change ownership otherwise we lose the 
+  setuid bit. Add ~arm keyword, tested on my cortex-a8.
 
 *kismet-2010.01.1 (14 Mar 2010)
 
diff --git a/net-wireless/kismet/kismet-2010.01.1-r1.ebuild b/net-wireless/kismet/kismet-2010.01.1-r1.ebuild
new file mode 100644
index 000000000000..f5f27bd60d26
--- /dev/null
+++ b/net-wireless/kismet/kismet-2010.01.1-r1.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/kismet/kismet-2010.01.1-r1.ebuild,v 1.1 2010/04/15 01:32:42 steev Exp $
+
+EAPI="2"
+
+inherit eutils
+
+MY_P=${P/\./-}
+MY_P=${MY_P/./-R}
+
+DESCRIPTION="IEEE 802.11 wireless LAN sniffer"
+HOMEPAGE="http://www.kismetwireless.net/"
+SRC_URI="http://www.kismetwireless.net/code/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+
+# plugins have unresolved QA issues 
+#KISMET_PLUGINS="autowep btscan ptw spectools"
+IUSE="+client kernel_linux +pcre +pcap +suid" # ${KISMET_PLUGINS}"
+
+RDEPEND="client? ( sys-libs/ncurses )
+	kernel_linux? (	dev-libs/libnl
+		sys-libs/libcap	)
+	pcap? ( net-libs/libpcap )
+	pcre? ( dev-libs/libpcre )"
+#	btscan? ( net-wireless/bluez )
+#	ptw? ( dev-libs/openssl )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	sed -i -e 's:# *logprefix=.*:logprefix=/tmp:' conf/kismet.conf.in \
+		|| die "failed to change logprefix"
+}
+
+src_configure() {
+	econf --with-suidgroup=kismet \
+		$(use_enable client) \
+		$(use_enable kernel_linux linuxwext) \
+		$(use_enable pcre) \
+		$(use_enable pcap)
+}
+
+src_compile() {
+	emake || die "emake failed"
+
+#	for plugin in ${KISMET_PLUGINS}; do
+#		if use ${plugin}; then
+#			emake -C plugin-${plugin} KIS_SRC_DIR="${S}" \
+#				|| die "emake in plugin-${plugin} failed"
+#		fi
+#	done
+}
+
+src_install() {
+	emake DESTDIR="${D}" commoninstall || die "emake install failed"
+
+#	for plugin in ${KISMET_PLUGINS}; do
+#		if use ${plugin}; then
+#			emake -C plugin-${plugin} KIS_SRC_DIR="${S}" DESTDIR="${D}" install \
+#				|| die "emake install in plugin-${plugin} failed"
+#		fi
+#	done
+
+	dodoc README RELEASENOTES.txt docs/{DEVEL.client,README.newcore} || die
+
+	insinto /etc
+	doins conf/kismet{,_drone}.conf || die
+
+	newinitd "${FILESDIR}"/${PN}.initd kismet || die
+	newconfd "${FILESDIR}"/${PN}.confd kismet || die
+
+	if use suid; then
+		dobin kismet_capture || die
+	fi
+}
+
+pkg_preinst() {
+	if use suid; then
+		enewgroup kismet
+		fowners root:kismet /usr/bin/kismet_capture || die
+		# Need to set the permissions after chowning.
+		# See chown(2)
+		fperms 4550 /usr/bin/kismet_capture || die
+		elog "Kismet has been installed with a setuid-root helper binary"
+		elog "to enable minimal-root operation.  Users need to be part of"
+		elog "the 'kismet' group to perform captures from physical devices."
+	fi
+}