app-emulation/libvirt/libvirt-0.6.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.6.2.ebuild,v 1.1 2009/04/17 15:01:16 cardoe Exp $

EAPI=1

inherit eutils autotools

DESCRIPTION="C toolkit to manipulate virtual machines"
HOMEPAGE="http://www.libvirt.org/"
SRC_URI="http://libvirt.org/sources/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="avahi iscsi hal kvm lvm +lxc +network openvz parted qemu sasl selinux uml xen"
# policykit is in package.mask
# devicekit isn't in portage

DEPEND="sys-libs/readline
	sys-libs/ncurses
	>=dev-libs/libxml2-2.5
	>=net-libs/gnutls-1.0.25
	dev-lang/python
	sys-fs/sysfsutils
	net-analyzer/netcat
	dev-util/pkgconfig
	avahi? ( >=net-dns/avahi-0.6 )
	iscsi? ( sys-block/open-iscsi )
	kvm? ( app-emulation/kvm )
	lvm? ( sys-fs/lvm2 )
	network? ( net-misc/bridge-utils net-dns/dnsmasq net-firewall/iptables )
	openvz? ( sys-kernel/openvz-sources )
	parted? ( >=sys-apps/parted-1.8 )
	qemu? ( app-emulation/qemu )
	sasl? ( dev-libs/cyrus-sasl )
	selinux? ( sys-libs/libselinux )
	xen? ( app-emulation/xen-tools app-emulation/xen )
	"
	#policykit? ( >=sys-auth/policykit-0.6 )

src_unpack() {
	unpack ${A}
	cd "${S}"

	epatch "${FILESDIR}"/"${PN}"-0.4.6-qemu-img-name.patch
	epatch "${FILESDIR}"/"${P}"-storage-fix.patch
	eautoreconf
}

pkg_setup() {
	local hasbackend=0
	local backends="lxc kvm openvz qemu uml xen"
	local backend

	for backend in $backends ; do
		use $backend && hasbackend=1
	done

	if [ "$hasbackend" == 0 ]; then
		local msg="You must enable one of these USE flags: $backends"
		eerror "$msg"
		die "$msg"
	fi
}

src_compile() {
	local my_conf=""
	if use qemu || use kvm ; then
		# fix path for kvm-img but use qemu-img if the useflag is set
		my_conf="--with-qemu \
			$(use_with !qemu qemu-img-name kvm-img)"
	else
		my_conf="--without-qemu"
	fi

	econf \
		$(use_with avahi) \
		$(use_with iscsi storage-iscsi) \
		$(use_with lvm storage-lvm) \
		$(use_with lxc) \
		$(use_with hal) \
		$(use_with openvz) \
		$(use_with parted storage-disk) \
		$(use_with sasl) \
		$(use_with selinux) \
		$(use_with uml) \
		$(use_with xen) \
		$(use_with network) \
		${my_conf} \
		--without-devkit \
		--without-polkit \
		--with-remote \
		--disable-iptables-lokkit \
		--localstatedir=/var \
		--with-remote-pid-file=/var/run/libvirtd.pid \
		|| die "econf failed"
		#$(use_with policykit) \
	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die
	mv "${D}"/usr/share/doc/{${PN}-python*,${P}/python}
	newinitd "${FILESDIR}"/libvirtd.init libvirtd
	newconfd "${FILESDIR}"/libvirtd.confd libvirtd
}

pkg_postinst() {
	elog "To allow normal users to connect to libvirtd you must change the"
	elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
}