dev-dotnet/gtk-sharp/gtk-sharp-1.9.5.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91

# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-dotnet/gtk-sharp/gtk-sharp-1.9.5.ebuild,v 1.2 2005/05/26 23:32:37 herbs Exp $

inherit eutils mono

DESCRIPTION="Gtk# is a C# language binding for the GTK2 toolkit and GNOME libraries"
SRC_URI="http://go-mono.com/sources/${PN}-2.0/${P}.tar.gz
		mirror://gentoo/${P}-configurable.diff.gz"
HOMEPAGE="http://gtk-sharp.sourceforge.net/"

LICENSE="LGPL-2.1"
SLOT="2"
IUSE="doc"

RDEPEND=">=sys-apps/sed-4.0
	>=dev-lang/mono-1.1.2
	>=x11-libs/gtk+-2.4
	>=gnome-base/orbit-2.8.3"

DEPEND="${RDEPEND}
	dev-util/pkgconfig"

KEYWORDS="~x86 ~ppc ~ppc"

src_unpack() {
	unpack ${A}

	# disable building of samples (#16015)
	cd ${S}
	epatch ${WORKDIR}/${P}-configurable.diff
	export WANT_AUTOMAKE="1.8"

	#fixes support with pkgconfig-0.17, bug #92503
	sed -i -e 's/\<PKG_PATH\>/GTK_SHARP_PKG_PATH/g' configure.in

	# Use correct libdir in pkgconfig files
	sed -i -e 's:^libdir.*:libdir=@libdir@:' \
		${S}/*/{,GConf}/*.pc.in || die

	aclocal || die
	automake || die
	autoconf || die
	libtoolize --copy --force

	sed -i -e "s:sample::" Makefile.in
}

src_compile() {

	local myconf=""
	# These are the same as from gtk-sharp-component.eclass
	for package in art gda glade gnome gnomedb gnomevfs gtkhtml rsvg vte
	do
		myconf="${myconf} --disable-${package}"
	done

	econf ${myconf} || die "./configure failed"
	LANG=C emake -j1 || die

	if use doc && has_version dev-util/monodoc
	then
		cd ${S}/doc
		emake assemble || die "Failed to generate docs"
	fi
}

src_install () {
	make GACUTIL_FLAGS="/root ${D}/usr/$(get_libdir) /gacdir /usr/$(get_libdir) /package ${PN}-2.0" \
		DESTDIR=${D} install || die

	dodoc README* ChangeLog

	if use doc && has_version dev-util/monodoc
	then
		cd ${S}/doc
		insinto $(monodoc --get-sourcesdir)
		doins gtk-sharp-docs.{tree,zip}
	fi
}

pkg_postinst() {
	if use doc && ! has_version dev-util/monodoc
	then
		ewarn
		ewarn "Although 'doc' is in the USE flag list, gtk-sharp will"
		ewarn "not install its monodoc documentation unless you have monodoc"
		ewarn "installed. If you want the documentation to be available in"
		ewarn "monodoc, please emerge monodoc then re-emerge gtk-sharp."
	fi
}