Version bump, thanks to Claus-Justus Heine <himself@claus-justus-heine.de>, #504372

(Portage version: 2.2.8-r1/cvs/Linux i686, signed Manifest commit with key 0x3AFFCE974D34BD8C!)

1 files changed, 68 insertions, 0 deletions

diff --git a/sci-mathematics/geomview/geomview-1.9.5.ebuild b/sci-mathematics/geomview/geomview-1.9.5.ebuild
new file mode 100644
index 000000000000..0ffb7bf92262
--- /dev/null
+++ b/sci-mathematics/geomview/geomview-1.9.5.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/geomview/geomview-1.9.5.ebuild,v 1.1 2014/03/25 05:49:23 grozin Exp $
+
+EAPI=5
+
+inherit elisp-common eutils flag-o-matic fdo-mime
+
+DESCRIPTION="Interactive Geometry Viewer"
+HOMEPAGE="http://geomview.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	http://dev.gentoo.org/~jlec/distfiles/geomview.png.tar"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="motionaveraging debug emacs zlib"
+
+DEPEND=">=x11-libs/motif-2.3:0
+	virtual/opengl
+	emacs? ( virtual/emacs )
+	zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}
+	x11-misc/xdg-utils"
+
+S="${WORKDIR}/${P/_/-}"
+
+SITEFILE=50${PN}-gentoo.el
+
+src_configure() {
+	econf --docdir=/usr/share/doc/${PF} \
+		--with-htmlbrowser=xdg-open \
+		--with-pdfviewer=xdg-open \
+		$(use_enable debug d1debug) \
+		$(use_with zlib) \
+		$(use_enable motionaveraging motion-averaging)
+}
+
+src_compile() {
+	default
+	if use emacs; then
+		cp "${FILESDIR}/gvcl-mode.el" "${S}"
+		elisp-compile *.el
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog NEWS INSTALL.Geomview || die
+	doicon "${WORKDIR}"/geomview.png || die
+	make_desktop_entry ${PN} "GeomView ${PV}" \
+		/usr/share/pixmaps/${PN}.png \
+		"Science;Math;Education"
+
+	if use emacs; then
+		elisp-install ${PN} *.el *.elc
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	fi
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	use emacs && elisp-site-regen
+}