1 files changed, 45 insertions, 0 deletions
diff --git a/net-libs/libtorrent/libtorrent-0.10.4.ebuild b/net-libs/libtorrent/libtorrent-0.10.4.ebuild
new file mode 100644
index 000000000000..cd9ebfe2d4e1
--- /dev/null
+++ b/net-libs/libtorrent/libtorrent-0.10.4.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/libtorrent/libtorrent-0.10.4.ebuild,v 1.1 2006/10/27 16:12:48 flameeyes Exp $
+
+inherit eutils toolchain-funcs flag-o-matic libtool
+
+DESCRIPTION="LibTorrent is a BitTorrent library written in C++ for *nix."
+HOMEPAGE="http://libtorrent.rakshasa.no/"
+SRC_URI="http://libtorrent.rakshasa.no/downloads/${P}.tar.gz"
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="debug"
+
+RDEPEND=">=dev-libs/libsigc++-2"
+
+DEPEND="${RDEPEND}
+	>=dev-util/pkgconfig-0.11"
+
+src_compile() {
+	replace-flags -Os -O2
+
+	if [[ $(tc-arch) = "x86" ]]; then
+		filter-flags -fomit-frame-pointer
+
+		# See bug #151221. It seems only to hit on GCC 4.1 and x86 architecture
+		# it could be safer to fallback to -O1, but with the high use of STL in
+		# rtorrent, that could make it too slow.
+		[[ $(gcc-major-version)$(gcc-minor-version) == "41" ]] && replace-flags -O2 -O3
+	fi
+
+	elibtoolize
+	econf \
+		$(use_enable debug) \
+		--disable-dependency-tracking \
+		|| die "econf failed"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+	dodoc AUTHORS ChangeLog NEWS README TODO
+}