1 files changed, 59 insertions, 0 deletions
diff --git a/dev-python/gevent/gevent-0.13.7.ebuild b/dev-python/gevent/gevent-0.13.7.ebuild
new file mode 100644
index 000000000000..d29146673fdd
--- /dev/null
+++ b/dev-python/gevent/gevent-0.13.7.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/gevent/gevent-0.13.7.ebuild,v 1.1 2012/05/18 10:59:04 xarthisius Exp $
+
+EAPI=4
+
+SUPPORT_PYTHON_ABIS=1
+RESTRICT_PYTHON_ABIS="3.* 2.7-pypy-* *-jython"
+
+inherit distutils
+
+DESCRIPTION="A Python networking library that uses greenlet to provide synchronous API"
+HOMEPAGE="http://pypi.python.org/pypi/gevent/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+IUSE="doc examples"
+LICENSE="MIT"
+SLOT="0"
+
+RDEPEND="dev-libs/libevent
+	dev-python/greenlet"
+DEPEND="${RDEPEND}
+	dev-python/setuptools
+	doc? ( dev-python/sphinx )"
+
+PYTHON_CFLAGS=("2.* + -fno-strict-aliasing")
+
+DOCS="AUTHORS changelog.rst"
+RESTRICT="test" # long and lot's of failures
+
+src_compile() {
+	distutils_src_compile
+	if use doc; then
+		PYTHONPATH="$(ls -d ${S}/build-$(PYTHON -f --ABI)/lib.*)" emake html -C	doc
+	fi
+}
+
+src_test() {
+	pushd greentest &> /dev/null
+	testing() {
+		PYTHONPATH="$(ls -d ../build-${PYTHON_ABI}/lib.*)" "$(PYTHON)" testrunner.py
+	}
+	python_execute_function testing
+	popd &> /dev/null
+}
+
+src_install() {
+	distutils_src_install
+
+	if use doc; then
+		dohtml -r doc/_build/html/
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins -r examples/*
+	fi
+}