Version bump. Clean up ebuild and 9999 version. Switch live ebuild to 1.1 branch

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C!)

2 files changed, 130 insertions, 15 deletions

diff --git a/x11-libs/libfm/libfm-1.1.4.ebuild b/x11-libs/libfm/libfm-1.1.4.ebuild
new file mode 100644
index 000000000000..91b2ad91b286
--- /dev/null
+++ b/x11-libs/libfm/libfm-1.1.4.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libfm/libfm-1.1.4.ebuild,v 1.1 2013/12/09 19:51:36 hwoarang Exp $
+
+EAPI=5
+
+inherit autotools fdo-mime vala
+
+MY_PV=${PV/_/}
+MY_P="${PN}-${MY_PV}"
+DESCRIPTION="A library for file management"
+HOMEPAGE="http://pcmanfm.sourceforge.net/"
+SRC_URI="http://dev.gentoo.org/~hwoarang/distfiles/${MY_P}.tar.xz"
+
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86 ~amd64-linux ~x86-linux"
+LICENSE="GPL-2"
+SLOT="0/4.7.1" #copy ABI_VERSION because it seems upstream change it randomly
+IUSE="debug doc examples vala"
+
+COMMON_DEPEND=">=dev-libs/glib-2.18:2
+	>=x11-libs/gtk+-2.16:2
+	>=lxde-base/menu-cache-0.3.2:=
+	!lxde-base/lxshortcut"
+RDEPEND="${COMMON_DEPEND}
+	x11-misc/shared-mime-info
+	|| ( gnome-base/gvfs[udev,udisks] gnome-base/gvfs[udev,gdu] )"
+DEPEND="${COMMON_DEPEND}
+	vala? ( $(vala_depend) )
+	doc? (
+		dev-util/gtk-doc
+	)
+	app-arch/xz-utils
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	sys-devel/gettext"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	if ! use doc; then
+		sed -ie '/SUBDIRS=/s#docs##' "${S}"/Makefile.am || die "sed failed"
+		sed -ie '/^[[:space:]]*docs/d' configure.ac || die "sed failed"
+	fi
+	sed -i -e "s:-O0::" -e "/-DG_ENABLE_DEBUG/s: -g::" \
+		configure.ac || die "sed failed"
+
+	#disable unused translations. Bug #356029
+	for trans in app-chooser ask-rename exec-file file-prop preferred-apps \
+		progress;do
+		echo "data/ui/"${trans}.ui >> po/POTFILES.in
+	done
+	#Remove -Werror for automake-1.12. Bug #421101
+	sed -i "s:-Werror::" configure.ac || die
+
+	# subslot sanity check
+	local sub_slot=${SLOT#*/}
+	local libfm_major_abi=$(sed -rne '/ABI_VERSION/s:.*=::p' src/Makefile.am | tr ':' '.')
+
+	if [[ ${sub_slot} != ${libfm_major_abi} ]]; then
+		eerror "Ebuild sub-slot (${sub_slot}) does not match ABI_VERSION(${libfm_major_abi})"
+		eerror "Please update SLOT variable as follows:"
+		eerror "    SLOT=\"${SLOT%%/*}/${libfm_major_abi}\""
+		eerror
+		die "sub-slot sanity check failed"
+	fi
+
+	eautoreconf
+	rm -r autom4te.cache || die
+	use vala && export VALAC="$(type -p valac-$(vala_best_api_version))"
+}
+
+src_configure() {
+	econf \
+		--sysconfdir="${EPREFIX}/etc" \
+		--disable-dependency-tracking \
+		--disable-static \
+		--disable-udisks \
+		$(use_enable examples demo) \
+		$(use_enable debug) \
+		$(use_enable vala actions) \
+		$(use_enable doc gtk-doc) \
+		--with-html-dir=/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -exec rm -f '{}' +
+	# Sometimes a directory is created instead of a symlink. No idea why...
+	# It is wrong anyway. We expect a libfm-1.0 directory and then a libfm
+	# symlink to it.
+	if [[ -h ${D}/usr/include/${PN} || -d ${D}/usr/include/${PN} ]]; then
+		rm -r "${D}"/usr/include/${PN}
+	fi
+}
+
+pkg_preinst() {
+	# Resolve the symlink mess. Bug #439570
+	[[ -d "${ROOT}"/usr/include/${PN} ]] && \
+		rm -rf "${ROOT}"/usr/include/${PN}
+	if [[ -d "${D}"/usr/include/${PN}-1.0 ]]; then
+		cd "${D}"/usr/include
+		ln -s --force ${PN}-1.0 ${PN}
+	fi
+}
+
+pkg_postinst() {
+	fdo-mime_mime_database_update
+}
+
+pkg_postrm() {
+	fdo-mime_mime_database_update
+}
diff --git a/x11-libs/libfm/libfm-9999.ebuild b/x11-libs/libfm/libfm-9999.ebuild
index 69cd12e4f8e8..fe92098edb3e 100644
--- a/x11-libs/libfm/libfm-9999.ebuild
+++ b/x11-libs/libfm/libfm-9999.ebuild
@@ -1,18 +1,19 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libfm/libfm-9999.ebuild,v 1.34 2013/11/17 11:51:31 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libfm/libfm-9999.ebuild,v 1.35 2013/12/09 19:51:36 hwoarang Exp $
 
 EAPI=5
 
