adding distutils-r1, thanks to significant help from mgorny

(Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key DD11F94A)

3 files changed, 162 insertions, 6 deletions

diff --git a/net-wireless/aircrack-ng/ChangeLog b/net-wireless/aircrack-ng/ChangeLog
index 4febe5a4ded9..1429594bfdcf 100644
--- a/net-wireless/aircrack-ng/ChangeLog
+++ b/net-wireless/aircrack-ng/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/aircrack-ng
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v 1.81 2014/04/17 19:14:33 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v 1.82 2014/04/18 01:30:53 zerochaos Exp $
+
+*aircrack-ng-1.2_beta3-r1 (18 Apr 2014)
+
+  18 Apr 2014; Rick Farina <zerochaos@gentoo.org>
+  +aircrack-ng-1.2_beta3-r1.ebuild, aircrack-ng-9999.ebuild:
+  adding distutils-r1, thanks to significant help from mgorny
 
 *aircrack-ng-1.2_beta3 (17 Apr 2014)
 
diff --git a/net-wireless/aircrack-ng/aircrack-ng-1.2_beta3-r1.ebuild b/net-wireless/aircrack-ng/aircrack-ng-1.2_beta3-r1.ebuild
new file mode 100644
index 000000000000..b93a4fa78915
--- /dev/null
+++ b/net-wireless/aircrack-ng/aircrack-ng-1.2_beta3-r1.ebuild
@@ -0,0 +1,133 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-1.2_beta3-r1.ebuild,v 1.1 2014/04/18 01:30:53 zerochaos Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_OPTIONAL=1
+
+inherit toolchain-funcs versionator distutils-r1
+
+DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
+HOMEPAGE="http://www.aircrack-ng.org"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit subversion
+	ESVN_REPO_URI="http://svn.aircrack-ng.org/trunk"
+	KEYWORDS=""
+	S="${WORKDIR}/${PN}"
+else
+	MY_P=${P/\_/-}
+	MY_PV="$(replace_version_separator 2 '-')"
+	SRC_URI="http://download.aircrack-ng.org/${PN}-${MY_PV}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD +netlink +pcre +sqlite +unstable"
+
+DEPEND="dev-libs/openssl
+	netlink? ( dev-libs/libnl:3 )
+	pcre? ( dev-libs/libpcre )
+	airdrop-ng? ( ${PYTHON_DEPS} )
+	airgraph-ng? ( ${PYTHON_DEPS} )
+	sqlite? ( >=dev-db/sqlite-3.4 )"
+RDEPEND="${DEPEND}
+	kernel_linux? (
+		net-wireless/iw
+		net-wireless/wireless-tools
+		sys-apps/ethtool
+		sys-apps/usbutils
+		sys-apps/pciutils )
+	sys-apps/hwids
+	airdrop-ng? ( net-wireless/lorcon[python,${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="airdrop-ng? ( ${PYTHON_REQUIRED_USE} )
+		airgraph-ng? ( ${PYTHON_REQUIRED_USE} )"
+
+src_compile() {
+	if [[ ${PV} == "9999" ]] ; then
+		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
+	fi
+
+	emake \
+	CC="$(tc-getCC)" \
+	AR="$(tc-getAR)" \
+	LD="$(tc-getLD)" \
+	RANLIB="$(tc-getRANLIB)" \
+	libnl=$(usex netlink true false) \
+	pcre=$(usex pcre true false) \
+	sqlite=$(usex sqlite true false) \
+	unstable=$(usex unstable true false) \
+	${liveflags}
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_compile
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	if [[ ${PV} == "9999" ]] ; then
+		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
+	fi
+
+	emake check \
+		libnl=$(usex netlink true false) \
+		pcre=$(usex pcre true false) \
+		sqlite=$(usex sqlite true false) \
+		unstable=$(usex unstable true false) \
+		${liveflags}
+}
+
+src_install() {
+	if [[ ${PV} == "9999" ]] ; then
+		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
+	fi
+
+	emake \
+		prefix="${ED}/usr" \
+		libnl=$(usex netlink true false) \
+		pcre=$(usex pcre true false) \
+		sqlite=$(usex sqlite true false) \
+		unstable=$(usex unstable true false) \
+		${liveflags} \
+		install
+
+	dodoc AUTHORS ChangeLog INSTALLING README
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_install
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_install
+	fi
+
+	#we don't need aircrack-ng's oui updater, we have our own
+	rm "${ED}"/usr/sbin/airodump-ng-oui-update
+}
+
+pkg_postinst() {
+	# Message is (c) FreeBSD
+	# http://www.freebsd.org/cgi/cvsweb.cgi/ports/net-mgmt/aircrack-ng/files/pkg-message.in?rev=1.5
+	if use kernel_FreeBSD ; then
+		einfo "Contrary to Linux, it is not necessary to use airmon-ng to enable the monitor"
+		einfo "mode of your wireless card.  So do not care about what the manpages say about"
+		einfo "airmon-ng, airodump-ng sets monitor mode automatically."
+		echo
+		einfo "To return from monitor mode, issue the following command:"
+		einfo "    ifconfig \${INTERFACE} -mediaopt monitor"
+		einfo
+		einfo "For aireplay-ng you need FreeBSD >= 7.0."
+	fi
+}
diff --git a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
index 3f660e60e6a3..04dde0abb8c9 100644
--- a/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
+++ b/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild
@@ -1,10 +1,13 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild,v 1.8 2014/04/17 19:14:33 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild,v 1.9 2014/04/18 01:30:53 zerochaos Exp $
 
 EAPI="5"
 
-inherit toolchain-funcs versionator
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_OPTIONAL=1
+
+inherit toolchain-funcs versionator distutils-r1
 
 DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
 HOMEPAGE="http://www.aircrack-ng.org"
@@ -30,6 +33,8 @@ IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD +netlink +pcre +sqlit
 DEPEND="dev-libs/openssl
 	netlink? ( dev-libs/libnl:3 )
 	pcre? ( dev-libs/libpcre )
+	airdrop-ng? ( ${PYTHON_DEPS} )
+	airgraph-ng? ( ${PYTHON_DEPS} )
 	sqlite? ( >=dev-db/sqlite-3.4 )"
 RDEPEND="${DEPEND}
 	kernel_linux? (
@@ -39,7 +44,10 @@ RDEPEND="${DEPEND}
 		sys-apps/usbutils
 		sys-apps/pciutils )
 	sys-apps/hwids
-	airdrop-ng? ( net-wireless/lorcon[python] )"
+	airdrop-ng? ( net-wireless/lorcon[python,${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="airdrop-ng? ( ${PYTHON_REQUIRED_USE} )
+		airgraph-ng? ( ${PYTHON_REQUIRED_USE} )"
 
 src_compile() {
 	if [[ ${PV} == "9999" ]] ; then
@@ -56,6 +64,15 @@ src_compile() {
 	sqlite=$(usex sqlite true false) \
 	unstable=$(usex unstable true false) \
 	${liveflags}
+
+	if use airgraph-ng; then
+		cd "${S}/scripts/airgraph-ng"
+		distutils-r1_src_compile
+	fi
+	if use airdrop-ng; then
+		cd "${S}/scripts/airdrop-ng"
+		distutils-r1_src_compile
+	fi
 }
 
 src_test() {
@@ -89,11 +106,11 @@ src_install() {
 
 	if use airgraph-ng; then
 		cd "${S}/scripts/airgraph-ng"
-		emake prefix="${ED}/usr" install
+		distutils-r1_src_install
 	fi
 	if use airdrop-ng; then
 		cd "${S}/scripts/airdrop-ng"
-		emake prefix="${ED}/usr" install
+		distutils-r1_src_install
 	fi
 
 	#we don't need aircrack-ng's oui updater, we have our own