DEPEND on virtual/pkgconfig, X11 protos. Version bump.

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key A792A613)

4 files changed, 69 insertions, 4 deletions

diff --git a/x11-terms/st/ChangeLog b/x11-terms/st/ChangeLog
index 6865d2f80feb..349216474f77 100644
--- a/x11-terms/st/ChangeLog
+++ b/x11-terms/st/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for x11-terms/st
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/st/ChangeLog,v 1.14 2013/04/02 23:33:56 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/st/ChangeLog,v 1.15 2013/04/27 17:19:31 jer Exp $
+
+*st-0.4.1 (27 Apr 2013)
+
+  27 Apr 2013; Jeroen Roovers <jer@gentoo.org> st-0.4.ebuild, +st-0.4.1.ebuild,
+  st-9999.ebuild:
+  DEPEND on virtual/pkgconfig, X11 protos. Version bump.
 
   02 Apr 2013; Agostino Sarubbo <ago@gentoo.org> -st-0.3.ebuild, st-0.4.ebuild:
   Add ~x86, remove old, wrt to bug #464252
diff --git a/x11-terms/st/st-0.4.1.ebuild b/x11-terms/st/st-0.4.1.ebuild
new file mode 100644
index 000000000000..974361bbf97f
--- /dev/null
+++ b/x11-terms/st/st-0.4.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/st/st-0.4.1.ebuild,v 1.1 2013/04/27 17:19:31 jer Exp $
+
+EAPI=5
+
+inherit multilib savedconfig toolchain-funcs
+
+DESCRIPTION="simple terminal implementation for X"
+HOMEPAGE="http://st.suckless.org/"
+SRC_URI="http://dl.suckless.org/st/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="savedconfig"
+
+RDEPEND="media-libs/fontconfig
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXft"
+DEPEND="${RDEPEND}
+	sys-libs/ncurses
+	virtual/pkgconfig
+	x11-proto/xextproto
+	x11-proto/xproto"
+
+src_prepare() {
+	sed -e '/^CFLAGS/s:[[:space:]]-O[^[:space:]]*[[:space:]]: :' \
+		-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
+		-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
+		-i config.mk || die
+	sed -e '/@echo/!s:@::' \
+		-i Makefile || die
+	tc-export CC
+
+	restore_config config.h
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
+	tic -s -o "${ED}"/usr/share/terminfo st.info || die
+	dodoc TODO
+
+	save_config config.h
+}
+
+pkg_postinst() {
+	if ! [[ "${REPLACING_VERSIONS}" ]]; then
+		elog "Please ensure a usable font is installed, like"
+		elog "    media-fonts/corefonts"
+		elog "    media-fonts/dejavu"
+		elog "    media-fonts/urw-fonts"
+	fi
+}
diff --git a/x11-terms/st/st-0.4.ebuild b/x11-terms/st/st-0.4.ebuild
index efab34e84b34..643e72a0326c 100644
--- a/x11-terms/st/st-0.4.ebuild
+++ b/x11-terms/st/st-0.4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/st/st-0.4.ebuild,v 1.2 2013/04/02 23:33:56 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/st/st-0.4.ebuild,v 1.3 2013/04/27 17:19:31 jer Exp $
 
 EAPI=5
 
@@ -21,6 +21,7 @@ RDEPEND="media-libs/fontconfig
 	x11-libs/libXft"
 DEPEND="${RDEPEND}
 	sys-libs/ncurses
+	virtual/pkgconfig
 	x11-proto/xextproto
 	x11-proto/xproto"
 
diff --git a/x11-terms/st/st-9999.ebuild b/x11-terms/st/st-9999.ebuild
index b8b6c099aab5..9db68c5effbd 100644
--- a/x11-terms/st/st-9999.ebuild
+++ b/x11-terms/st/st-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/st/st-9999.ebuild,v 1.9 2013/02/23 22:52:45 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/st/st-9999.ebuild,v 1.10 2013/04/27 17:19:31 jer Exp $
 
 EAPI=5
 
@@ -20,7 +20,10 @@ RDEPEND="media-libs/fontconfig
 	x11-libs/libXext
 	x11-libs/libXft"
 DEPEND="${RDEPEND}
-	sys-libs/ncurses"
+	sys-libs/ncurses
+	virtual/pkgconfig
+	x11-proto/xextproto
+	x11-proto/xproto"
 
 src_prepare() {
 	sed -e '/^CFLAGS/s:[[:space:]]-Wall[[:space:]]: :' \