Version bump.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 4F064CA3)

2 files changed, 62 insertions, 1 deletions

diff --git a/sys-apps/moreutils/ChangeLog b/sys-apps/moreutils/ChangeLog
index 72b13db21bae..08f921f1e354 100644
--- a/sys-apps/moreutils/ChangeLog
+++ b/sys-apps/moreutils/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/moreutils
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.69 2015/01/29 06:40:31 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/ChangeLog,v 1.70 2015/06/17 21:21:27 radhermit Exp $
+
+*moreutils-0.56 (17 Jun 2015)
+
+  17 Jun 2015; Tim Harder <radhermit@gentoo.org> +moreutils-0.56.ebuild:
+  Version bump.
 
 *moreutils-0.55 (29 Jan 2015)
 
diff --git a/sys-apps/moreutils/moreutils-0.56.ebuild b/sys-apps/moreutils/moreutils-0.56.ebuild
new file mode 100644
index 000000000000..a53ecca3fd86
--- /dev/null
+++ b/sys-apps/moreutils/moreutils-0.56.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/moreutils/moreutils-0.56.ebuild,v 1.1 2015/06/17 21:21:27 radhermit Exp $
+
+EAPI=5
+inherit toolchain-funcs
+
+DESCRIPTION="a growing collection of the unix tools that nobody thought to write thirty years ago"
+HOMEPAGE="http://joeyh.name/code/moreutils/"
+SRC_URI="mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}.orig.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~x86 ~x86-linux"
+IUSE="+doc +perl"
+
+RDEPEND="
+	perl? (
+		dev-lang/perl
+		dev-perl/IPC-Run
+		dev-perl/Time-Duration
+		dev-perl/TimeDate
+	)"
+DEPEND="
+	doc? (
+		dev-lang/perl
+		>=app-text/docbook2X-0.8.8-r2
+		app-text/docbook-xml-dtd:4.4
+	)"
+
+src_prepare() {
+	# don't build manpages
+	if ! use doc ; then
+		sed -i -e '/^all:/s/$(MANS)//' -e '/man1/d' Makefile || die
+	fi
+
+	# don't install perl scripts
+	if ! use perl ; then
+		sed -i -e '/PERLSCRIPTS/d' Makefile || die
+	fi
+}
+
+src_compile() {
+	tc-export CC
+	emake CFLAGS="${CFLAGS}" DOCBOOK2XMAN=docbook2man.pl PREFIX="${EPREFIX}/usr"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" INSTALL_BIN=install install
+
+	# sys-process is more advanced than parallel from moreutils, rename it
+	if use doc; then
+		mv "${ED}"usr/share/man/man1/{,${PN}_}parallel.1 || die
+	fi
+	mv "${ED}"usr/bin/{,${PN}_}parallel || die
+}