1 files changed, 132 insertions, 0 deletions
diff --git a/app-i18n/uim/uim-1.1.0.ebuild b/app-i18n/uim/uim-1.1.0.ebuild
new file mode 100644
index 000000000000..89ae05c8227c
--- /dev/null
+++ b/app-i18n/uim/uim-1.1.0.ebuild
@@ -0,0 +1,132 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-i18n/uim/uim-1.1.0.ebuild,v 1.1 2006/06/17 13:34:00 usata Exp $
+
+inherit eutils kde-functions flag-o-matic multilib elisp-common
+
+MY_P="${P/_/-}"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="Simple, secure and flexible input method library"
+HOMEPAGE="http://uim.freedesktop.org/"
+SRC_URI="http://uim.freedesktop.org/releases/${MY_P}.tar.gz"
+
+LICENSE="GPL-2 BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="gtk qt immqt immqt-bc nls X m17n-lib canna emacs"
+
+RDEPEND="
+	X? ( || ( (
+	   	 	    x11-libs/libX11
+				x11-libs/libXft
+				x11-libs/libXt
+				x11-libs/libICE
+				x11-libs/libSM
+				x11-libs/libXext
+				x11-libs/libXrender
+			  )
+		   	  virtual/x11 ) )
+	gtk? ( >=x11-libs/gtk+-2 )
+	m17n-lib? ( dev-libs/m17n-lib )
+	!app-i18n/uim-svn
+	canna? ( app-i18n/canna )
+	immqt? ( $(qt_min_version 3.3.4) )
+	immqt-bc? ( $(qt_min_version 3.3.4) )
+	qt? ( $(qt_min_version 3.3.4) )
+	emacs? ( virtual/emacs )
+	!<app-i18n/prime-0.9.4"
+
+DEPEND="${RDEPEND}
+	X? ( || ( ( x11-proto/xextproto x11-proto/xproto )
+	   	 	  virtual/x11 ) )
+	dev-lang/perl
+	dev-perl/XML-Parser
+	>=sys-apps/sed-4
+	sys-devel/autoconf
+	sys-devel/automake
+	sys-devel/libtool
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	# An arch specific config directory is used on multilib systems
+	has_multilib_profile && GTK2_CONFDIR="/etc/gtk-2.0/${CHOST}"
+	GTK2_CONFDIR=${GTK2_CONFDIR:=/etc/gtk-2.0/}
+}
+
+src_unpack() {
+	unpack ${A}
+
+	cd "${S}"
+	# we execute gtk-query-immodules-2.0 in pkg_postinst()
+	# to not violate sandbox.
+	sed -i -e "/gtk-query-immodules-2.0/s/.*/	:\\\\/g" \
+		Makefile.am || die
+	use X || sed -i -e '/^SUBDIRS/s/xim//' Makefile.in || die
+}
+
+src_compile() {
+	local myconf
+	use qt && set-qtdir 3
+	if use immqt || use immqt-bc ; then
+		myconf="${myconf} --with-qt-immodule"
+		export CPPFLAGS="${CPPFLAGS} -DQT_THREAD_SUPPORT"
+	fi
+
+	myconf="${myconf}
+		$(use_enable nls)
+		$(use_with X x)
+		$(use_with gtk gtk2)
+		$(use_with m17n-lib m17nlib)
+		$(use_with canna)
+		$(use_with qt)
+		$(use_enable emacs)"
+
+	autoreconf
+	libtoolize --copy --force
+
+	# --with-scim is not stable enough
+	# --with-libedit should be fixed in SVN trunk, but not well tested
+	econf ${myconf} --without-scim --without-libedit || die "econf failed"
+	emake -j1 || die "emake failed"
+}
+
+src_install() {
+	make DESTDIR="${D}" install || die "make install failed"
+
+	dodoc AUTHORS ChangeLog INSTALL* NEWS README*
+	dodoc doc/{HELPER-CANDWIN,KEY,UIM-SH}
+	use X && dodoc doc/XIM-SERVER
+	use emacs && elisp-site-file-install ${FILESDIR}/50uim-el-gentoo.el
+}
+
+pkg_postinst() {
+	einfo
+	einfo "To use uim-anthy you should emerge app-i18n/anthy or app-i18n/anthy-ss."
+	einfo "To use uim-skk you should emerge app-i18n/skk-jisyo."
+	einfo "To use uim-prime you should emerge app-i18n/prime."
+	einfo
+
+	ewarn
+	ewarn "New input method switcher has been introduced. You need to set"
+	ewarn
+	ewarn "% GTK_IM_MODULE=uim ; export GTK_IM_MODULE"
+	ewarn "% QT_IM_MODULE=uim ; export QT_IM_MODULE"
+	ewarn "% XMODIFIERS=@im=uim ; export XMODIFIERS"
+	ewarn
+	ewarn "If you would like to use uim-anthy as default input method, put"
+	ewarn "(define default-im-name 'anthy)"
+	ewarn "to your ~/.uim."
+	ewarn
+	ewarn "All input methods can be found by running uim-im-switcher-gtk"
+	ewarn "or uim-im-switcher-qt."
+	ewarn
+
+	use gtk && gtk-query-immodules-2.0 > ${ROOT}/${GTK2_CONFDIR}/gtk.immodules
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use gtk && gtk-query-immodules-2.0 > ${ROOT}/${GTK2_CONFDIR}/gtk.immodules
+	use emacs && elisp-site-regen
+}