version bump (#318959)

(Portage version: 2.2_rc67/cvs/Linux i686)

2 files changed, 89 insertions, 1 deletions

diff --git a/sys-power/cpufreqd/ChangeLog b/sys-power/cpufreqd/ChangeLog
index 312d3a23eb9a..1a11c6e6556c 100644
--- a/sys-power/cpufreqd/ChangeLog
+++ b/sys-power/cpufreqd/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-power/cpufreqd
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufreqd/ChangeLog,v 1.57 2010/01/10 23:34:33 bangert Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufreqd/ChangeLog,v 1.58 2010/05/26 09:51:10 bangert Exp $
+
+*cpufreqd-2.4.2 (26 May 2010)
+
+  26 May 2010; Thilo Bangert <bangert@gentoo.org> +cpufreqd-2.4.2.ebuild:
+  version bump (#318959)
 
 *cpufreqd-2.3.4-r2 (10 Jan 2010)
 
diff --git a/sys-power/cpufreqd/cpufreqd-2.4.2.ebuild b/sys-power/cpufreqd/cpufreqd-2.4.2.ebuild
new file mode 100644
index 000000000000..b8cb7602ef09
--- /dev/null
+++ b/sys-power/cpufreqd/cpufreqd-2.4.2.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-power/cpufreqd/cpufreqd-2.4.2.ebuild,v 1.1 2010/05/26 09:51:10 bangert Exp $
+
+EAPI="2"
+
+inherit eutils
+
+NVCLOCK_VERSION="0.8b"
+
+DESCRIPTION="CPU Frequency Daemon"
+HOMEPAGE="http://www.linux.it/~malattia/wiki/index.php/Cpufreqd"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+		nvidia? ( http://www.linuxhardware.org/nvclock/nvclock${NVCLOCK_VERSION}.tar.gz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="acpi apm lm_sensors nforce2 nvidia pmu"
+RDEPEND=">=sys-power/cpufrequtils-002
+		sys-fs/sysfsutils
+		lm_sensors? ( >sys-apps/lm_sensors-3 )"
+DEPEND="sys-apps/sed
+		${RDEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-conf.d.patch
+
+	if use nvidia; then
+		cd "${WORKDIR}"/nvclock${NVCLOCK_VERSION}
+		epatch "${FILESDIR}"/nvclock${NVCLOCK_VERSION}-fpic.patch
+	fi
+}
+
+src_configure() {
+	local config
+
+	if use nvidia; then
+		cd "${WORKDIR}"/nvclock${NVCLOCK_VERSION}
+		econf \
+			--disable-gtk \
+			--disable-qt \
+			--disable-nvcontrol \
+			|| die "econf nvclock failed"
+		emake -j1 || die "emake nvclock failed"
+		config="--enable-nvclock=${WORKDIR}/nvclock${NVCLOCK_VERSION}"
+	fi
+
+	cd "${S}"
+	econf \
+		$(use_enable acpi) \
+		$(use_enable apm) \
+		$(use_enable lm_sensors sensors) \
+		$(use_enable nforce2) \
+		$(use_enable pmu) \
+		${config} \
+		|| die "econf failed"
+}
+
+src_compile() {
+	if use nvidia; then
+		cd "${WORKDIR}"/nvclock${NVCLOCK_VERSION}
+	fi
+
+	cd "${S}"
+	emake || die "make failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	rm -rf "${D}"/usr/$(get_libdir)/*.la
+	dodoc AUTHORS ChangeLog NEWS README TODO
+	newinitd "${FILESDIR}"/${PN}-init.d ${PN}
+}
+
+pkg_postinst() {
+	if [ -f "${ROOT}"/etc/conf.d/cpufreqd ] ; then
+		ewarn "An old \"/etc/conf.d/cpufreqd\" file was found. It breaks"
+		ewarn "the new init script! Please remove it."
+		ewarn "# rm /etc/conf.d/cpufreqd"
+	fi
+}