EAPI4, add cman compatibility via IUSE, move to GitHub for sources.

(Portage version: 2.1.10.29/cvs/Linux x86_64)

3 files changed, 98 insertions, 1 deletions

diff --git a/sys-cluster/pacemaker/ChangeLog b/sys-cluster/pacemaker/ChangeLog
index 216deeccb111..f9be19336bbc 100644
--- a/sys-cluster/pacemaker/ChangeLog
+++ b/sys-cluster/pacemaker/ChangeLog
@@ -1,12 +1,22 @@
 # ChangeLog for sys-cluster/pacemaker
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/pacemaker/ChangeLog,v 1.16 2011/10/18 18:40:04 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/pacemaker/ChangeLog,v 1.17 2011/10/24 11:25:48 ultrabug Exp $
+
+  24 Oct 2011; Ultrabug <ultrabug@gentoo.org> +pacemaker-1.1.6.1.ebuild,
+  metadata.xml:
+  EAPI4, add cman compatibility via IUSE, move to GitHub for sources.
 
   18 Oct 2011; Kacper Kowalik <xarthisius@gentoo.org>
   pacemaker-1.1.4-r4.ebuild, pacemaker-1.1.5.ebuild:
   Depend either on corosync or on heartbeat stack wrt bug #387581 by Jeroen
   Roovers <jer@gentoo.org>
 
+*pacemaker-1.1.6.1 (12 Oct 2011)
+
+  12 Oct 2011; Ultrabug <ultrabug@gentoo.org> +pacemaker-1.1.6.1.ebuild,
+  metadata.xml:
+  Version bump, add cman to IUSE.
+
   21 Sep 2011; Ultrabug <ultrabug@gentoo.org> pacemaker-1.1.5.ebuild:
   Fix missing dep #382957, thanks to Guillaume Chanaud.
 
diff --git a/sys-cluster/pacemaker/metadata.xml b/sys-cluster/pacemaker/metadata.xml
index 08b424331f5c..e36a21bf761c 100644
--- a/sys-cluster/pacemaker/metadata.xml
+++ b/sys-cluster/pacemaker/metadata.xml
@@ -9,6 +9,7 @@
    </longdescription>
    <use>
 	   <flag name="ais">Enable <pkg>sys-cluster/openais</pkg> support.</flag>
+	   <flag name="cman">Enable <pkg>sys-cluster/cman</pkg> support.</flag>
 	   <flag name="heartbeat">Enable <pkg>sys-cluster/heartbeat</pkg> support.</flag>
 	   <flag name="smtp">Enable SMTP support via <pkg>net-libs/libsmtp</pkg></flag>
    </use>
diff --git a/sys-cluster/pacemaker/pacemaker-1.1.6.1.ebuild b/sys-cluster/pacemaker/pacemaker-1.1.6.1.ebuild
new file mode 100644
index 000000000000..f89b6ad0b471
--- /dev/null
+++ b/sys-cluster/pacemaker/pacemaker-1.1.6.1.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/pacemaker/pacemaker-1.1.6.1.ebuild,v 1.1 2011/10/24 11:25:48 ultrabug Exp $
+
+EAPI=4
+
+inherit autotools base python
+
+MY_PN=Pacemaker
+MY_P=${MY_PN}-${PV}
+MY_TREE="0c7312c"
+PYTHON_DEPEND="2"
+
+DESCRIPTION="Pacemaker CRM"
+HOMEPAGE="http://www.linux-ha.org/wiki/Pacemaker"
+SRC_URI="https://github.com/ClusterLabs/${PN}/tarball/${MY_P} -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+REQUIRED_USE="cman? ( !heartbeat )"
+IUSE="acl cman heartbeat smtp snmp static-libs"
+
+DEPEND="
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	sys-cluster/cluster-glue
+	sys-cluster/resource-agents
+	cman? ( sys-cluster/cman )
+	heartbeat? ( >=sys-cluster/heartbeat-3.0.0 )
+	!heartbeat? ( sys-cluster/corosync )
+	smtp? ( net-libs/libesmtp )
+	snmp? ( net-analyzer/net-snmp )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/ClusterLabs-${PN}-${MY_TREE}"
+
+pkg_setup() {
+	python_set_active_version 2
+	python_pkg_setup
+}
+
+src_prepare() {
+	base_src_prepare
+	sed -i -e "/ggdb3/d" configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local myopts=""
+	use heartbeat || myopts="--with-ais"
+	# appends lib to localstatedir automatically
+	econf \
+		--localstatedir=/var \
+		--disable-dependency-tracking \
+		--disable-fatal-warnings \
+		$(use_with acl) \
+		$(use_with cman cs-quorum) \
+		$(use_with cman cman) \
+		$(use_with heartbeat) \
+		$(use_with smtp esmtp) \
+		$(use_with snmp) \
+		$(use_enable static-libs static) \
+		${myopts}
+}
+
+src_install() {
+	base_src_install
+	newinitd "${FILESDIR}/${PN}.initd" ${PN} || die
+	insinto /etc/corosync/service.d
+	newins "${FILESDIR}/${PN}.service" ${PN} || die
+}
+
+pkg_postinst() {
+	elog "This version of Pacemaker uses the new MCP feature"
+	elog "and the v1 plugin for CoroSync. Read [1] for more info."
+	elog
+	elog "To start the Pacemaker Cluster Manager, run:"
+	elog "/etc/init.d/pacemaker start"
+	elog
+	elog "[1] http://theclusterguy.clusterlabs.org/post/907043024/introducing-the-pacemaker-master-control-process-for"
+	elog
+	elog "Note: sys-cluster/openais is no longer a hard dependency of ${P},"
+	elog "so you may need to install it yourself to suit your needs."
+}