1 files changed, 42 insertions, 0 deletions
diff --git a/x11-libs/gtksourceview/gtksourceview-2.8.2.ebuild b/x11-libs/gtksourceview/gtksourceview-2.8.2.ebuild
new file mode 100644
index 000000000000..bf3493b8acc7
--- /dev/null
+++ b/x11-libs/gtksourceview/gtksourceview-2.8.2.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/gtksourceview/gtksourceview-2.8.2.ebuild,v 1.1 2009/12/21 22:10:19 eva Exp $
+
+EAPI="2"
+GCONF_DEBUG="no"
+
+inherit gnome2
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="2.0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc"
+
+RDEPEND=">=x11-libs/gtk+-2.12
+	>=dev-libs/libxml2-2.5
+	>=dev-libs/glib-2.14"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/intltool-0.40
+	>=dev-util/pkgconfig-0.9
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README"
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in \
+		|| die "sed failed"
+}
+
+src_install() {
+	gnome2_src_install
+
+	insinto /usr/share/${PN}-2.0/language-specs
+	doins "${FILESDIR}"/2.0/gentoo.lang || die "doins failed"
+}