Version bump.

(Portage version: 2.2.0_alpha118/cvs/Linux x86_64)

2 files changed, 64 insertions, 1 deletions

diff --git a/sys-apps/less/ChangeLog b/sys-apps/less/ChangeLog
index 32c029c7d1f7..ad10d555cb88 100644
--- a/sys-apps/less/ChangeLog
+++ b/sys-apps/less/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/less
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.144 2012/06/27 23:03:16 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/ChangeLog,v 1.145 2012/07/16 05:55:31 radhermit Exp $
+
+*less-450 (16 Jul 2012)
+
+  16 Jul 2012; Tim Harder <radhermit@gentoo.org> +less-450.ebuild:
+  Version bump.
 
 *less-449 (27 Jun 2012)
 
diff --git a/sys-apps/less/less-450.ebuild b/sys-apps/less/less-450.ebuild
new file mode 100644
index 000000000000..33c4f2baf047
--- /dev/null
+++ b/sys-apps/less/less-450.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/less/less-450.ebuild,v 1.1 2012/07/16 05:55:31 radhermit Exp $
+
+EAPI="4"
+
+inherit eutils
+
+DESCRIPTION="Excellent text file viewer"
+HOMEPAGE="http://www.greenwoodsoftware.com/less/"
+SRC_URI="http://www.greenwoodsoftware.com/less/${P}.tar.gz
+	http://www-zeuthen.desy.de/~friebel/unix/less/code2color"
+
+LICENSE="|| ( GPL-3 BSD-2 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="pcre unicode"
+
+DEPEND=">=app-misc/editor-wrapper-3
+	>=sys-libs/ncurses-5.2
+	pcre? ( dev-libs/libpcre )"
+RDEPEND="${DEPEND}"
+
+src_unpack() {
+	unpack ${P}.tar.gz
+	cp "${DISTDIR}"/code2color "${S}"/
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/code2color.patch
+}
+
+src_configure() {
+	export ac_cv_lib_ncursesw_initscr=$(usex unicode)
+	export ac_cv_lib_ncurses_initscr=$(usex !unicode)
+
+	local regex="posix"
+	use pcre && regex="pcre"
+
+	econf \
+		--with-regex=${regex} \
+		--with-editor="${EPREFIX}"/usr/libexec/editor
+}
+
+src_install() {
+	default
+
+	dobin code2color
+	newbin "${FILESDIR}"/lesspipe.sh lesspipe
+	dosym lesspipe /usr/bin/lesspipe.sh
+	newenvd "${FILESDIR}"/less.envd 70less
+
+	dodoc NEWS README* "${FILESDIR}"/README.Gentoo
+}
+
+pkg_postinst() {
+	einfo "lesspipe offers colorization options.  Run 'lesspipe -h' for info."
+}