Version Bump

(Portage version: 2.2_rc67/cvs/Linux x86_64)

2 files changed, 90 insertions, 1 deletions

diff --git a/sci-chemistry/aria/ChangeLog b/sci-chemistry/aria/ChangeLog
index 807fd22c8bae..d623db7fe1ca 100644
--- a/sci-chemistry/aria/ChangeLog
+++ b/sci-chemistry/aria/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/aria
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/aria/ChangeLog,v 1.2 2010/03/07 09:31:51 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/aria/ChangeLog,v 1.3 2010/03/20 13:27:23 jlec Exp $
+
+*aria-2.3.1 (20 Mar 2010)
+
+  20 Mar 2010; Justin Lecher (jlec) <jlec@gentoo.org> +aria-2.3.1.ebuild:
+  Version Bump
 
   07 Mar 2010; Justin Lecher (jlec) <jlec@gentoo.org> aria-2.2_p2.ebuild:
   keyworded for *-linux, tested by me
diff --git a/sci-chemistry/aria/aria-2.3.1.ebuild b/sci-chemistry/aria/aria-2.3.1.ebuild
new file mode 100644
index 000000000000..4431bee4790c
--- /dev/null
+++ b/sci-chemistry/aria/aria-2.3.1.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/aria/aria-2.3.1.ebuild,v 1.1 2010/03/20 13:27:23 jlec Exp $
+
+EAPI="3"
+PYTHON_DEPEND="2"
+PYTHON_USE_WITH="tk"
+
+inherit base python eutils versionator
+
+MY_P="${PN}$(get_version_component_range 1-2 ${PV})"
+
+DESCRIPTION="Software for automated NOE assignment and NMR structure calculation."
+HOMEPAGE="http://aria.pasteur.fr/"
+SRC_URI="http://aria.pasteur.fr/archives/${MY_P}.1.tar.gz"
+
+SLOT="0"
+LICENSE="cns"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/numpy
+	dev-python/matplotlib[tk]
+	sci-chemistry/cns[aria,openmp]
+	>=dev-lang/tk-8.3
+	>=sci-chemistry/ccpn-2.0.5
+	>=dev-tcltk/tix-8.1.4"
+DEPEND="${RDEPEND}"
+
+RESTRICT="fetch"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_nofetch(){
+	einfo "Go to ${HOMEPAGE}, download ${A}"
+	einfo "and place it in ${DISTDIR}"
+}
+
+src_test(){
+	export CCPNMR_TOP_DIR="${EPREFIX}"/$(python_get_sitedir)
+	export PYTHONPATH=.:${CCPNMR_TOP_DIR}/ccpn/python
+	$(PYTHON) check.py || die
+}
+
+src_install(){
+	insinto "$(python_get_sitedir)/${PN}"
+	doins -r src aria2.py || die "failed to install ${PN}"
+	insinto "$(python_get_sitedir)/${PN}"/cns
+	doins -r cns/{protocols,toppar,src/helplib} || die "failed to install cns part"
+
+	if use examples; then
+		insinto /usr/share/${P}/
+		doins -r examples || die
+	fi
+
+	# ENV
+	cat >> "${T}"/20aria <<- EOF
+	ARIA2="${EPREFIX}/$(python_get_sitedir)/${PN}"
+	EOF
+
+	doenvd "${T}"/20aria
+
+	# Launch Wrapper
+	cat >> "${T}"/aria <<- EOF
+	#!/bin/sh
+	export CCPNMR_TOP_DIR="${EPREFIX}/$(python_get_sitedir)"
+	export PYTHONPATH="${EPREFIX}/$(python_get_sitedir)/ccpn/python"
+	exec "$(PYTHON)" -O "\${ARIA2}"/aria2.py \$@
+	EOF
+
+	dobin "${T}"/aria || die "failed to install wrapper"
+	dosym aria /usr/bin/aria2
+
+	dodoc README || die
+}
+
+pkg_postinst() {
+	python_mod_optimize ${PN}
+}
+
+pkg_postrm() {
+	python_mod_cleanup ${PN}
+}