Version bumped, bug #288082.

(Portage version: 2.1.6.13/cvs/Linux x86_64)

2 files changed, 67 insertions, 1 deletions

diff --git a/sys-libs/slang/ChangeLog b/sys-libs/slang/ChangeLog
index 70a9d559a4e0..e08f8269ad5e 100644
--- a/sys-libs/slang/ChangeLog
+++ b/sys-libs/slang/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/slang
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.102 2009/10/07 16:37:55 nixnut Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.103 2009/10/07 23:12:02 matsuu Exp $
+
+*slang-2.2.1 (07 Oct 2009)
+
+  07 Oct 2009; MATSUU Takuto <matsuu@gentoo.org> +slang-2.2.1.ebuild:
+  Version bumped, bug #288082.
 
   07 Oct 2009; nixnut <nixnut@gentoo.org> slang-2.2.0.ebuild:
   ppc stable #287733
diff --git a/sys-libs/slang/slang-2.2.1.ebuild b/sys-libs/slang/slang-2.2.1.ebuild
new file mode 100644
index 000000000000..021063cd3665
--- /dev/null
+++ b/sys-libs/slang/slang-2.2.1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/slang-2.2.1.ebuild,v 1.1 2009/10/07 23:12:02 matsuu Exp $
+
+EAPI=2
+inherit eutils
+
+DESCRIPTION="a portable programmer's library designed to allow a developer to create robust portable software."
+HOMEPAGE="http://www.s-lang.org"
+SRC_URI="ftp://ftp.fu-berlin.de/pub/unix/misc/slang/v${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="cjk pcre png readline zlib"
+
+RDEPEND="sys-libs/ncurses
+	pcre? ( dev-libs/libpcre )
+	png? ( media-libs/libpng )
+	cjk? ( dev-libs/oniguruma )
+	readline? ( sys-libs/readline )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.1.2-slsh-libs.patch \
+		"${FILESDIR}"/${PN}-2.1.3-uclibc.patch
+}
+
+src_configure() {
+	local myconf
+
+	if use readline; then
+		myconf+=" --with-readline=gnu"
+	else
+		myconf+=" --with-readline=slang"
+	fi
+
+	econf \
+		$(use_with cjk onig) \
+		$(use_with pcre) \
+		$(use_with png) \
+		$(use_with zlib z) \
+		${myconf}
+}
+
+src_compile() {
+	emake -j1 elf static || die "emake elf static failed"
+
+	cd slsh
+	emake -j1 slsh || die "emake slsh failed"
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}" install-all || die "emake install-all failed"
+
+	rm -rf "${D}"/usr/share/doc/{slang,slsh}
+
+	dodoc NEWS README *.txt doc/{,internal,text}/*.txt
+	dohtml doc/slangdoc.html slsh/doc/html/*.html
+}