-EGIT_REPO_URI="git://pcmanfm.git.sourceforge.net/gitroot/pcmanfm/${PN}"
-
+EGIT_REPO_URI="https://github.com/lxde/${PN}"
+# master seems way too unstable for us to use
+EGIT_BRANCH="1.1"
 inherit autotools git-2 fdo-mime vala
 
 DESCRIPTION="A library for file management"
 HOMEPAGE="http://pcmanfm.sourceforge.net/"
 
 LICENSE="GPL-2"
-SLOT="0/4.0.0" #copy ABI_VERSION because it seems upstream change it randomly
+SLOT="0/4.7.1" #copy ABI_VERSION because it seems upstream change it randomly
 IUSE="debug doc examples vala"
 KEYWORDS=""
 
@@ -24,8 +25,7 @@ RDEPEND="${COMMON_DEPEND}
 	x11-misc/shared-mime-info
 	|| ( gnome-base/gvfs[udev,udisks] gnome-base/gvfs[udev,gdu] )"
 DEPEND="${COMMON_DEPEND}
-	>=dev-lang/vala-0.14.0
-	dev-util/gtk-doc-am
+	vala? ( $(vala_depend) )
 	doc? (
 		dev-util/gtk-doc
 	)
@@ -37,23 +37,22 @@ DOCS=( AUTHORS TODO )
 
 src_prepare() {
 	if ! use doc; then
-		sed -ie "/^SUBDIRS_DOCS/d" Makefile.am || die "sed failed"
-		sed -ie "/^[[:space:]]*docs/d" configure.ac || die "sed failed"
+		sed -ie '/SUBDIRS=/s#docs##' "${S}"/Makefile.am || die "sed failed"
+		sed -ie '/^[[:space:]]*docs/d' configure.ac || die "sed failed"
 	else
 		gtkdocize --copy || die
 	fi
+	sed -i -e "s:-O0::" -e "/-DG_ENABLE_DEBUG/s: -g::" \
+		configure.ac || die "sed failed"
+
 	intltoolize --force --copy --automake || die
 	#disable unused translations. Bug #356029
 	for trans in app-chooser ask-rename exec-file file-prop preferred-apps \
 		progress;do
 		echo "data/ui/"${trans}.ui >> po/POTFILES.in
 	done
-	sed -i -e "s:-O0::" -e "/-DG_ENABLE_DEBUG/s: -g::" "${S}"/configure.ac || die
 	#Remove -Werror for automake-1.12. Bug #421101
 	sed -i "s:-Werror::" configure.ac || die
-	# Drop the symlink. We will create it later on. 439580
-	sed -i "/@LN_S@ @PACKAGE@-@FMLIBVER@/d" src/Makefile.am \
-		|| die "failed to remove the includedir symlink"
 
 	# subslot sanity check
 	local sub_slot=${SLOT#*/}
@@ -88,9 +87,13 @@ src_configure() {
 src_install() {
 	default
 	find "${D}" -name '*.la' -exec rm -f '{}' +
-	# 439570
-	[[ -d ${D}/usr/include/${PN} ]] \
-		&& rm -r ${D}/usr/include/${PN}
+	# Remove broken symlink #439570
+	# Sometimes a directory is created instead of a symlink. No idea why...
+	# It is wrong anyway. We expect a libfm-1.0 directory and then a libfm
+	# symlink to it.
+	if [[ -h ${D}/usr/include/${PN} || -d ${D}/usr/include/${PN} ]]; then
+		rm -r "${D}"/usr/include/${PN}
+	fi
 }
 
 pkg_preinst() {